CAD拼图

vexation · 发表于 2011-8-9 21:01

有没有什么办法,我在拼图的时候,让他只拼指定的图层名称啊?比如:"TK"层,把所有的图都拼起来太慢了``

vexation · 发表于 2011-8-11 11:16

浏览的人不少啊，怎么就没人回答呢？难道这个问题不可以实现吗？？

Gu_xl · 发表于 2011-8-11 12:39

回复 vexation 的帖子

http://lee-mac.com/steal.html

vexation · 发表于 2011-8-12 10:04

谢谢Gu_xl斑主,但是貌似我看不懂啊.`

gogo风铃之音 · 发表于 2011-8-12 14:39

抱歉，弄不懂您到底想要达到怎样的效果。怎么个拼法？

Gu_xl · 发表于 2011-8-12 15:33

回复 vexation 的帖子

;;;从DWG文件复制图层数据明经通道 Gu_xl 2011.08.12
(prompt "\r*** 命令：copylayers 从DWG文件复制图层数据 By 明经通道: Gu_xl 2011.08.12***")
(defun c:copylayers (/ DwgName DBXDOC DBXModelSpace
blocks blocknames dbxblocknames
dcfname file dc fl
ptr block norm pt
layers objlst dbxlayers i
all)
(setq DwgName (GETFILED "选择DWG文件" "" "dwg" 4))
(if
(not
(equal
(strcase DwgName)
(strcase (strcat (getvar "dwgprefix") (getvar "dwgname")))
)
)
(progn
(setq DBXDOC
(vla-GetInterfaceObject
(vlax-get-acad-object)
(if (< (setq acVer (atoi (getvar "ACADVER"))) 16)
"ObjectDBX.AxDbDocument"
(strcat "ObjectDBX.AxDbDocument." (itoa acVer))
)
))
(vla-open DBXDOC DWGNAME)
(setq DBXModelSpace (vla-get-ModelSpace DBXDOC))
(vlax-for lay (vla-get-layers DBXDOC)
(setq dbxlayers (cons (vla-get-name lay) dbxlayers))
)
(setq dcfname (vl-filename-mktemp nil nil ".dcl"))
(if (setq file (open dcfname "w"))
(progn
(write-line
"copylayers : dialog
{ label = \"选择复制图层 By 明经通道: Gu_xl \";
spacer;
: list_box { key = \"layers\"; multiple_select = true;}
spacer;
: row
{
: button { key = \"selectall\"; label = \"全选\";}
: button { key = \"clearall\"; label = \"清除选择\";}
}
ok_cancel;}"
file)
(close file)
)
)
(setq dc (load_dialog dcfname))
(setq i 0)
(new_dialog "copylayers" dc)
(start_list "layers")
(foreach n dbxlayers
(add_list n)
(if all
(setq all (strcat all " " (itoa i)))
(setq all (itoa i))
)
(setq i (1+ i))
)
(end_list)
(set_tile "layers" "0")
(setq ptr nil)
(action_tile "layers" "(setq ptr $value)")
(action_tile
"selectall"
"(set_tile \"layers\" all) (setq ptr all)")
(action_tile
"clearall"
"(set_tile \"layers\" \"\") (setq ptr nil)")
(setq fl (start_dialog)
dc (unload_dialog dc))
(if (and ptr (= 1 fl))
(progn
(setq layers (mapcar '(lambda (x) (nth x dbxlayers))
(read (strcat "(" ptr ")"))))
(vlax-for obj DBXModelSpace
(if (member (vla-get-layer obj) layers)
(setq objlst (cons obj objlst))
)
)
(vla-CopyObjects
dbxDoc
(vlax-make-variant
(vlax-safearray-fill
(vlax-make-safearray
vlax-vbObject
(cons 0 (1- (length objlst))))
objlst
)
)
(vla-get-ModelSpace
(vla-get-ActiveDocument (vlax-get-acad-object)))
)
)
(princ "\n*Cancel*")
)
)
)
(princ)
)

;;;从DWG文件复制图层数据 明经通道 Gu_xl 2011.08.12 
(prompt "\r*** 命令：copylayers 从DWG文件复制图层数据 By 明经通道: Gu_xl 2011.08.12***") 
(defun c:copylayers  (/   DwgName    DBXDOC     DBXModelSpace 
        blocks  blocknames dbxblocknames 
        dcfname  file     dc        fl 
        ptr  block     norm       pt 
        layers  objlst     dbxlayers  i 
        all) 
  (setq DwgName (GETFILED "选择DWG文件" "" "dwg" 4)) 
  (if 
    (not 
      (equal 
 (strcase DwgName) 
 (strcase (strcat (getvar "dwgprefix") (getvar "dwgname"))) 
 ) 
      ) 
     (progn 
       (setq DBXDOC 
       (vla-GetInterfaceObject 
  (vlax-get-acad-object) 
  (if (< (setq acVer (atoi (getvar "ACADVER"))) 16) 
    "ObjectDBX.AxDbDocument" 
    (strcat "ObjectDBX.AxDbDocument." (itoa acVer)) 
    ) 
  )) 
       (vla-open DBXDOC DWGNAME) 
       (setq DBXModelSpace (vla-get-ModelSpace DBXDOC)) 
       (vlax-for lay  (vla-get-layers DBXDOC) 
  (setq dbxlayers (cons (vla-get-name lay) dbxlayers)) 
  ) 
       (setq dcfname (vl-filename-mktemp nil nil ".dcl")) 
       (if (setq file (open dcfname "w")) 
  (progn 
    (write-line 
      "copylayers : dialog 
              { label = \"选择复制图层 By 明经通道: Gu_xl \"; 
              spacer; 
              : list_box { key = \"layers\"; multiple_select = true;} 
              spacer; 
              : row 
              { 
              : button { key = \"selectall\"; label = \"全选\";} 
              : button { key = \"clearall\"; label = \"清除选择\";} 
              } 
              ok_cancel;}" 
      file) 
    (close file) 
    ) 
  ) 
       (setq dc (load_dialog dcfname)) 
       (setq i 0) 
       (new_dialog "copylayers" dc) 
       (start_list "layers") 
       (foreach n  dbxlayers 
  (add_list n) 
  (if all 
    (setq all (strcat all " " (itoa i))) 
    (setq all (itoa i)) 
    ) 
  (setq i (1+ i)) 
  ) 
       (end_list) 
       (set_tile "layers" "0") 
       (setq ptr nil) 
       (action_tile "layers" "(setq ptr $value)") 
       (action_tile 
  "selectall" 
  "(set_tile \"layers\" all) (setq ptr all)") 
       (action_tile 
  "clearall" 
  "(set_tile \"layers\" \"\") (setq ptr nil)") 
       (setq fl (start_dialog) 
      dc (unload_dialog dc)) 
       (if (and ptr (= 1 fl)) 
  (progn 
    (setq layers (mapcar '(lambda (x) (nth x dbxlayers)) 
    (read (strcat "(" ptr ")")))) 
    (vlax-for obj  DBXModelSpace 
      (if (member (vla-get-layer obj) layers) 
        (setq objlst (cons obj objlst)) 
        ) 
      ) 
    (vla-CopyObjects 
      dbxDoc 
      (vlax-make-variant 
        (vlax-safearray-fill 
   (vlax-make-safearray 
     vlax-vbObject 
     (cons 0 (1- (length objlst)))) 
   objlst 
   ) 
        ) 
      (vla-get-ModelSpace 
        (vla-get-ActiveDocument (vlax-get-acad-object))) 
      ) 
    ) 
  (princ "\n*Cancel*") 
  ) 
       ) 
     ) 
  (princ) 
  )

vexation · 发表于 2011-8-13 18:25

谢谢斑主大大,可是不能批量自动拼接吗?一个一个点是不是麻烦了点?

账号		自动登录	找回密码
密码			注册

[讨论] CAD拼图