[求助]用lisp调用vb把ANSI编码的文件转换成UTF-8

xiaoquansb

2. Private Sub Command1_Click()
3. Dim FileName As String, b() As Byte, S As String
4. Dim ADO_Stream As Object
5. FileName = App.Path & "\1.txt" '请修改为具体文件名
6. If Dir(FileName) = "" Then Exit Sub
7. ReDim b(FileLen(FileName))
8. Open FileName For Binary As #1
9. Get #1, , b
10. Close #1
11. S = StrConv(b, vbUnicode)
13. Set ADO_Stream = CreateObject("ADODB.Stream")
15. With ADO_Stream
16. .Type = 2
17. .Mode = 3
18. .Charset = "utf-8"
19. .open
20. .WriteText S
21. .SaveToFile FileName, 2
22. End With
24. Set ADO_Stream = Nothing
25. MsgBox "文件转换完毕！"
26. End Sub

Private Sub Command1_Click() Dim FileName As String, b() As Byte, S As String Dim ADO_Stream As Object FileName = App.Path & "\1.txt" '请修改为具体文件名 If Dir(FileName) = "" Then Exit Sub ReDim b(FileLen(FileName)) Open FileName For Binary As #1 Get #1, , b Close #1 S = StrConv(b, vbUnicode) Set ADO_Stream = CreateObject("ADODB.Stream") With ADO_Stream .Type = 2 .Mode = 3 .Charset = "utf-8" .open .WriteText S .SaveToFile FileName, 2 End With Set ADO_Stream = Nothing MsgBox "文件转换完毕！" End Sub

上面是一段vb程序源码，可把ANSI编码的文件转换成UTF-8
可怜小弟太菜，不懂vb，只懂一点lsp
哪位老师可代为修改一下，让lsp调用
对话框就不用了，给出文件地址，自动转换就可以了，不用什么提示的
先谢谢了

xshrimp

UTF-8编码的文件转换成ANSI
(xzj-file-WriteTextFile  "c:\\ansi.txt"   (xzj-file-ReadTextFile    "c:\\ansi.txt"  "utf-8")   "gb2312")

ANSI编码的文件转换成UTF-8

(xzj-file-WriteTextFile  "c:\\ansi.txt"   (xzj-file-ReadTextFile     "c:\\ansi.txt"  "gb2312")   "utf-8")


