高手们帮忙编个程序---“标注尺寸箭头变圆点”

lsj2004

程序要求：变圆点有三种情况，1、将箭头1变为圆点。2、将箭头2变为圆点。3、将箭头1和2均变为圆点。
只要能实现这三个要求就OK了。
请各个高手们帮一下忙！谢谢！

caoyin

(defun c:tt (/ OBJ)
(setq OBJ (vlax-ename->vla-object (car(entsel))))
;;下面两行3是大圆点，4是小圆点
(vla-put-Arrowhead1Type OBJ 3);;第1个箭头
(vla-put-Arrowhead2Type OBJ 3);;第2个箭头
)

lsj2004

回复 caoyin 的帖子

谢谢，程序非常好用！但能否再将程序人性化，因为有时需要各别的尺寸一端是圆点，另一端是箭头或者是无箭头。原来咱们网站上郑大师有一个VBA的程序，挺好用，只不过在CAD2010和2011里需要再单独安装VBA程序。他的程序是有一个界面可以控制实现此功能，我将界面图片上来，你帮忙参考一下，看看是否程序可以修改一下。

caoyin

;;方法告诉你了，自己要学会动手
(defun c:tt (/ OBJ KW)
  (if (and (setq OBJ (entsel "\n选择标注对象: "))
           (progn
             (setq OBJ (vlax-ename->vla-object (car OBJ)))
             (or (wcmatch (vla-get-ObjectName OBJ) "*Dimension")
                 (progn (princ "\n必须选择标注对象!") nil)
             )
           )
      )
    (progn
      (initget "Start End Both")
      (or (setq KW (getkword "\n指定要修改的箭头[起始箭头(S)\结束箭头(E)\两者(B)] <两者>: "))
          (setq KW "Both")
      )
      (cond ((if (member KW '("Start" "Both"))
               (progn (vla-put-Arrowhead1Type OBJ 3) nil)
             )
            )
            ((member KW '("End" "Both"))
             (vla-put-Arrowhead2Type OBJ 3)
            )
      )
    )
  )
  (princ)
)

xyp1964