设为首页收藏本站CAD论坛CAD教程CAD下载明经币充值
切换到宽版

明经CAD社区

 找回密码
 注册

QQ登录

只需一步，快速开始

搜索
明经CAD社区»社区 › 开发篇 › AutoLISP/Visual LISP 编程技术 › 请问为什么隐显对象对象有时行有时不行
12345678910... 14下一页
返回列表 发新帖
查看: 20901|回复: 137

请问为什么隐显对象对象有时行有时不行

  [复制链接]
flytoday
发表于 2012-3-31 23:13:48 | 显示全部楼层 |阅读模式
1明经币
本帖最后由 flytoday 于 2012-3-31 23:17 编辑

(defun c:DOFF (/ ss)
(vl-load-com)
(prompt "\n 选择对象隐藏: ")
(if (setq ss (ssget))
((lambda (i / e)
(while (setq e (ssname ss (setq i (1+ i))))
(vla-put-visible
(vlax-ename->vla-object e)
:vlax-false)))
-1))
(princ))
;--------------------------------------------------
(defun c:DON (/ ss)
(vl-load-com)
(prompt "\n 所有的对象已打开... ")
(if (setq ss (ssget "_x"))
((lambda (i / e)
(while (setq e (ssname ss (setq i (1+ i))))
(vla-put-visible
(vlax-ename->vla-object e)
:vlax-true)))
-1))
(princ))
;---------------------对象的隐藏和取消隐藏-------------------



有时候隐藏是隐藏了就是显示不出来.....
有时有些对些对象不能隐藏了(天正的墙体之类的不能隐藏)
提示
; 错误: Automation 错误。未提供说明。
哪位大侠帮修改下..让程序适用天正及CAD所有对象都能隐藏显示///谢谢

最佳答案

Gu_xl

查看完整内容

显示隐藏工具 **** 本内容被作者隐藏 ****

点评

Gu_xl
失灵时不灵，那是段誉的六脉神剑！  发表于 2012-4-1 09:30
"觉得好，就打赏"
打赏
还没有人打赏，支持一下
回复

使用道具 举报

Gu_xl
发表于 2012-3-31 23:13:49 | 显示全部楼层
本帖最后由 Gu_xl 于 2012-4-1 12:00 编辑

显示隐藏工具
  1. ;;隐藏对象
  2. (defun c:Objhide  (/ ss n data) (vl-load-com)
  3.   (setq ss (ssget ":L"))
  4.   (if ss
  5.     (progn
  6.       (repeat (setq n (sslength ss))
  7.         (vla-put-Visible
  8.           (setq        obj (vlax-ename->vla-object
  9.                       (ssname ss (setq n (1- n)))))
  10.           :vlax-false)
  11.         (setq data (cons (vla-get-Handle obj) data))
  12.         )
  13.       (VLAX-LDATA-PUT
  14.         "隐藏对象"
  15.         "隐藏对象数据"
  16.         (append (VLAX-LDATA-get "隐藏对象" "隐藏对象数据") Data))
  17.       )
  18.     )
  19.   (princ)
  20.   )
  21. ;;显示对象
  22. (defun c:ObjShow  (/ data en LayerStaus layer layers)
  23.   (vl-load-com)
  24.   (setq data (VLAX-LDATA-get "隐藏对象" "隐藏对象数据"))
  25.   (if data
  26.     (progn
  27.       (foreach hand  data
  28.         (if (setq en (handent hand))
  29.           (progn
  30.             (setq layers (vla-get-layers
  31.                            (vla-get-ActiveDocument
  32.                              (vlax-get-acad-object))))
  33.             (if        (or (= :vlax-true
  34.                        (vla-get-Lock
  35.                          (setq
  36.                            layer (vla-item layers
  37.                                            (vla-get-layer
  38.                                              (setq obj
  39.                                                     (vlax-ename->vla-object
  40.                                                       en)))))))
  41.                     (= :vlax-true (vla-get-Freeze layer))
  42.                     )
  43.               (progn
  44.                 (setq LayerStaus
  45.                        (cons (list layer
  46.                                    (vla-get-Lock layer)
  47.                                    (vla-get-Freeze layer))
  48.                              LayerStaus)) ;_ 保存图层状态
  49.                 (vla-put-lock layer :vlax-false) ;_ 解锁
  50.                 (vla-put-lock layer :vlax-false) ;_ 解冻
  51.                 )
  52.               )

  54.             (vla-put-Visible obj :vlax-true) ;_ 显示
  55.             )
  56.           )
  57.         )
  58.       (VLAX-LDATA-delete "隐藏对象" "隐藏对象数据")
  59.       (if LayerStaus
  60.         (foreach la  LayerStaus
  61.           (vla-put-lock (car la) (cadr la))
  62.           (vla-put-freeze (car la) (caddr la))
  63.           )
  64.         )
  65.       )
  66.     )
  67.   (princ)
  68.   )

