让我们共同走进CAD的动画世界！新增-->时钟

xazhji · 发表于 2003-6-24 13:39:00

本帖最后由作者于 2005-4-5 20:38:53 编辑

今天我看到一个很老的贴子，要是我用回复吧，贴子太老，跟不上“形势”，所以，我就重新发起吧。
谈的就是“cad能不能做动画”。我做了一个lisp程序，是一个四杆机构的动画，在屏幕上顺序选择四个顶点，按回车键是实现步进功能，C连续等等，在命令行里有详尽说明。当然，可以实现分析如摆角大小等。
如果合适的选点，可以实现双摇杆机构的诙?lt;BR>;;;17:02 02-3-22
(defun c:sg(/ os ff1 w1 w2 w tt x y e f g kf tis)
(setvar "cmdecho" 0)
(setvar "osmode" 0)
(initget 7 " ")
(if ba (setq jc (entget ba)))
(setq tis nil)
(if (null jc)(setq ba nil))
(if (null ba)(setq ppa (getpoint "\n请连续给出四个铰链点的起始位置\n第一点:")))
(if (null ba)(setq ppb (getpoint ppa "\n第二点:")))
(if (null ba)(setq ppc (getpoint ppb "\n第三点:")))
(if (null ba)(setq ppd (getpoint ppc "\n第四点:")))
(if ba
(progn
(setq tm 1 jc (cdr jc))
(while jc
(if (= '10 (car (car jc)))
(progn (cond ((= tm 1)(setq ppa (cdr (car jc))))
((= tm 2)(setq ppb (cdr (car jc))))
((= tm 3)(setq ppc (cdr (car jc))))
((= tm 4)(setq ppd (cdr (car jc))))
)
(setq tm (1+ tm))
)
)
(setq jc (cdr jc))
)
)
)
(setq ll1 (distance ppa ppb))
(setq ll2 (distance ppb ppc))
(setq ll3 (distance ppd ppc))
(if (null ba) (progn (command "pline" ppa ppb ppc ppd "")
(setq ba (entlast))
)
)
(setq ff1 (angle ppa ppb))
(setq w1 (angle ppc ppb) w2 (angle ppc ppd))
(if (< w1 w2) (setq w 1))
(if (null zzs)(setq zzs 0.1 kai 0))
(princ " \n[Esc]退出\\V速度\\C连续\\L轨迹线\\<步进运行>:")
(setq tt (strcase (getstring)))
(if (= tt "V")(get_v))
(while (or (= tt "L")(= tt "")(= tt "C"))
(setq x (- (car ppd) (car ppa)) y (- (cadr ppd) (cadr ppa)))
(setq e (* 2 ll3 (- x (* ll1 (cos ff1)))))
(setq f (* 2 ll3 (- y (* ll1 (sin ff1)))))
(setq g (- (+ (* x x) (* y y) (* ll1 ll1) (* ll3 ll3)) (* ll2 ll2) (* 2 x ll1 (cos ff1)) (* 2 y ll1 (sin ff1))))
(setq kf (- (+ (* e e) (* f f)) (* g g)))
(if (> 0 kf)(setq zzs (- 0 zzs) kai 1)(setq kai 0))
(if (= kai 0) (if (= w 1)(setq ff3 (* 2 (atan (/ (+ f (sqrt kf)) (- e g))))) (setq ff3 (* 2 (atan (/ (- f (sqrt kf)) (- e g)))))))
(command "pedit" ppa "e" "n" "m" (polar ppa ff1 ll1) "n" "m" (polar ppd ff3 ll3) "x" "")
(if (= tt "L")(command "line" ppc (polar ppd ff3 ll3) "" "line" ppb (polar ppa ff1 ll1) ""))
(setq ppb (polar ppa ff1 ll1) ppc (polar ppd ff3 ll3))
(if (not (or (= tt "L")(= tt "C")))(setq tt (strcase (getstring)) tis 0)(setq tis 1))
(if (= tt "V")(get_v))
(setq ff1 (+ ff1 zzs))
)
)

(defun get_v()
(initget 1 " ")
(setq zzs (getreal "\n 输入速度(0.1～5)<1>:"))
(if (= zzs "") (setq zzs 1))
(setq zzs (* zzs 0.1) kai 0)
(princ " \n[Esc]退出\\V速度\\C连续\\L轨迹线\\<步进运行>:")
(setq tt (strcase (getstring)))
(if (= tt "V")(get_v))
)
(princ "《四杆机构运动分析程序》已成功装载，输入sg可运行！")

xazhji · 发表于 2003-6-24 16:53:00

本帖最后由作者于 2007-3-18 18:46:16 编辑

2007新年祝福动画请见145楼

只是喜欢静态绘图？

xazhji · 发表于 2003-6-27 16:30:00

大家为什么不发表高见呢？难道动态分析，在autocad中是个盲点吗？ProE在这方面可是有强大的功能呀！

xazhji · 发表于 2003-7-7 10:19:00

本帖最后由作者于 2003-7-7 11:50:11 编辑

为了激发大家的cad的兴趣，本人早上又写了一个动画程序，一个可以翻滚的线条，可很好玩哟！

;;;;会翻滚的线条
;;;;by xazhji
;;;;2003-7-7
(defun c:fg()
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (command "zoom" "w" "0,62" "200,-58")
  (command "line" "-60,0" "260,0" "")
  (command "line" "0,0" "0,10" "")
  (setq dang (/ pi 180) ang (- (/ pi 2) dang))
  (setq p1 (list 0 0) p2 (polar p1 ang 10))
  (while t
      (if (and (> dang 0)(<= ang 0)) (setq p3 (polar p1 0 10) p1 p3 p2 (polar p1 pi 10) ang pi))
      (if (and (< dang 0)(>= ang pi)) (setq p3 (polar p1 pi 10) p1 p3 p2 (polar p1 0 10) ang 0))
      (command "erase" "l" "")
      (command "line" p1 p2 "")(command)
      (setq ang (- ang dang))
      (setq p2 (polar p1 ang 10))
      (if (or (>= 0 (car p2))(<= 200 (car p2)))(setq p1 p2 p2 (polar p1 (/ pi 2) 10) dang (* dang -1) ang (/ pi 2)))
)
  )
  (princ "\n成功调入!键入 fg 运行......")(prin1)

meflying · 发表于 2003-7-7 11:42:00

这样好象快点，
(defun c:fg( / dang p1 p2 ang p3 str sname)
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (command "zoom" "w" "0,62" "200,-58")
  (command "line" "-60,0" "260,0" "")

  (setq str '((0 . "LINE") (100 . "AcDbEntity") (67 . 0) (410 . "Model")
      (8 . "center") (100 . "AcDbLine") (10 0.0 0.0 0.0)
      (11 0.0 10.0 0.0) (210 0.0 0.0 1.0)))
  (entmake str)
  (setq sname (entlast))
  (setq dang (/ pi 180) ang (- (/ pi 2) dang))
  (setq p1 (list 0 0) p2 (polar p1 ang 10))
  (while t
      ;(if (<= ang 0) (progn (setq p3 p2 p2 p1 p1 p3 ang pi)(princ "p1==>" )(princ p1 )(princ "p2==>" )(princ p2)))
      (if (and (> dang 0)(<= ang 0)) (setq p3 (polar p1 0 10) p1 p3 p2 (polar p1 pi 10) ang pi))
      (if (and (< dang 0)(>= ang pi)) (setq p3 (polar p1 pi 10) p1 p3 p2 (polar p1 0 10) ang 0))
   (setq str (entget sname))
   (setq str (subst (cons 10 p1) (assoc 10 str) str))
   (setq str (subst (cons 11 p2) (assoc 11 str) str))
   (entmod str)
      (redraw)
   (setq sname (entlast))
      (setq ang (- ang dang))
      (setq p2 (polar p1 ang 10))
      (if (or (>= 0 (car p2))(<= 200 (car p2)))(setq p1 p2 p2 (polar p1 (/ pi 2) 10) dang (* dang -1) ang (/ pi 2)))
)
  )
  (princ "\n成功调入!键入 fg 运行......")(prin1)

