[源码]批量定义函数

cabinsummer · 发表于 2011-9-12 20:29

本帖最后由 cabinsummer 于 2016-12-24 15:14 编辑

(defun cmdload (cmdlist)
(mapcar '(lambda (cmdgrp / cmd lay)
(setq cmd (nth 0 cmdgrp))
(setq lay (nth 1 cmdgrp))
(eval (read
(strcat "(defun c:" cmd "(/ ss)
(setvar \"cmdecho\" 0)
(setq ss (ssget))
(if ss
(command \"CHANGE\" ss \"\" \"P\" \"LA\" \"" lay "\" \"\")
(setvar \"CLAYER\" \"" lay "\")
)
(princ))"
)
))
)
cmdlist
)
)
(cmdload '(("1" "DRAW")
("2" "HIDDEN")
("3" "CENTER")
("4" "DIM")
("5" "BORDER")
("6" "MISC")
("7" "PART")
("8" "PHANTOM")
("9" "TEXT_ENGLISH")
)
)

以上例子为图形内有九个层，层名分别"DRAW" "HIDDEN" "CENTER" "DIM" "BORDER" "MISC" "PART" "PHANTOM" "TEXT"。
按数字1-9后，如果有选择的实体，则将实体的层改为指定的层，如果没有选择则将当前图层切换到指定的图层。此函数还可以扩展，对于很多功能类似而又略有差别的函数定义是很方便的。例如将上述代码另存为cmdload.lsp，用以下代码加载

