[求助]获取多段线的点

3527188 · 发表于 2010-10-11 22:26:00

请问下高手这样的程序怎么可以实现。

图形变化多端的，点必须在闭合多段线里。

Gu_xl · 发表于 2010-10-11 22:57:00

没太整明白你要计算什么点？是不是要计算闭合多段线上等距间隔点向多段线内侧偏移一定距离的点呢？还是其他什么。。。请详细说清楚，这个应该不难！

Gu_xl · 发表于 2010-10-12 09:17:00

;;;(gxl-GetCurveTangent curve pt) 计算曲线上pt处切线方向角度，返回值弧度
;;;(gxl-GetCurveTangent (car (entsel)) (getpoint))
(defun gxl-GetCurveTangent (curve pt / param)
(setq param (vlax-curve-getParamAtPoint curve (setq pt (vlax-curve-getclosestpointto curve pt))))
(angle pt (mapcar '+ pt (vlax-curve-getFirstDeriv curve param)))
)
;;;(gxl-GetCurveNormal curve pt) 计算曲线上pt处法线方向角度，返回值弧度
;;;(gxl-GetCurveNormal (car (entsel)) (getpoint))
(defun gxl-GetCurveNormal (curve pt / param)
(GXL-NUM-TANG (+ (gxl-GetCurveTangent curve pt) pi2) 2pi)
)
;;生成一个LINE
;;gxl-MAKELINE 参数：pt1:起点，pt2:终点,均为三维点,即(x y z)
(DEFUN gxl-MAKELINE (PT1 PT2 /)
(setq pT1 (append '(10) pt1)
pT2 (append '(11) pt2)
)
(entmake (list
'(0
.
"LINE"
)
pT1
PT2
)
)
)
;;;(gxl-clock en) 判断Polyline是顺时钟还是逆时钟走，顺时钟 nil 逆时钟 T
;;;(gxl-Clock (car (entsel)))
(defun gxl-Clock (plineObj / fd ang offsetplineObj flag)
(setq plineObj (vlax-ename->vla-object plineObj))
;(setq fd (vlax-curve-getFirstDeriv plineObj 0.5))
;(setq ang (atan (/ (cadr fd) (car fd))))
(setq offsetplineObj
(car (vlax-safearray->list
(vlax-variant-value
(GXL-OFFSET plineObj 0.001)
) ;_ 结束vlax-variant-value
) ;_ 结束vlax-safearray->list
) ;_ 结束car
) ;_ 结束setq
(if (> (vlax-curve-getdistatparam
plineobj
(vlax-curve-getEndParam plineobj)
) ;_ 结束vlax-curve-getdistatparam
(vlax-curve-getdistatparam
offsetplineObj
(vlax-curve-getEndParam offsetplineObj)
) ;_ 结束vlax-curve-getdistatparam
) ;_ 结束>
(setq flag nil)
(setq flag T)
) ;_ 结束if
(vla-delete offsetplineObj)
flag
) ;_ 结束defun
;;;gxl-Offset 重定义 vla-offset 函数，避免在2004版下坐标大于10000时出错！
(defun gxl-Offset (obj d / Flag minpoint maxpoint acadver rtn)
(setq acadver (substr (getvar "acadver") 1 2))
(if (= 'ENAME (type obj))
(setq obj (vlax-ename->vla-object obj))
)
(vla-GetBoundingBox obj 'minpoint 'maxpoint)
(setq maxpoint (vlax-safearray->list maxpoint))
(if (or (>= (abs(car maxpoint)) 10000.0)(>= (abs(cadr maxpoint)) 10000.0))
(setq Flag t)
)
(cond ((and flag (= "16" acadver) (= (vla-get-ObjectName obj) "AcDbPolyline"))
(vla-move obj minpoint (vlax-3d-point '(0 0 0)))
(setq rtn (VL-CATCH-ALL-APPLY 'vla-Offset (list obj d)))
(if (not (VL-CATCH-ALL-ERROR-P rtn))
(progn
(vla-move obj (vlax-3d-point '(0 0 0)) minpoint)
(vla-move (vlax-ename->vla-object (entlast)) (vlax-3d-point '(0 0 0)) minpoint)
)
)
rtn
)
(t
(VL-CATCH-ALL-APPLY 'vla-Offset (list obj d))
)
)
)
;;;计算曲线长度 (gxl-GetCurveLenth en)
;;; (gxl-GetCurveLenth (car (entsel)))
(defun gxl-GetCurveLength (en / obj)
(vlax-curve-getdistatparam en (vlax-curve-getEndParam en))
) ;_ 结束defun
(defun c:tt(/ cmdecho osmode en flag jj pj dist p1 pt pts)
(setq cmdecho (getvar "cmdecho")
osmode (getvar "osmode")
)
(setvar "cmdecho" 0)
(setvar "osmode" 0)
(princ "\n选择曲线：")
(setq en (car (entsel)))
(setq flag (gxl-Clock en))
(setq jj (getreal " \n输入间距：")
pj (getreal " \n输入偏距：")
)
(setq CurveLength (GXL-GETCURVELENGTH en)
dist jj)
(while (< dist CurveLength)
(setq pt (vlax-curve-getPointAtDist en dist)
ang (GXL-GETCURVENORMAL en pt)
)
(setq p1 (polar pt (if (not flag) (+ ang pi) ang) pj))
(GXL-MAKELINE pt p1)
(setq pts (cons p1 pts))
(setq dist (+ dist jj))
)
(setvar "cmdecho" cmdecho)
(setvar "osmode" osmode)
(reverse pts)
)

;;;(gxl-GetCurveTangent curve pt) 计算曲线上pt处切线方向角度，返回值 弧度
;;;(gxl-GetCurveTangent (car (entsel)) (getpoint))
(defun gxl-GetCurveTangent (curve pt / param)
  (setq param (vlax-curve-getParamAtPoint curve (setq pt (vlax-curve-getclosestpointto curve pt))))
  (angle pt (mapcar '+ pt (vlax-curve-getFirstDeriv curve param))) 
  )
;;;(gxl-GetCurveNormal curve pt) 计算曲线上pt处法线方向角度，返回值 弧度
;;;(gxl-GetCurveNormal (car (entsel)) (getpoint))
(defun gxl-GetCurveNormal (curve pt / param)
  (GXL-NUM-TANG (+ (gxl-GetCurveTangent curve pt) pi2) 2pi)
  )
;;生成一个LINE
;;gxl-MAKELINE 参数：pt1:起点，pt2:终点,均为三维点,即(x y z)
(DEFUN gxl-MAKELINE (PT1 PT2 /)
  (setq pT1 (append '(10) pt1)
 pT2 (append '(11) pt2)
  )
  (entmake (list
      '(0
        .
        "LINE"
       )
      pT1
      PT2
    )
  )
  
)
;;;(gxl-clock en) 判断Polyline是顺时钟还是逆时钟走，顺时钟 nil 逆时钟 T
;;;(gxl-Clock (car (entsel)))
(defun gxl-Clock (plineObj / fd ang offsetplineObj flag)
  (setq plineObj (vlax-ename->vla-object plineObj))
  ;(setq fd (vlax-curve-getFirstDeriv plineObj 0.5))
  ;(setq ang (atan (/ (cadr fd) (car fd))))
  (setq offsetplineObj
  (car (vlax-safearray->list
  (vlax-variant-value
    (GXL-OFFSET plineObj 0.001)
  ) ;_ 结束vlax-variant-value
       ) ;_ 结束vlax-safearray->list
  ) ;_ 结束car
  ) ;_ 结束setq 
  (if (> (vlax-curve-getdistatparam
    plineobj
    (vlax-curve-getEndParam plineobj)
  ) ;_ 结束vlax-curve-getdistatparam
  (vlax-curve-getdistatparam
    offsetplineObj
    (vlax-curve-getEndParam offsetplineObj)
  ) ;_ 结束vlax-curve-getdistatparam
      ) ;_ 结束>
    (setq flag nil)
    (setq flag T)
  ) ;_ 结束if
  (vla-delete offsetplineObj)
  flag
) ;_ 结束defun
;;;gxl-Offset 重定义 vla-offset 函数，避免在2004版下坐标大于10000时出错！
(defun gxl-Offset (obj d / Flag minpoint maxpoint acadver rtn)
  (setq acadver (substr (getvar "acadver") 1 2))
  (if (= 'ENAME (type obj))
    (setq obj (vlax-ename->vla-object obj))
    )
  (vla-GetBoundingBox obj 'minpoint 'maxpoint)
  (setq maxpoint (vlax-safearray->list maxpoint))
  (if (or (>= (abs(car maxpoint)) 10000.0)(>= (abs(cadr maxpoint)) 10000.0))
    (setq Flag t)
    )
  (cond ((and flag (= "16" acadver) (= (vla-get-ObjectName obj) "AcDbPolyline"))
  (vla-move obj minpoint (vlax-3d-point '(0 0 0)))
  (setq rtn (VL-CATCH-ALL-APPLY 'vla-Offset  (list obj d)))
  (if (not (VL-CATCH-ALL-ERROR-P rtn))
    (progn
  (vla-move obj (vlax-3d-point '(0 0 0)) minpoint)
  (vla-move (vlax-ename->vla-object (entlast)) (vlax-3d-point '(0 0 0)) minpoint)
  )
    )
  rtn
  )
 (t
  (VL-CATCH-ALL-APPLY 'vla-Offset  (list obj d))
  )
 )
  )
;;;计算曲线长度 (gxl-GetCurveLenth en)
;;; (gxl-GetCurveLenth (car (entsel)))
(defun gxl-GetCurveLength (en / obj)
  (vlax-curve-getdistatparam en (vlax-curve-getEndParam en))
) ;_ 结束defun
(defun c:tt(/ cmdecho osmode en flag jj pj dist p1 pt pts)
  (setq cmdecho (getvar "cmdecho")
 osmode (getvar "osmode")
 )
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (princ "\n选择曲线：")
  (setq en (car (entsel)))
  (setq flag (gxl-Clock en))
  (setq jj (getreal " \n输入间距：")
 pj (getreal " \n输入偏距：")
 )
  (setq CurveLength (GXL-GETCURVELENGTH en)
 dist jj)
  (while (< dist CurveLength)
    (setq pt (vlax-curve-getPointAtDist en dist)
   ang (GXL-GETCURVENORMAL en pt)
   )
    (setq p1 (polar pt (if (not flag) (+ ang pi) ang) pj))
    (GXL-MAKELINE pt p1)
    (setq pts (cons p1 pts))
    (setq dist (+ dist jj))
    )
    (setvar "cmdecho" cmdecho)
  (setvar "osmode" osmode)
  (reverse pts)
 
  )

调用命令：tt

3527188 · 发表于 2010-10-12 09:27:00

谢谢关注····

我需要找出的是这些圆的点，

这些点都是有规律的等距

3527188 · 发表于 2010-10-12 09:31:00

程序不能完整运行

Gu_xl · 发表于 2010-10-12 10:15:00

有何提示？

Gu_xl · 发表于 2010-10-12 10:38:00

补上一个函数,应该可以了

;;;==================================================================
;;;gxl-Num-TAng 角度相除取余
;;;==================================================================
(defun gxl-Num-TAng (ang sty / n)
(if (not *jd*) (setq *jd* 1e-5))
(setq n (rem (+ (* 2 pi) ang) sty))
(if (equal n sty *jd*)
0.0
n)
)

3527188 · 发表于 2010-10-12 17:58:00

(defun gxl-GetCurveNormal (curve pt / param)

(GXL-NUM-TANG (+ (gxl-GetCurveTangent curve pt) pi2) 2pi)

)

pi2 2pi

是怎么来的？还有好几个自定义函数都么有

Gu_xl · 发表于 2010-10-12 18:33:00

(setq pi2 (/ pi 2.0) 2pi (* 2 pi))

yoyoho · 发表于 2010-10-12 20:03:00

感谢Gu_xl分享程序,谢谢!

账号		自动登录	找回密码
密码			注册

[讨论] [求助]获取多段线的点

本帖子中包含更多资源