前生 · 发表于 2003-7-7 11:44:00

在冲压模具设计中,经常要在板上打一些小的孔,供线切割加工板时用
就做了这个动态的。。。

(DEFUN C:WC () ; (/ P0 P1 XY)
;;;________________________________
  (defun mc ()
(SETVAR "ORTHOMODE" 0)
(setq xy (trans (list (* 0.5 (+ (CAR P0) (CAR P1)))
   (* 0.5 (+ (CADR P0) (CADR P1)))
   (caddr p1)
      )
      1
      0
      )
)
(setq eli (list (cons 0 "CIRCLE")
      (cons 8 "HH")
      (cons 10 xy)
      (Cons 40 0.75)
      )
)
(entmake eli)
  )
;;;________________________________
  (setq p0 nil
p1 nil
  )
  (SETQ P0 (GETPOINT "\n 请点取第一点!.."))
  (setq pp (trans p0 1 0))
  (while (= 0 (distance (setq p1 (cadr (grread t 4 0))) p0)))
  (mc)
  (setq ls (entlast))
  (vla-put-color (vlax-ename->vla-object ls) 1)
  (setq ed (entget ls))
  (command "line" p0 p1 "")
  (setq ls1 (entlast))
  (vla-put-color (vlax-ename->vla-object ls1) 2)
  (setq ed1 (entget ls1))
  (setq pick nil)
  (while (null pick)
; (setq p (grread t 4 0))
(setq p (grread t 4 2))
(princ)
(setq ip (car p)
   pt (cadr p)
)
(if (= ip 5)
   (progn
(setq xy (trans (list (* 0.5 (+ (CAR P0) (CAR Pt)))
      (* 0.5 (+ (CADR P0) (CADR Pt)))
      (caddr p1)
)
1
0
   )
)
(setq ed (Subst (cons 10 xy) (assoc 10 ed) ed))
(entmod ed)
(setq p2 (trans pt 1 0))
(setq ed1 (subst (cons 10 pp) (assoc 10 ed1) ed1))
(setq ed1 (subst (cons 11 p2) (assoc 11 ed1) ed1))
(entmod ed1)
   )
)
(setq pick (= 3 ip))
  )
  (entdel ls1)
  (prompt "\n 前生制作")
  (prompt "....circle园系列")
  (princ)
)

