求高手帮忙改进程序，谢谢！

xieling888

程序改进：

如何能实现：输入TT命令后,选择第一点(整排圆能跟着显示出来，随第二点的位置而确定圆的个数），然后选择第2点结束。

langjs

改了一下，程序能用但不好用，圆的数量多的话会卡
(defun c:qq (/ ang code d data di gr i loop lst n nbak pt1 pt3 r)
  (defun #err001 (s)
    (ssde lst)
    (setq *error* $orr)
  )
  (defun ssde (lst / i)
    (if lst(foreach x lst (entdel x)))
  )
  (setq $orr *error*)
  (setq *error* #err001)
  (if (= (tblsearch "layer" "6") nil)
    (entmake (list '(0 . "LAYER") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLayerTableRecord") '(70 . 0) '(6 . "Continuous")
                   (cons 2 "6") (cons 62 4)
             )
    )
  )
  (setq d 2.2  r 2.5  loop t nbak 0  pt1 (getpoint "\n第一点:"))
  (while (progn
           (setq gr (grread t 15 0) code (car gr) data (cadr gr))
           (cond
             ((= code 3) (setq loop nil))
             ((= code 5)
               (setq di (distance pt1 data) ang (angle pt1 data) n (fix (/ di d)) pt3 pt1)
               (if (/= n nbak)
                 (progn
                   (ssde lst)
                   (setq lst nil)
                   (princ (strcat "\n当前圆数量：" (itoa (1+ n))))
                   (entmake (list '(0 . "CIRCLE") (cons 10 pt3) (cons 40 r) (cons 8 "6")))
                   (setq lst (cons (entlast) lst))
                   (repeat n
                     (setq pt3 (polar pt3 ang d))
                     (entmake (list '(0 . "CIRCLE") (cons 10 pt3) (cons 40 r) (cons 8 "6")))
                     (setq lst (cons (entlast) lst))
                   )
                   (setq nbak n)
                 )
               )
             )
             ((member code '(11 25))
               (ssde lst)
               (setq loop nil)
             )
             (t
             )
           )
           loop
         )
  )
  (setq *error* $orr)
  (princ)
)

langjs

setq d 2.2  r 2.5  
d为两个圆间距，r为圆半径,自己改吧。卡的问题无法解决。