请教陈大虾，这程序为什么不好用

LIHUISHUAN

程序目的：擦除重复的线条问题：一次选的对象过多，就会有一些线擦不掉，甚至一条也不擦 选的对象不多是可以用 千万指教！

龙龙仔

;;試試這個擦除重复物件
;| Programmed by Dave Aguilar
   DUPREM.LSP <c> 1994 Onyx Software

This program creates an list of entity lists for all entities in the
drawing (using the first VERTEX for POLYLINES) and then compares each
entity list with the total list, building a new selection set of all
duplicate entries which are then erased.

it's not guarenteed but try it on a copy of a badly duplicated drawing
and see if it helps.

------------------------------------------------------------------------
------------------------------------------------------------------------
Modified by J. Tippit, SPAUG President    08/25/99
    E-mail:                     cadpres@spaug.org
    Web Site:                http://www.spaug.org

1. Modified to work with R14 & 2000
2. Now prompts for 3 types of selection sets
3. Works on all types of entities (including LWPOLYLINES)

Large donations to SPAUG is appreciated. :)
------------------------------------------------------------------------
------------------------------------------------------------------------

|;

(defun C:DUPREM        (/ F1 SLE SA CA        TA LA LB ENTA EA TYPA A1 A2 A3 A4 SC
                 LTEST TES
                )
  (setvar "cmdecho" 0)
  (setq        F1 NIL
        F1 0
  )
  ;; Added by Jeff Tippit 08/25/99
  ;; Start
  (or :GCHOICE (setq :GCHOICE "Set"))
  (initget "Set Limits All")
;;;   (setq SLE (getkword "\nSelect objects by <S>election set, <L>imits, or <E>ntire database: "))
  (setq        SLE
         (getkword (strcat "\nType of selection [Set/Limits/All] <"
                           :GCHOICE
                           ">: "
                   )
         )
  )
  (if (not SLE)
    (setq SLE :GCHOICE)
    (setq :GCHOICE SLE)
  )
  (cond
    ((= SLE "Set") (setq SA (ssget)))
    ((= SLE "Limits")
     (setq SA (ssget "c" (getvar "extmin") (getvar "extmax")))
    )
    ((= SLE "All") (setq SA (ssget "X")))
  )

  (if (and SA (= (type SA) 'PICKSET) (not (zerop (sslength SA))))
    (progn
      (setq CA 0
            TA (sslength SA)
            LA NIL
            LB NIL
      )
      (while (< CA TA)
        (setq ENTA (ssname SA CA)
              EA   (cdr (entget ENTA))
              TYPA (cdr (assoc 0 EA))
        )
        ;;      (if (= typa "OLYLINE") (progn
        ;;         (setq entb (entnext enta) ea (cdr (entget entb)))
        ;;      ))
        ;; Added by Jeff Tippit 08/25/99
        ;; Updated for R14 & 2000
        ;; Start
        (setq A1 (assoc 5 EA))
        (setq A2 (cons 5 ""))
        (setq EA (subst A2 A1 EA))
        (if (wcmatch (getvar "ACADVER") "*15*")
          (progn
            (setq A3 (assoc 330 EA))
            (setq A4 (cons 330 ""))
            (setq EA (subst A4 A3 EA))
          )
        )

        (setq LA (cons ENTA LA)
              LB (cons EA LB)
              CA (+ CA 1)
        )
      )
      (setq SC          NIL
            SC          (ssadd)
            LTEST LB
      )
      (setq CA 0)
      (setq TES          (car LTEST)
            LTEST (cdr LTEST)
            TA          NIL
            TA          (length LTEST)
      )
      (while (/= TA 0)
        (if (member TES LTEST)
          (progn
            (setq SC (ssadd (nth CA LA) SC))
            (prompt "\nFound duplicate entity.")
            (setq F1 (+ F1 1))
          )
        )
        (setq CA (+ CA 1))
        (setq TES   (car LTEST)
              LTEST (cdr LTEST)
              TA    (length LTEST)
        )
      )
      (command "erase" SC "")
      (redraw)
      (prompt "\n")
      (prin1 F1)
      (prompt " duplicate entities erased.")
    )
  )
  (princ)
)
(prompt
  "\nType DUPREM to run. Delete duplicate entity routine Ver 2.0 loaded."
)
(princ)

LIHUISHUAN

谢谢龙哥，我先试一试

morecs

龙哥，这程序不好用，您试了吗？再来点中文注释好吗？谢谢！！！

龙龙仔

这程序那裡不好用可以說說嗎?

morecs

我用来消除重复得线、圆、圆弧，但不行，Set/Limits/All分别代表什么意思？我都试了，老是
0 duplicate entities erased.麻烦龙哥了！！！

citykunan

龙龙仔的程序不错，但好像对块就没用了。

BDYCAD

不能刪除的. 好象這里有幾條,但是效果麻麻地.

wb0815

龙龙仔的程序不错，太强了。我真的很需要。

lhr

龙龙仔你的程序太好了，而且非常实用。



但是能不能把有重叠的实体，亮显，呈选中状态。不用自动删除。


待查过之后再手工删除。


我只是担心不知删的是哪个实体，是否真的是无用的实体。


非常感谢！