xazhji · 发表于 2003-7-7 11:53:00

希望大家弄些好玩的程序......

莫测 · 发表于 2003-7-8 22:30:00

很好！我很喜欢您编的这个程序。

莫测 · 发表于 2003-7-8 22:30:00

很好！我很喜欢您编的这个程序。

xazhji · 发表于 2003-7-14 15:40:00

本帖最后由作者于 2003-7-16 10:33:04 编辑

为了恭贺明经通道“CAD专业研讨会”的胜利闭幕，我写了一个“屏幕蹦蹦球”与大家一同分享！
[注]7月16日更改反射角度错误

;;;;屏幕蹦蹦球
;;;;By xazhji  03-7-13
(defun c:pb( )
  (setvar "cmdecho" 0)
  (setq dx (getvar "screensize"))
  (setq kgb (/ (car dx) (cadr dx)))
  (setq hd (getvar "viewsize"))
  (setq vcen (getvar "viewctr"))
  (setq a (list (- (car vcen) (* hd kgb 0.5)) (- (cadr vcen) (/ hd 2))))
  (setq b (list (+ (car a) (* hd kgb)) (+ (cadr a) hd)))
  (setq ang 1)
  (setq pcen vcen)
  (setq r (/ (abs (- (cadr a) (cadr b))) 10))
  (setq a (list (+ (car a) r) (+ (cadr a) r)) b (list (- (car b) r) (- (cadr b) r)))
  (setq col 1)
  (command "color" col)
  (command "circle" pcen r)
  (setq obj (entlast))
  (while t
(command "move" obj "" pcen (polar pcen ang (/ r 50)))
(setq pcen (polar pcen ang (/ r 50)))
(if (or (> (car pcen) (car b))(< (car pcen)(car a))
         (> (cadr pcen) (cadr b))(< (cadr pcen)(cadr a)))
      (progn
      (setq pcen0 (polar pcen (+ ang pi) (/ r 50)))
      (cond ((inters pcen pcen0 a (list (car a) (cadr b)))(setq ang (- pi ang)))
            ((inters pcen pcen0 b (list (car b) (cadr a)))(setq ang (- pi ang)))
            ( t (setq ang (- (* 2 pi) ang)))
      )
      (setq col (1+ col))
      (if (= 7 col) (setq col 1))
      (command "change" obj "" "p" "c" col "")
      )
   )
  )
)
(princ "成功调入！  ***键入 pb 运行***")
(prin1)

账号		自动登录	找回密码
密码			注册

让我们共同走进CAD的动画世界！新增-->时钟

本帖子中包含更多资源

评分

难道没有人对cad动态感兴趣吗？

一个拖动的例子

“屏幕蹦蹦球”与大家一同分享！

评分