lisp创建自定义工具栏

langjs

初衷：我们在加载某个lisp程序时，如果同时为该程序自动生成个自定义工具栏使用起来就方便了。
实现：在加载lisp时，自动执行一段程序，创建一个mnu文件，写入工具栏内容，然后加载。
例子：

;;;; 自动创建"动态轴测图"工具栏子程序(defun create_toolbar ( / file x)
  (setvar "cmdecho" 0)
  (vl-load-com)
  (if (not (menugroup "TEMPTOOLBAR"))  ; 判断cad是否加载temptoolbar工具栏
    (progn                               ; 如果没加载，则自动执行下面程序
      (alert "\n程序自动创建\"TEMPTOOLBAR\"工具栏，请稍后")
      (setq file (open "TEMPTOOLBAR.mnu" "W")) ; 在cad搜索目录创建一个菜单mnu文件,写状态打开
      (foreach x '("***MENUGROUP=TEMPTOOLBAR\n\n***TOOLBARS\n**TEMPTOOLBAR" ; 下面定义工具栏内容，
                                       ; 第一行是工具栏名称为“动态轴测图”
                                       ; 剩下四行对应四个工具栏图标，可以自行仿照格式增减。
                                       ; 自定义图标有点麻烦，最好采用cad自带图标，系统自定义的图标很多，
                                       ; 在“工具”-“自定义”-“界面”-“工具栏”——点开五角星。
                                       ; 右侧图像类似RCDATA_16_OSNEN为图标名称，选择一个可以填在下面格式，
                                       ; 下面^C^C后面跟着的是lisp程序名，意思是双击图标要执行的程序。
         "ID_ZCT001   [_Toolbar(\"动态轴测图\", _Floating, _Hide, 10, 340, 1)]"
         "ID_ZCT011   [_Button(\"轴测图直线\", \"RCDATA_16_OSNEND\", \"RCDATA_16_OSNEND\")]^C^Czline"
         "ID_ZCT012   [_Button(\"轴测图标注\", \"RCDATA_16_DIMOBL\", \"RCDATA_16_DIMOBL\")]^C^Czdim"
         "ID_ZCT013   [_Button(\"轴测图文字\", \"RCDATA_16_TEXEDI\", \"RCDATA_16_TEXEDI\")]^C^Cztext"
         "ID_ZCT014   [_Button(\"轴测图更改\", \"RCDATA_16_DIMOVE\", \"RCDATA_16_DIMOVE\")]^C^Czch"
        )
        (princ (strcat x "\n") file)   ; 将定义工具栏内容写入mnu文件

      )
      (close file)                       ; 关闭mnu文件
      (command "menuload" "TEMPTOOLBAR.mnu") ; 加载temptoolbar工具栏
    )
  )
  (command "TOOLBAR" "动态轴测图" "S") ; 显示工具栏
  (princ)
)
(create_toolbar)
;;; 本句的作用是加载本lisp就自动执行create_toolbar子程序






;;; 以下部分是正常的程序
(defun c:zline ()
  (alert "\n\"轴测图直线\"暂未开源")
  (princ)
)
(defun c:zdim ()
  (alert "\n\"轴测图标注\"源码在明经论坛")
  (princ)
)
(defun c:ztext ()
  (alert "\n\"轴测图文字\"暂未开源")
  (princ)
)
(defun c:zch ()
  (alert "\n\"轴测图更改\"暂未开源")
  (princ)
)





例子2:
;;; ================================================================
;;; 功能：自动为.isp命令创建一个命令的按钮子函数
;;; 使用: 在.isp文件最后最下方写入一句 (createtoolbar name sym bmp )
;;;       其中:name为命令中文名称,sym为执行的命令,bmp为图标,最好采用
;;;       系统图标,自定义图标需拷贝到支持目录,为*.bmp格式.
;;; 样例createtoolbar "轴测图直线" "zline" "rcdata_16_osnend")
;;;      (createtoolbar "轴测图直线" "zline" "zline.bmp")
;;; 作者：langjs                                   日期:2012年4月1日
;;; ================================================================
(defun createtoolbar (name sym bmp / file x)
  (setvar "cmdecho" 0)
  (vl-load-com)
  (if (menugroup "TEMPTOOLBAR") (command "menuunload" "TEMPTOOLBAR"))
  (alert "\n程序将自动创建\"临时工具栏\"，请稍后")
  (setq file (open "TEMPTOOLBAR.mnu" "W"))
  (foreach x (list "***MENUGROUP=TEMPTOOLBAR\n\n***TOOLBARS\n**TEMPTOOLBAR"
     "ID_TEMP001   [_Toolbar(\"临时工具栏\", _Floating, _Hide, 10, 340, 1)]"
    (strcat "ID_TEMP011   [_Button(\"" name "\", \"" bmp "\", \"" bmp "\")]^C^C" sym)
      )
    (princ (strcat x "\n") file)
  )
  (close file)
  (command "menuload" "TEMPTOOLBAR.mnu")
  (command "TOOLBAR" "临时工具栏" "S")
  (princ)
)
(createtoolbar "轴测图直线" "zline" "RCDATA_16_OSNEND")