(defun xzj-file-ReadTextFile (File charset / encode filepath filestream)
  (if
    (and
      (setq FilePath   (findfile File))
      (setq FileStream (vlax-create-object "Adodb.Stream"))
    )
    (progn                        
      (vlax-put-property FileStream 'Type 2) ;1二进制读取 2文本模读取
      (vlax-put-property FileStream 'mode 3) ;1-读,2-写,3-读写
      (vlax-put-property FileStream 'charset charset)        ;unicode;utf-8;Ascii;gb2312;big5;gbk               
      (vlax-invoke FileStream 'Open)                        
      (vlax-invoke FileStream 'LoadFromFile filePath)                                
      (setq Encode (vlax-invoke FileStream 'readtext))
      (vlax-invoke FileStream 'close)
      (vlax-release-object FileStream)
      Encode
    )
  )
)(defun xzj-file-WriteTextFile (File charset str /  filestream)
;;;判断文件路径是否存在
(if (findfile (vl-filename-directory File))
     (if
          (setq FileStream (vlax-create-object "Adodb.Stream"))
          (progn                        
            (vlax-put-property FileStream 'Type 2) ;1二进制读取 2文本模读取
            (vlax-put-property FileStream 'mode 3) ;1-读,2-写,3-读写
            (vlax-put-property FileStream 'charset charset)        ;unicode;utf-8;Ascii;gb2312;big5;gbk               
            (vlax-invoke FileStream 'Open)
            (vlax-invoke FileStream 'WriteText str)                        
            (vlax-invoke FileStream 'SaveToFile File 2)
            (vlax-invoke FileStream 'flush)
            (vlax-invoke FileStream 'Close)                        
            (vlax-release-object FileStream)
            T                        
          )
      )
   (progn
     (princ "\n文件路径不存在,无法创建文件!")
      nil
   )   
)   
)

wudechao

xshrimp 发表于 2019-11-3 22:44
UTF-8编码的文件转换成ANSI
(xzj-file-WriteTextFile  "c:\\ansi.txt"   (xzj-file-ReadTextFile    "c:\\ ...

;我把它合并
;例如 (file-encode-trans  "c:\\ansi.txt"   "gb2312"    "utf-8")
(defun file-encode-trans (file charset1 charset2 / obj encode)
  (setq obj (vlax-create-object "ADODB.Stream"))
  (vlax-put-property obj 'type 2);1二进制读取 2文本模读取
  (vlax-put-property obj 'mode 3);1-读,2-写,3-读写
  (vlax-invoke obj 'open)
  (vlax-put-property obj "charset" charset1);;unicode;utf-8;ascii;gb2312;big5;gbk
  (vlax-invoke-method obj 'loadfromfile file)
  (setq encode (vlax-invoke obj 'readtext))
  (vlax-invoke obj 'close)
  (vlax-release-object obj)
  (setq obj (vlax-create-object "ADODB.Stream"))
  (vlax-put-property obj 'type 2);1二进制读取 2文本模读取
  (vlax-put-property obj 'mode 3);1-读,2-写,3-读写
  (vlax-invoke obj 'open)
  (vlax-put-property obj "charset" charset2);;unicode;utf-8;ascii;gb2312;big5;gbk
  (vlax-invoke obj 'writetext encode)
  (vlax-invoke-method obj 'savetofile file 2);1新建，2覆盖
  (vlax-invoke obj 'flush);将缓存中的数据强制输出
  (vlax-invoke obj 'close)
  (vlax-release-object obj)
)

xshrimp

检查文件的编码

;;命令: (GPS->CHECKCODE "c:\\unicode big endian.txt")

;;"unicode big endian"

;;命令: (GPS->CHECKCODE "c:\\unicode.txt")

;;"Unicode"

;;命令: (GPS->CHECKCODE "c:\\utf-8.txt")

;;"UTF-8"

;;命令: (GPS->CHECKCODE "c:\\ansi.txt")

;;"GB2312"

(gps->WriteToFile  "c:\\utf8.txt"  "Str" "utf-8")

(gps->ReadFile     "c:\\ansi.txt" "gb2312")

转化文件编码

ANSI编码的文件转换成UTF-8

(gps->gtu  "c:\\ansi.txt")

xiaoquansb

太感谢了

xshrimp

UTF-8编码的文件转换成ANSI

(gps->WriteToFile  "c:\\ansi.txt"   (gps->ReadFile     "c:\\ansi.txt"  "utf-8")   "gb2312")

ANSI编码的文件转换成UTF-8

(gps->WriteToFile  "c:\\ansi.txt"   (gps->ReadFile     "c:\\ansi.txt"  "gb2312")   "utf-8")

xiaoquansb

再次感谢xshrimp，这个对我来说太重要了

flowerson

xshrimp 发表于 2010-8-23 19:19
UTF-8编码的文件转换成ANSI(gps->WriteToFile  "c:\\ansi.txt"   (gps->ReadFile  ...

不知可否提供源码下载？可以收点明经币都可以。

flowerson

xshrimp 发表于 2019-11-3 22:44
[/code]

非常谢谢xshrimp。xzj-file-WriteTextFile 里面的三参数顺序 File charset str 应该是File  str charset对吧？

wudechao

flowerson 发表于 2019-11-4 01:15
非常谢谢xshrimp。xzj-file-WriteTextFile 里面的三参数顺序 File charset str 应该是File  str charset ...

确实如此！