(autoload "cmdload" '("1" "2" "3" "4" "5" "6" "7" "8" "9"))

shcvip · 发表于 2018-11-25 21:43

我编译后，出现以下的情况;

警告: 运行时计算的表达式: (READ (STRCAT "(defun c:" CMD "(/ ss)\n (setvar "cmdecho" 0)\n (setq ss (ssget))\n (if ss\n (command "CHANGE" ss "" "P" "LA" "" ... ))

shcvip · 发表于 2019-9-30 12:17

程序使用反馈：有的图纸中，至改了图层，颜色没有改变。

yjr111 · 发表于 2011-9-12 22:00

mapcar 和lambda还不怎么能领会，学习中！

cabinsummer · 发表于 2011-9-12 22:17

lambda是定义无名函数，mapcar有两个参数，将第二参数的列表逐个应用到前一参数中。

434939575 · 发表于 2011-9-12 22:45

学习者

xshrimp · 发表于 2011-9-13 09:52

lambda后面的progn是不需要的.

cabinsummer · 发表于 2011-9-13 10:11

xshrimp 发表于 2011-9-13 09:52
lambda后面的progn是不需要的.

You are right

hao3ren · 发表于 2011-9-13 16:08

除了用数字，可以用字母吗？

gbhsu · 发表于 2011-9-13 17:56

顶一个!!!.........

USER2128 · 发表于 2011-9-19 21:44

;;; 局部放大视图标注式样批量定义程序.
;;;
;;; 程序设计者: LCAD, (USER2128, QQ:781400968,Email:Leedashan@163.com)
;;;
;;; 绘制过程中, 不可避免地要涉及到局部放大视图.
;;; 习惯只在“模型”空间绘图时，对局部放大视图进行尺寸标注时，
;;; 就要临时去修改系统变量"dimlfac"(如放大2倍时, dimlfac=0.5),
;;; 在标注完局部放大视图后, 还要改回: dimlfac=1, 工作不便.
;;;
;;; 本程序批量定义局部放大视图比例函数: 1 2 3 4 5 6 7 8 9 10 20倍,
;;; 调用命令为: 在提示符（command: ）下：键入下列其中之一：
;;; X1、X2、X3、X4、X5、X6、X7、X8、X9、X10、X20
;;; 即可设置好、对应的、放大1、2、3、4、5、6、7、8、9、10、20倍的、
;;; 局部放大视图进行标注时所需标注式样.
;;; 标注完成局部放大视图中的尺寸后, 键入X1即返回1:1绘图的标注式样(基本式样).
;;;
;;; 程序中, 参数“D_style”为图中已存在的、1:1绘图时的标注式样名,
;;; 如参数“D_style”为“nil”, 则默认以当前的标注式样为基本式样.
;;;============================================================
(defun chg_dimlfac (D_style / Lst i a b c)
(setvar "CMDECHO" 0)
(setq LST '(1 2 3 4 5 6 7 8 9 10 20))
(foreach I LST
(setq A (itoa I)
B (list
'defun
(read (strcat "C:X" A))
(list '/ 'xx)
(if (not D_style) (setq D_style (getvar "dimstyle")))
(list 'if (list 'tblsearch "dimstyle" D_style)
(list 'progn
(list 'command "._dimstyle" "_restore" D_style)
(list 'if (list '= i 1) 'nil
(list 'progn
(list 'setq 'xx (list 'strcat D_style "_X" A))
(list 'setvar "dimlfac" (list '/ 1.0 i))
(list 'command "._dim" "_save" 'xx)
(list 'if (list 'tblsearch "dimstyle" 'xx)
(list 'command "_yes" "_exit")
(list 'command "_exit"))
)))
(list 'princ (list 'strcat "\n图中不存在标注式样""
D_style
"", 先建立该式样，然后再使用该项命令."))
)
(list 'princ)
))
(eval B)
) ;_结束 foreach
(princ)) ;_结束 defun
;;;(chg_dimlfac "INTE")
(chg_dimlfac nil)
;;; 本例为：默认以当前的标注式样为基本式样.
;;; 你可以使用(chg_dimlfac "ISO-25")或(chg_dimlfac "STANDARD")
;;; 即以名称为"ISO-25"或"STANDARD"的标注式样为基本式样.
;;;============================================================

;;; 局部放大视图标注式样批量定义程序. 
;;; 
;;; 程序设计者: LCAD, (USER2128, QQ:781400968,Email:Leedashan@163.com) 
;;; 
;;; 绘制过程中, 不可避免地要涉及到局部放大视图. 
;;; 习惯只在“模型”空间绘图时，对局部放大视图进行尺寸标注时， 
;;; 就要临时去修改系统变量"dimlfac"(如放大2倍时, dimlfac=0.5), 
;;; 在标注完局部放大视图后, 还要改回: dimlfac=1, 工作不便. 
;;; 
;;; 本程序批量定义局部放大视图比例函数: 1 2 3 4 5 6 7 8 9 10 20倍, 
;;; 调用命令为: 在提示符（command: ）下：键入下列其中之一： 
;;;        X1、X2、X3、X4、X5、X6、X7、X8、X9、X10、X20 
;;; 即可设置好、对应的、放大1、2、3、4、5、6、7、8、9、10、20倍的、 
;;; 局部放大视图进行标注时所需标注式样. 
;;; 标注完成局部放大视图中的尺寸后, 键入X1即返回1:1绘图的标注式样(基本式样). 
;;; 
;;; 程序中, 参数“D_style”为图中已存在的、1:1绘图时的标注式样名, 
;;; 如参数“D_style”为“nil”, 则默认以当前的标注式样为基本式样. 
 
;;;============================================================ 
(defun chg_dimlfac (D_style / Lst i a b c) 
  (setvar "CMDECHO" 0) 
  (setq LST '(1 2 3 4 5 6 7 8 9 10 20)) 
  (foreach I LST 
    (setq A (itoa I) 
B (list 
    'defun 
    (read (strcat "C:X" A)) 
    (list '/ 'xx) 
    (if (not D_style) (setq D_style (getvar "dimstyle"))) 
    (list 'if (list 'tblsearch "dimstyle" D_style) 
          (list 'progn 
                (list 'command "._dimstyle" "_restore" D_style) 
    (list 'if (list '= i 1) 'nil 
          (list 'progn 
                (list 'setq 'xx (list 'strcat D_style "_X" A)) 
                (list 'setvar "dimlfac" (list '/ 1.0 i)) 
                (list 'command "._dim" "_save" 'xx) 
                      (list 'if (list 'tblsearch "dimstyle" 'xx) 
                            (list 'command "_yes" "_exit") 
                            (list 'command "_exit")) 
                ))) 
          (list 'princ (list 'strcat "\n图中不存在标注式样"" 
                             D_style 
                             "", 先建立该式样，然后再使用该项命令.")) 
          ) 
    (list 'princ) 
    )) 
    (eval B) 
    ) ;_结束 foreach 
  (princ)) ;_结束 defun 
;;;(chg_dimlfac "INTE") 
(chg_dimlfac nil) 
;;; 本例为：默认以当前的标注式样为基本式样. 
;;; 你可以使用(chg_dimlfac "ISO-25")或(chg_dimlfac "STANDARD") 
;;; 即以名称为"ISO-25"或"STANDARD"的标注式样为基本式样. 
;;;============================================================

USER2128 · 发表于 2011-9-19 22:30

以前用过InteCAD，后来就不用了

账号		自动登录	找回密码
密码			注册

[【风之影】] [源码]批量定义函数

评分

点评

点评

评分

点评