请教各位老师：如何调用vba命令对多义线进行fit(拟合)处理？-->mccad转移

sdxylijian

我用vba绘制多义线LWPOLYLINE，但是我不会在vba中如何使刚绘制出来的LWPOLYLINE线条进行(fit)拟合处理，使线条光滑。请教各位，不胜感激！！！
                                           小李子

mccad

sdxylijian

请mccad老师详细指点。
能否列出一个具体的例程演示：
具体过程如下：
    先用vba建立多义线LWPOLYLINE，然后在vba中调用SendCommand命令对该多义线进行编辑-拟合(fit),整个过程程序自动完成，不需人为选择object或人为干预！
    请老师赐教！！！不胜感激！！！
                                             小李子

mccad

' 转换对象用自定义函数
Public Function axEnt2lspEnt(entObj As AcadEntity) As String
    Dim entHandle As String
    entHandle = entObj.Handle
    axEnt2lspEnt = "(handent " & Chr(34) & entHandle & Chr(34) & ")"
End Function

'执行主程序
Sub fitpline()

    ' 在模型空间创建细多义线。
    Dim plineObj As AcadLWPolyline
    Dim points(0 To 7) As Double
   
    points(0) = 3: points(1) = 7
    points(2) = 9: points(3) = 2
    points(4) = 3: points(5) = 5
    points(6) = 5: points(7) = 8
   
    Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
'    plineObj.Closed = True

'    进行拟合

   ThisDrawing.SendCommand "_PEdit" & vbCr & axEnt2lspEnt(plineObj) & vbCr & "f" & vbCr & vbCr
   ThisDrawing.SendCommand "_zoom" & vbCr & "e" & vbCr
   
End Sub

sdxylijian

mccad

mycad

mccad老师不是一般的牛！谢谢了，我也用到了。
顶！！！！！！！！！！！！！！！！！