[求助]怎么修改一个INSERT中的HATCH的比例？

SWAYWOOD

我现在有很多的图块，每个图块分别在每个DWG中，我现在想请教的是如何将一个块中的填充图案的比例调整到一个统一的比例，如0.5并进行更新，我试了，发现DXF表是更新了，但图中还是没有变。由于公司的DWG文件是加密的，没有办法传上来，可以自己随便做一个块试试，谢谢了！

SWAYWOOD

大侠们帮帮忙呀!

龙龙仔

要改block定義

SWAYWOOD

龙哥能否给个相关的例子，block用ENTMOD更新吗，还是什么其它 的函数？

caoyin

用vlax-for遍历块定义对象，这样的例子很多，搜一下试试

SWAYWOOD

遍历块我知道，但怎么修改并保存，并且在INSERT中更新，请指条路。

龙龙仔

(defun C:TT ()
  (vlax-for VOBJ
     (vla-item
       (vla-get-blocks
  (vla-get-activedocument
    (vlax-get-acad-object)
  )
       )
       (vla-get-name (vlax-ename->vla-object (car (entsel))))
     )
    (if (= (vla-get-objectname VOBJ) "AcDbHatch")
      (vla-put-patternscale VOBJ 0.1)
    )
  )
  (command "_.regen")
  (princ)
)

(defun C:TTT ()
  (vlax-for VOBJ (vla-get-blocks
     (vla-get-activedocument
       (vlax-get-acad-object)
     )
   )
    (vlax-for VVOBJ VOBJ
      (if (= (vla-get-objectname VVOBJ) "AcDbHatch")
 (vla-put-patternscale VVOBJ 0.1)
      )
    )
  )
  (command "_.regen")
  (princ)
)

SWAYWOOD

还有这样的搞法，学习了，看来几年不写程序真是落伍了，谢谢龙哥！！！

SWAYWOOD

龙哥，我想同时将块其中的ATTDEF的标记修改为一个定值，比如：XXX，要怎么加语句？

龙龙仔

;;注意程序沒有修改固定屬性

;;(TTTT "比例" "XXX")

;;(TTTT <屬性提示> <值>)
(defun TTTT (TAG STR)
  (vlax-for VVOBJ (vla-get-blocks
      (vla-get-activedocument
        (vlax-get-acad-object)
      )
    )
    (vlax-for VOBJ VVOBJ
     ;|
      (if (= (vla-get-objectname VVOBJ) "AcDbHatch")
 (vla-put-patternscale VVOBJ 0.1)
      )|;
      (if (and (= (vla-get-objectname VOBJ) "AcDbBlockReference")
        (= (vla-get-hasattributes VOBJ) :vlax-true)
   )
 (foreach ENT (vlax-safearray->list
         (vlax-variant-value (vla-getattributes VOBJ))
       )
   (if (= (strcase (vla-get-tagstring ENT)) (strcase TAG))
     (vla-put-textstring ENT STR)
   )
 )
      )
    )
  )
  (command "_.regen")
  (princ)
)