langjs

changyiran 发表于 2012-4-16 20:29
这个路径貌似不好取得，其实如果能取得cad下面的backup的路径也是很好的，可惜我不会取得。能不能指教下？ ...

(defun getlsppath (/ lsppath)        ; 读取运行程序路径并加到cad支持路径_by:wzh，如果运行的是vlx，要把程序里边的lsp改为vlx
    (setq lsppath (vl-registry-read "HKEY_CURRENT_USER\\Software\\Microsoft\\Windows\\CurrentVersion\\Explorer\\ComDlg32\\OpenSaveMRU\\lsp"
                                    (substr (vl-registry-read "HKEY_CURRENT_USER\\Software\\Microsoft\\Windows\\CurrentVersion\\Explorer\\ComDlg32\\OpenSaveMRU\\lsp"
                                                              "MRUList"
                                            ) 1 1
                                    )
                  )
    )
    (setenv "ACAD" (strcat (getenv "ACAD") ";" (vl-filename-directory lsppath)))
    lsppath
  )

ajunseo

;;; ================================================================
;;; 功能：自动为.isp命令创建一个命令的按钮子函数
;;; 使用: 在.isp文件最后最下方写入一句 (createtoolbar name sym bmp )
;;;       其中:name为命令中文名称,sym为执行的命令,bmp为图标,最好采用
;;;       系统图标,自定义图标需拷贝到支持目录,为*.bmp格式.
;;; 样例createtoolbar "轴测图直线" "zline" "rcdata_16_osnend")
;;;      (createtoolbar "轴测图直线" "zline" "zline.bmp")
;;; 作者：langjs                                   日期:2012年4月1日
;;; ================================================================
(defun createtoolbar (name sym bmp / file x)
  (setvar "cmdecho" 0)
  (vl-load-com)
  (if (menugroup "TEMPTOOLBAR") (command "menuunload" "TEMPTOOLBAR"))
  (alert "\n程序将自动创建\"临时工具栏\"，请稍后")
  (setq file (open "TEMPTOOLBAR.mnu" "W"))
  (foreach x (list "***MENUGROUP=TEMPTOOLBAR\n\n***TOOLBARS\n**TEMPTOOLBAR"
     "ID_TEMP001   [_Toolbar(\"临时工具栏\", _Floating, _Hide, 10, 340, 1)]"
    (strcat "ID_TEMP011   [_Button(\"" name "\", \"" bmp "\", \"" bmp "\")]^C^C" sym)
      )
    (princ (strcat x "\n") file)
  )
  (close file)
  (command "menuload" "TEMPTOOLBAR.mnu")
  (command "TOOLBAR" "临时工具栏" "S")
  (princ)
)
(createtoolbar "轴测图直线" "zline" "RCDATA_16_OSNEND"  )
;(createtoolbar "红色" "tt" "co1.bmp"  )

不能创建多个按钮，有方法吗？

广易精通

langjs 发表于 2012-4-16 21:47
(defun getlsppath (/ lsppath)        ; 读取运行程序路径并加到cad支持路径_by:wzh，如果运行的是vlx， ...

楼主你好，生成的cui，mnu文件怎么放到自己指定的位置而不在文档里面，谢谢

功夫佬

  (progn                           ; 如果没加载，则自动执行下面程序
      (alert "\n程序自动创建\"动态轴测图\"工具栏，请稍后")
我被执行这段，ACAD2010的

669423907

这个好啊，谢谢楼主分享。慢慢看。

CTC

先占个位子

zyhandw

这个例子太好了，下来好好学学，谢谢楼主！！

wang.bay

是好方法，

CTC

好期待

功夫佬

功夫佬 发表于 2012-4-6 22:27
(progn                           ; 如果没加载，则自动执行下面程序
      (alert "\n程序自动创建\"动 ...

看到你回后，再次去试一下，真的可以啦了，太感谢你给我有成功的喜悦感~~

jiekecao

dddddddddddddddddddddd

xujinhua

我一直相学这个啊..谢谢！我慢慢看