点评

yjr111
看来G版已经修成金刚不坏神功，六脉神剑也轻易破解了  发表于 2012-4-1 12:40

评分

参与人数 1明经币 +1 收起 理由
flytoday + 1 很给力!G版出手超完美。。。谢谢。太感动了

查看全部评分

回复

使用道具 举报

yjr111
发表于 2012-4-1 00:39:36 | 显示全部楼层
  2. ;;;---------------------------------------------------------------------------;
  3. ;;;
  4. ;;;   BLANK.LSP   Version 1.0
  5. ;;;
  6. ;;;   Copyright (C) 1995 by Autodesk, Inc.
  7. ;;;
  8. ;;;   Permission to use, copy, modify, and distribute this software and its
  9. ;;;   documentation for any purpose and without fee is hereby granted.
  10. ;;;
  11. ;;;   THIS SOFTWARE IS PROVIDED "AS IS" WITHOUT EXPRESS OR IMPLIED WARRANTY.
  12. ;;;   ALL IMPLIED WARRANTIES OF FITNESS FOR ANY PARTICULAR PURPOSE AND OF
  13. ;;;   MERCHANTABILITY ARE HEREBY DISCLAIMED.
  14. ;;;
  15. ;;;---------------------------------------------------------------------------;
  16. ;;;   BLANK, UNBLANK, and UNBLANKALL
  17. ;;;
  18. ;;;   This module provides functions to manipulate the visibility field of
  19. ;;;   AutoCAD objects.  BLANK will make a selection set of objects invisible.
  20. ;;;   UNBLANK will make a specified object (given its handle) visible.
  21. ;;;   UNBLANKALL will make all blanked entities visible.
  22. ;;;
  23. ;;;---------------------------------------------------------------------------;


  26. ;;;---------------------------------------------------------------------------;
  27. ;;; Internal error handling.
  28. ;;;---------------------------------------------------------------------------;
  29. (defun blank_error(s)
  30.   ;; The strings in the following statements can be translated.
  31.   (if (/= s ;|MSG1|;"Function cancelled")
  32.     (princ (strcat ;|MSG2|;"\nBLANK Error: " s))
  33.   )
  34.   (setq *error* olderr)
  35.   (princ)
  36. )

  38. (defun unblank_error(s)
  39.   ;; The strings in the following statements can be translated.
  40.   (if (/= s ;|MSG3|;"Function cancelled")
  41.     (princ (strcat ;|MSG3|;"\nUNBLANK Error: " s))
  42.   )
  43.   (setq *error* olderr)
  44.   (princ)
  45. )

  47. (defun blank60 (e / e2)
  48.   (if (not (null (assoc '60 e)))
  49.     (setq e2 (subst '(60 . 1) '(60 . 0) e))
  50.     (setq e2 (append e '((60 . 1))))
  51.   )
  52. )   

  54. (defun show60 (e / e2)
  55.   (if (not (null (assoc '60 e)))
  56.      (setq e2 (subst '(60 . 0) '(60 . 1) e))
  57.      (setq e2 (append e '((60 . 0))))
  58.   )
  59. )

  61. (defun setvis ( vis ename / e)
  62.   (setq e (entget ename))
  63.   (if (eq vis 0)
  64.      (entmod (show60 e))
  65.      (entmod (blank60 e))
  66.   )
  67.   (entupd ename)
  68.   ;; Blank vertices of polyline, if necessary
  69.   (if (eq (cdr (nth 1 e)) "POLYLINE")
  70.     (progn
  71.       (setq ename (entnext ename))
  72.       (setq e (entget ename))
  73.       (while (eq (cdr (nth 1 e)) "VERTEX")
  74.         (if (eq vis 0)
  75.            (entmod (show60 e))
  76.            (entmod (blank60 e))
  77.         )
  78.         (entupd ename)
  79.         (setq ename (entnext ename))
  80.         (setq e (entget ename))
  81.       ) ; while
  82.     ) ; progn
  83.   ) ; if polyline
  84.   (if (and (eq (cdr (nth 1 e)) "INSERT")
  85.            (assoc '66 e))
  86.     (progn
  87.       (setq ename (entnext ename))
  88.       (setq e (entget ename))
  89.       (while (eq (cdr (nth 1 e)) "ATTRIB")
  90.         (if (eq vis 0)
  91.            (entmod (show60 e))
  92.            (entmod (blank60 e))
  93.         )
  94.         (entupd ename)
  95.         (setq ename (entnext ename))
  96.         (setq e (entget ename))
  97.       ) ; while
  98.     ) ; progn
  99.   )
  100. )

  102. (defun c:blank ( ) ;;; / olderr echo ss i ename )
  103.   (setq olderr *error*                ; Redefine error handler.
  104.         echo (getvar ;|MSG0|;"cmdecho")
  105.         *error* blank_error)
  106.   (setvar ;|MSG0|;"cmdecho" 0)                ; Turn off cmdecho sysvar
  107.   (command ;|MSG0|;"_.undo" ;|MSG0|;"_group")

  109.   (setq ss (ssget))
  110.   (setq i 0)
  111.   (while (< i (sslength ss)) (progn
  112.      (setq ename (ssname ss i))
  113.      (setvis 1 ename)
  114.      (setq i (1+ i))
  115.   ))

  117.   (setq *error* old_error)            ; restore error function
  118.   (command ;|MSG0|;"_.undo" ;|MSG0|;"_end")
  119.   (setvar ;|MSG0|;"cmdecho" echo)             ; restore cmdecho sysvar
  120.   (princ)                             ; Quiet exit.
  121. )

  123. (defun c:unblankall ( ) ;;; / olderr echo ss i ename )
  124.   (setq olderr *error*                ; Redefine error handler.
  125.         echo (getvar ;|MSG0|;"cmdecho")
  126.         *error* unblank_error)
  127.   (setvar ;|MSG0|;"cmdecho" 0)                ; Turn off cmdecho sysvar
  128.   (command ;|MSG0|;"_.undo" ;|MSG0|;"_group")

  130.   ;; Select all blanked entities
  131.   (setq ss (ssget ;|MSG0|;"_x" '((60 . 1))))
  132.   (if (not (null ss))
  133.     (progn
  134.       (setq i 0)
  135.       (princ (sslength ss))
  136.       (princ " blanked entities found.\n");
  137.       ;; Unblank each entity in the set
  138.       (while (< i (sslength ss)) (progn
  139.          (setq ename (ssname ss i))
  140.          (setvis 0 ename)
  141.          (setq i (1+ i))
  142.       ))
  143.     )   
  144.     (princ "\n0 blanked entities found.\n");
  145.   )

  147.   (setq *error* old_error)            ; restore error function
  148.   (command ;|MSG0|;"_.undo" ;|MSG0|;"_end")
  149.   (setvar ;|MSG0|;"cmdecho" echo)             ; restore cmdecho sysvar
  150.   (princ)                             ; Quiet exit.
  151. )

  153. (defun c:unblank ( ) ;;; / olderr echo ss i ename hand )
  154.   (setq olderr *error*                ; Redefine error handler.
  155.         echo (getvar ;|MSG0|;"cmdecho")
  156.         *error* unblank_error)
  157.   (setvar ;|MSG0|;"cmdecho" 0)                ; Turn off cmdecho sysvar
  158.   (command ;|MSG0|;"_.undo" ;|MSG0|;"_group")

  160.   (setq hand (getstring ;|MSG5|;"\nEnter handle of entity to be unblanked: "))
  161.   ;; Unblank the entity if handle is not an empty string
  162.   (if (> (strlen hand) 0)
  163.     (progn
  164.       (setq ename (handent hand))
  165.       (if (/= nil ename)
  166.         (setvis 0 ename)
  167.         (princ ;|MSG6|;"Invalid handle.")
  168.       )
  169.     )
  170.   )

  172.   (setq *error* old_error)            ; restore error function
  173.   (command ;|MSG0|;"_.undo" ;|MSG0|;"_end")
  174.   (setvar ;|MSG0|;"cmdecho" echo)             ; restore cmdecho sysvar
  175.   (princ)                             ; Quiet exit.
  176. )

BLANK隐藏实体 UNBLANKALL显示所有实体

点评

669423907
果然能这样就更好了： 1：加循环 2：选择对象后立即隐藏（不用右键确认） 3：可反向选择（隐藏未选择对象）  发表于 2012-4-1 10:06

评分

参与人数 1明经币 +1 收起 理由
669423907 + 1 yjr111大师总是那么热心！

查看全部评分

回复

使用道具 举报

flytoday
 楼主| 发表于 2012-4-1 09:21:13 | 显示全部楼层
严哥这个在天正中多选择对象直接CAD崩溃，。卡住退出了哦。。不过也是很感谢

点评

yjr111
问一下G版有没有办法破解段誉的六脉神剑哦：-）  发表于 2012-4-1 09:46
yjr111
啥天正啊，AUTOCAD原版的程序也崩溃!  发表于 2012-4-1 09:45
回复

使用道具 举报

flytoday
 楼主| 发表于 2012-4-1 09:51:02 | 显示全部楼层
当然G版肯出手一定行呵呵。。。
回复

使用道具 举报

flytoday
 楼主| 发表于 2012-4-1 09:54:01 | 显示全部楼层
很关键滴是有些对象隐藏了显示不出来
回复

使用道具 举报

ㄘ丶转裑ㄧ灬
发表于 2012-4-1 10:02:24 | 显示全部楼层
flytoday 发表于 2012-4-1 09:21
严哥这个在天正中多选择对象直接CAD崩溃，。卡住退出了哦。。不过也是很感谢

额。。。天正的工具里不是有局部隐藏吗、、、
我也开着天正，用严哥这程序一切正常、、、、、8.5+2012
回复

使用道具 举报

ㄘ丶转裑ㄧ灬
发表于 2012-4-1 10:06:38 | 显示全部楼层
悲剧，确实对天正墙体之类的不能隐藏，一用就崩溃、、、、
回复

使用道具 举报

Andyhon
发表于 2012-4-1 10:07:21 | 显示全部楼层
Ref:
http://www.mjtd.com/Codes/ArticleShow.asp?ArticleID=988

未审天正合用否

点评

flytoday
; 错误: Automation 错误...这个不能选择隐藏显示。。。  发表于 2012-4-1 10:35
回复

使用道具 举报

ㄘ丶转裑ㄧ灬
发表于 2012-4-1 10:19:17 | 显示全部楼层
Andyhon 发表于 2012-4-1 10:07
Ref:
http://www.mjtd.com/Codes/ArticleShow.asp?ArticleID=988

、、、、除了隐藏和显示所有，其他的都不会用、、、
暂时没有崩溃现象、、、
回复

使用道具 举报

12345678910... 14下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码，在未取得本站及作者授权的情况下，不得用于商业用途

GMT+8, 2025-5-21 01:25 , Processed in 0.215070 second(s), 26 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表