[求助]如何批量修改标注尺寸值同时加（或减）一个数值

yansu · 发表于 2009-12-3 13:14:00

请高手帮忙，如何批量修改标注尺寸值，使选中的尺寸值同时加（或减）一个数值。谢谢

liminnet · 发表于 2009-12-3 17:47:00

提示: 作者被禁止或删除内容自动屏蔽

carrot1983 · 发表于 2009-12-4 10:55:00

(defun c:dimdd (/ measure plus real result ss text)
(vl-load-com)
(vla-endundomark
(vla-get-activedocument
(vlax-get-acad-object)
)
)
(vla-startundomark
(vla-get-activedocument
(vlax-get-acad-object)
)
)
(princ "\n★批量增减标注尺寸值 by carrot1983 [12/4/09]")
(setq plus (getreal "\n输入增值<100.>: "))
(if (and (cond ((null plus) (setq plus 100.))
((eq plus 0) nil)
(t)
)
(setq ss (ssget '((0 . "DIMENSION"))))
)
(foreach obj
(mapcar
'vlax-ename->vla-object
(vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
)
(if (and (setq text (vla-get-textoverride obj))
(setq measure (vla-get-measurement obj))
(/= text "")
(numberp (read text))
)
(setq real (read text))
(setq real measure)
)
(and real
(setq result (vl-princ-to-string (+ real plus)))
(vla-put-textoverride obj result)
)
)
)
(vla-endundomark
(vla-get-activedocument
(vlax-get-acad-object)
)
)
(princ)
)
(princ "\n本程序作者: carrot1983 转贴请注明出处、作者.")
(princ "\n本程序作命令: dimdd")

(defun c:dimdd (/ measure plus real result ss text)
  (vl-load-com)
  (vla-endundomark
    (vla-get-activedocument
      (vlax-get-acad-object)
    )
  )
  (vla-startundomark
    (vla-get-activedocument
      (vlax-get-acad-object)
    )
  )
  (princ "\n★批量增减标注尺寸值 by carrot1983 [12/4/09]")
  (setq plus (getreal "\n输入增值<100.>: "))
  (if (and (cond ((null plus) (setq plus 100.))
   ((eq plus 0) nil)
   (t)
    )
    (setq ss (ssget '((0 . "DIMENSION"))))
      )
    (foreach obj
   (mapcar
     'vlax-ename->vla-object
     (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
   )
      (if (and (setq text (vla-get-textoverride obj))
        (setq measure (vla-get-measurement obj))
        (/= text "")
        (numberp (read text))
   )
 (setq real (read text))
 (setq real measure)
      )
      (and real
    (setq result (vl-princ-to-string (+ real plus)))
    (vla-put-textoverride obj result)
      )
    )
  )
  (vla-endundomark
    (vla-get-activedocument
      (vlax-get-acad-object)
    )
  )
  (princ)
)
(princ "\n本程序作者: carrot1983 转贴请注明出处、作者.")
(princ "\n本程序作命令: dimdd")

wuxuloveguo · 发表于 2009-12-4 11:28:00

支持萝卜头！不错！能够满足楼主要求！

2楼的又是让加QQ？。。。。。。

navsun · 发表于 2009-12-4 11:33:00

就是，鄙视之，好像在给QQ公司打广告。
发一个可以批量修改标注的程序，而且可以恢复默认尺寸。

(setq txt_de "100")
(setq dde_mrbl 1)
(defun c:de (/ ss txt)
(setvar "cmdecho" 0) (princ "\n 选择需修改文本的标注:")
(setq ss (ssget '((0 . "DIMENSION"))))
(if ss (progn (princ "\n 请输入字符（空格＝恢复）<"")(princ txt_de)
(setq txt (getstring T "">:"))
(cond ((= txt " ")(setq txt ""))
((= txt "")(setq txt txt_de))
(T (setq txt_de txt)))
(command "dimedit" "n" txt "p" "")
)) (SETVAR "CMDECHO" 1)(princ)
)

yansu · 发表于 2009-12-9 06:43:00

非常感谢大家的帮助，3楼的满足要求，只是如何修改标注精度，例如不要小数，

skyxh06 · 发表于 2009-12-10 14:03:00

长见识了

nanguohappy · 发表于 2011-6-28 11:58:14

这个很好的功能啊

流动的清泉 · 发表于 2018-1-5 09:18:33

如果能改标注的实际长度就好了。

注册 · 发表于 2022-12-2 10:54:19

carrot1983 发表于 2009-12-4 10:55

如果去掉增加以后数字后面的小数点及后一位啊？

账号		自动登录	找回密码
密码			注册

liminnet liminnet 当前离线积分 9742 明经币个注册时间 2007-8-22 在线时间小时威望金钱个贡献激情	发表于 2009-12-3 17:47:00 \| 显示全部楼层提示: 作者被禁止或删除内容自动屏蔽

	回复支持反对使用道具举报显身卡