如何获得boundary后的新生成的物体？

xyz002 · 发表于 2009-12-22 00:15

本帖最后由作者于 2009-12-22 9:10:29 编辑

怎么才能获得boundary后的所有物体或新生成的物体的选择集,然后转移到其它图层？下面的程序实现不了，问题出在哪？

(defun c:tt()
(setq ss1 (ssget "X"))
(command "boundary")
(setq ss2 (ssget "_P"))
(command "select" SS2 "r" SS1 "")
)

sdls · 发表于 2019-9-20 23:21

感谢楼主的问题，感谢版主的解答！谢谢！！！

xiaoniao7619 · 发表于 2019-6-11 19:56

学习了，多谢

phoenixdjq · 发表于 2009-12-22 08:39

(entlast)

xyz002 · 发表于 2009-12-22 09:16

是这样么，还是不行啊

(defun c:tt()
(command "boundary")
(setq ent (entlast))
(command "change" ent "" "p" "la" "1" "")
)

xhq1954425 · 发表于 2009-12-22 10:30

(defun c:tt()
(setq p (getpoint"\n拾取封闭线框内部点:"))
(command "BOUNDARY" "A" "O" "P" "I" "N" "" "" p "")
(setq ent (entlast))
(command "change" ent "" "p" "la" "图层1" "")
)

caoyin · 发表于 2009-12-22 11:26

先 entlast

然后 BOUNDARY

最后 entnext

这是老问题了，在论坛上搜一下

xyz002 · 发表于 2009-12-22 11:47

谢谢xhq1954425帮助，按照你的程序能够获得边界并转移到新图层。不过对于不是封闭的多边形，点内部点会选择到外面的封闭多边形。我想要的是：点某个多边形（不管是封闭与否）内部点时，会出现虚线框，以便确认是否是对该多边形执行boundary，如果不是封闭的，会在其外面的闭合多边形上出现虚线框，以便检查使之封闭，然后再boundary。

如果去掉(command "BOUNDARY" "A" "O" "P" "I" "N" "" "" p "")最后的""，能够出现虚线框，但(setq ent (entlast)) 语句选不中boundary后新生成的边界，实现不了转移图层的目的，这是什么原因呢？如何才能实现？

xyz002 · 发表于 2009-12-22 12:04

caoyin版主说的我也试了，

(defun c:tt()
(setq ent (entlast))
(setq p (getpoint))
(command "boundary" p "")
(setq ss (ssadd))
(while (setq ent (entnext ent))
(ssadd ent ss)
)
(command "change" ss "" "p" "la" "图层1" "")
)

但只要去掉(command "boundary" p "") 最后的" "，还是不能选中boundary后的边界，也就不能转移到新图层了

caoyin · 发表于 2009-12-22 23:56

;;;--------------------------------
(defun ttt (en / ss)
(if en
    (progn
      (setq ss (ssadd))
      (while (setq en (entnext en))
        (if (not (member (cdr (assoc 0 (entget en)))
                         '("ATTRIB" "VERTEX" "SEQEND")
                 )
            )
          (ssadd en ss)
        )
      )
      (if (zerop (sslength ss)) (setq ss nil))
      ss
    )
    (ssget "_x")
)
)

;;;--------------------------------
(defun c:tt (/ la p e ss)
(setq la (getvar 'clayer))
(setvar 'clayer "图层1")
(setq p(getpoint "\n指定内部点: "))
(setq e (entlast))
(vl-cmdf "_.bpoly" p "")
(or (setq ss (ttt e))
(alert "* 错误 *\n\n未找到有限边界。\n\n边界不闭合，或边界对象不可访问。")
)
(setvar 'clayer la)
ss
)

xyz002 · 发表于 2009-12-23 13:06

多谢caoyin版主

xhq1954425 · 发表于 2009-12-24 05:10

问一下，下面有一个单独的SS(红色的)是什么意思？看不懂！帮忙给解释一下！谢谢！

(defun c:tt (/ la p e ss)
(setq la (getvar 'clayer))
(setvar 'clayer "图层1")
(setq p(getpoint "\n指定内部点: "))
(setq e (entlast))
(vl-cmdf "_.bpoly" p "")
(or (setq ss (ttt e))
(alert "* 错误 *\n\n未找到有限边界。\n\n边界不闭合，或边界对象不可访问。")
)
(setvar 'clayer la)
ss
)

账号		自动登录	找回密码
密码			注册