[已解决]如何用Vlisp中的ActiveX方法创建选择集?

wangqin

如何用Vlisp中的ActiveX方法创建选择集?

xianaihua

将选择集内的对象的颜色变为蓝色

3. (defun selectionvl (/ ssets acadDocument newsset ctr item)
4.      ;load the visual lisp extensions
5.   (vl-load-com)
6.      ;retrieve a reference to the documents object
7.   (setq acadDocument
8.   (vla-get-activedocument
9.     (vlax-get-acad-object)
10.   )
11.   )
12.      ;retrieve a reference to the selection sets object
13.   (setq ssets (vla-get-selectionsets acadDocument))
14.      ;add a new selection set
15.   (setq newsset (vla-add ssets "SS1"))
16.      ;select your new selection set objects
17.   (vla-selectOnScreen newsset)
18.      ;set the counter to zero
19.   (setq ctr 0)
20.      ;count the number of objects and loop
21.   (repeat (vla-get-count newsset)
22.      ;retrieve each object
23.     (setq item (vla-item newsset ctr))
24.      ;check if the entity has a color property
25.      ;and it can be updated
26.     (setq check (vlax-property-available-p item "Color" T))
27.      ;if it can
28.     (if check
29.      ;change it's color
30.       (vlax-put-property item 'Color 5)
31.     )     ;if
32.      ;increment the counter
33.     (setq ctr (1+ ctr))
34.   )     ;repeat
35.      ;delete the selection set
36.   (vla-delete (vla-item ssets "SS1"))
37.   (princ)
38. )     ;defun
39. (princ)

(defun selectionvl (/ ssets acadDocument newsset ctr item)      ;load the visual lisp extensions   (vl-load-com)      ;retrieve a reference to the documents object   (setq acadDocument   (vla-get-activedocument     (vlax-get-acad-object)   )   )      ;retrieve a reference to the selection sets object   (setq ssets (vla-get-selectionsets acadDocument))      ;add a new selection set   (setq newsset (vla-add ssets "SS1"))      ;select your new selection set objects   (vla-selectOnScreen newsset)      ;set the counter to zero   (setq ctr 0)      ;count the number of objects and loop   (repeat (vla-get-count newsset)      ;retrieve each object     (setq item (vla-item newsset ctr))      ;check if the entity has a color property      ;and it can be updated     (setq check (vlax-property-available-p item "Color" T))      ;if it can     (if check      ;change it's color       (vlax-put-property item 'Color 5)     )     ;if      ;increment the counter     (setq ctr (1+ ctr))   )     ;repeat      ;delete the selection set   (vla-delete (vla-item ssets "SS1"))   (princ) )     ;defun (princ)

xianaihua

带过滤的选择集：
(setq newsset (ssget '((8 . "7"))))

2. (defun selectionvl (/   ssets       acadDocument newsset
3.       ctr   item       filter_code  filter_value
4.      )
5.      ;load the visual lisp extensions
6.   (vl-load-com)
7.      ;retrieve a reference to the documents object
8.   (setq acadDocument
9.   (vla-get-activedocument
10.     (vlax-get-acad-object)
11.   )
12.   )
13.      ;retrieve a reference to the selection sets object
14.   (setq ssets (vla-get-selectionsets acadDocument))
15.      ;add a new selection set
16.   (setq newsset (vla-add ssets "SS1"))
17.      ;create a single element array for the DXF Code
18.   (setq filter_code (vlax-make-safearray vlax-vbinteger '(0 . 0)))
19.      ;create a single element array for the value
20.   (setq filter_value (vlax-make-safearray vlax-vbvariant '(0 . 0)))
21.      ;DXF Code for layers
22.   (vlax-safearray-fill filter_code '(8))
23.      ;the filter value
24.   (vlax-safearray-fill filter_value '("7"))
25.      ;Use Select on Screen to select objects on Layer 7
26.   (vla-selectOnScreen newsset filter_code filter_value)
27.      ;set the counter to zero
28.   (setq ctr 0)
29.      ;count the number of objects and loop
30.   (repeat (vla-get-count newsset)
31.      ;retrieve each object
32.     (setq item (vla-item newsset ctr))
33.      ;check if the entity has a color property
34.      ;and it can be updated
35.     (setq check (vlax-property-available-p item "Color" T))
36.      ;if it can
37.     (if check
38.      ;change it's color
39.       (vlax-put-property item 'Color 5)
40.     )     ;if
41.      ;increment the counter
42.     (setq ctr (1+ ctr))
43.   )     ;repeat
44.      ;delete the selection set
45.   (vla-delete (vla-item ssets "SS1"))
46.   (princ)
47. )

(defun selectionvl (/   ssets       acadDocument newsset       ctr   item       filter_code  filter_value      )      ;load the visual lisp extensions   (vl-load-com)      ;retrieve a reference to the documents object   (setq acadDocument   (vla-get-activedocument     (vlax-get-acad-object)   )   )      ;retrieve a reference to the selection sets object   (setq ssets (vla-get-selectionsets acadDocument))      ;add a new selection set   (setq newsset (vla-add ssets "SS1"))      ;create a single element array for the DXF Code   (setq filter_code (vlax-make-safearray vlax-vbinteger '(0 . 0)))      ;create a single element array for the value   (setq filter_value (vlax-make-safearray vlax-vbvariant '(0 . 0)))      ;DXF Code for layers   (vlax-safearray-fill filter_code '(8))      ;the filter value   (vlax-safearray-fill filter_value '("7"))      ;Use Select on Screen to select objects on Layer 7   (vla-selectOnScreen newsset filter_code filter_value)      ;set the counter to zero   (setq ctr 0)      ;count the number of objects and loop   (repeat (vla-get-count newsset)      ;retrieve each object     (setq item (vla-item newsset ctr))      ;check if the entity has a color property      ;and it can be updated     (setq check (vlax-property-available-p item "Color" T))      ;if it can     (if check      ;change it's color       (vlax-put-property item 'Color 5)     )     ;if      ;increment the counter     (setq ctr (1+ ctr))   )     ;repeat      ;delete the selection set   (vla-delete (vla-item ssets "SS1"))   (princ) )

wangqin

非常感谢,我一直认为创建选择集的方法为VLA-AddSelectionSets,做了很长时间没做出来 ,另外,添加实体到选择集中的方法除本程序所提供的vla-selectOnScreen(屏幕选择)外,AddItems Items 方法应该也可以吧。

xianaihua

你说的对，可以的