请教大侠修改文本合并

阳光动力

网上搜了很久就找到的。
但存两个问题，不能满足需要，希望哪位大侠帮忙修改下。
1、合并后，首行文字没有删掉；（如，管径  DN50，合并后成 管径
                                                                                    管径
                                                                                    DN50）
2、合并后的文字成多行排列，能否改成单行排列。

;; wbhb.LSP 文字连接程序  CYN 2000.1.28
;; 最近一次修改 2002.3.27
(defun c:wbhb(/ sset1 ename1 elist1 str1 sset2 ename2 elist2 str2 nstr)  
    (setq  sset1 (entsel (strcat "\n选择首文字段:"))
          ename1 (car sset1)
          elist1 (entget ename1)
            str1 (cdr (assoc 1 elist1))
    )
    (redraw ename1 3)
    (setq sset2 T)
    (while sset2
       (setq  sset2 (entsel (strcat "\n选择尾文字段:")))
         (if (null sset2)
           (progn
             (princ "程序结束")
             (exit)
           )
         )
       (setq ename2 (car sset2)
             elist2 (entget ename2)
               str2 (cdr (assoc 1 elist2))
               nstr (strcat str1 str2)
       )
       (redraw ename1 4)
       (entmod (append elist1 (list (cons 1 nstr))))
       (command "_erase" ename2 "")
       (setq ename1 (cdr (assoc -1 elist1))
             elist1 (entget ename1)
               str1 (cdr (assoc 1 elist1))
       )
    )
    (princ)
);End Defun

langjs

;;; 文字连接程序  by：langjs
(defun c:aa ( / ent entbak name namebak str)
  (setq str "")
  (while (setq name (car (entsel "\n 选择文字:")))
    (setq str (strcat str (cdr (assoc 1 (setq ent (entget name))))))
    (if (null entbak)
      (setq entbak ent  namebak name)
      (progn (entmod (subst(cons 1 str)(assoc 1 entbak) entbak ))(entdel name))
    )
    (redraw namebak 3)
  )
  (if namebak (redraw namebak 4) )
  (princ)
)

革天明

langjs 发表于 2012-6-19 13:23
;;; 文字连接程序  by：langjs
(defun c:aa ( / ent entbak name namebak str)
  (setq str "")

精简，高质量代码

阳光动力

langjs 发表于 2012-6-19 13:23
;;; 文字连接程序  by：langjs
(defun c:aa ( / ent entbak name namebak str)
  (setq str "")

谢谢，大侠，很好用。

阳光动力

谢谢了，很好用，不错。