求一个根据一组设定值进行偏移的LSP程序

moshouhot · 发表于 2012-7-23 20:31:49

本帖最后由 moshouhot 于 2012-7-23 20:35 编辑

我在论坛里搜索了一个LSP程序，已经能部分实现我想要的功能，但希望各位大侠能把这段代码完善一下，谢谢各位了：

;;;“赖版”程序作一点小小的修改;;;
;;;---------------;;;
(defun C:OFFSETS (/ A S N PT1 AA AAA AL)
(setq A "")
(while (= A "")
(setq A (getstring "\nSpecify offset distance :"))
;;输入如:2/6/23…..
)
(setq A (strcat A "/"))
(prompt "\nSelect object to offset: ")
(while (= AA nil)
(setq AA (entsel))
)
(initget 1)
(setq PT1 (getpoint "\nSpecify point on side to offset: "))
(setq AL (+ (strlen A) 1))
(setq N 1)
(setq S "" S0 0)
(setq AAA (car AA))
(while (not (= N AL))
(if (= (substr A N 1) "/")
(progn
(setq s0 (+ s0 (atof s)))
(command "_.offset" S0 AAA PT1 "")
(setq S "")
)
(setq S (strcat S (substr A N 1)))
)
(setq N (1+ N))
)
(princ)
)

这个LSP可以根据我输入的如:2/6/23，将线段进行几次偏移。
1、因为我要做一条道路，全线都要偏移，能不能把第一次输入的值记录下来，第二次使用的时候作为默认值对下一个线段进行偏移。
2、偏移的时候，它会提示选择偏移的方向，可不可以在选项里面加一个，如果不选择方向直接空格就默认两侧都进行偏移。
3、还有个小小的请求，能实现最好。就是输入数值的时候可不可以用空格代替“/”，如2 6 23这样，不能实现也没事，关键是前面2个。

pxt2001 · 发表于 2018-1-16 14:24:17

yanchao316 发表于 2016-6-14 09:36
大神，请问能自己加入预设数据不?比如第一次加载必需输入一个值，我想第一次加载后就能默认一组数据比如

读写外部文件，read-line write-line

或者用词典
(if (not (setq dis-c2v2 (vlax-ldata-get "dict" "dis-c2v2")))
(setq dis-c2v2 "1")
)
(vlax-ldata-put "dict" "dis-c2v2" "6")

bai2000 · 发表于 2019-6-8 20:08:06

有时会出现：AutoCAD 变量设置被拒绝: "osmode" nil

xyp1964 · 发表于 2012-7-23 20:45:30

试试e派工具箱里的批量偏移功能：plpy

Andyhon · 发表于 2012-7-23 22:11:46

本帖最后由 Andyhon 于 2012-7-24 09:08 编辑

For test only

;;;「賴版」程序作一點小小的修改;;;
;;;---------------;;;
(Defun Off_Aux (ddL pnt)
(setq Hdd 0)
(while (setq dd (car ddL))
(setq Hdd (+ Hdd dd))
(command "_.offset" Hdd ee Pnt "")
(setq ddL (cdr ddL))
)
)
(defun C:OFFSETS ()
(if *HddLst*
(progn
(princ "\nOffsetDists ==> ")
(princ *HddLst*)
(initget "Yes No")
(setq Kwd (GetKword "\nSame as above <Yes> / No : "))
)
(setq Kwd "No")
)
(cond
((= Kwd "No")
(setq A "")
(while (= A "")
(setq A (getstring "\nSpecify offset distance : " T))
;; 輸入如: 2 6 23…..
)
(setq *HddLst* a)
)
(T
(setq a *HddLst*)
)
)
;; (setq *HddLst* Hddlst)
(setq ddLst (read (strcat "(" a ")")))
(prompt "\nSelect object to offset: ")
(while (not (setq ee (entsel))))
(setq Pt1 (getpoint "\nSpecify point on side to offset: "))
(cond
((null pt1)
(setq p5 (osnap (cadr ee) "Mid")
pa (osnap (cadr ee) "end")
vv (angle pa p5)
pt1 (polar p5 (+ vv 1.5) 8)
pt2 (polar p5 (- vv 1.5) 8)
)
)
(T (setq pt2 nil))
)
(Off_Aux ddLst pt1)
(if pt2
(Off_Aux ddLst pt2)
)
(princ)
)

;;;「賴版」程序作一點小小的修改;;; 
;;;---------------;;; 
 
(Defun Off_Aux (ddL pnt) 
  (setq Hdd 0) 
  (while (setq dd (car ddL)) 
    (setq Hdd (+ Hdd dd)) 
    (command "_.offset" Hdd ee Pnt "") 
    (setq ddL (cdr ddL)) 
  ) 
) 
 
(defun C:OFFSETS () 
  (if *HddLst* 
    (progn 
      (princ "\nOffsetDists ==> ") 
      (princ *HddLst*) 
      (initget "Yes No") 
      (setq Kwd (GetKword "\nSame as above <Yes> / No : ")) 
    ) 
    (setq Kwd "No") 
  ) 
 
  (cond 
    ((= Kwd "No") 
     (setq A "") 
     (while (= A "") 
       (setq A (getstring "\nSpecify offset distance : " T)) 
       ;; 輸入如: 2 6 23….. 
     ) 
     (setq *HddLst* a) 
    ) 
    (T 
     (setq a *HddLst*) 
    ) 
  ) 
  ;; (setq *HddLst* Hddlst) 
  (setq ddLst (read (strcat "(" a ")"))) 
  (prompt "\nSelect object to offset: ") 
  (while (not (setq ee (entsel)))) 
 
  (setq Pt1 (getpoint "\nSpecify point on side to offset: ")) 
 
  (cond 
    ((null pt1) 
     (setq p5  (osnap (cadr ee) "Mid") 
           pa  (osnap (cadr ee) "end") 
           vv  (angle pa p5) 
           pt1 (polar p5 (+ vv 1.5) 8) 
           pt2 (polar p5 (- vv 1.5) 8) 
     ) 
    ) 
    (T (setq pt2 nil)) 
  ) 
 
  (Off_Aux ddLst pt1) 
  (if pt2 
    (Off_Aux ddLst pt2) 
  ) 
  (princ) 
)

得依实务完善之 ...

moshouhot · 发表于 2012-7-24 08:45:56

xyp1964 发表于 2012-7-23 20:45
试试e派工具箱里的批量偏移功能：plpy

恩，我在贱人工具箱也找到类似的功能，但是不能同时两侧偏移是个遗憾。

moshouhot · 发表于 2012-7-24 08:48:23

Andyhon 发表于 2012-7-23 22:11
For test only得依实务完善之 ...

大侠，你的代码很棒，美中不足的是不能实现两侧偏移，另外我在运行你的代码的时候提示“Specify point on side to offset: ; 错误: no function definition: SIO”的错误，希望能进一步完善，谢谢了。

Andyhon · 发表于 2012-7-24 09:11:57

Sorry 3# 已订正

在这句
Specify point on side to offset:
[Enter] 空回应即可实现两侧偏移

xyp1964 · 发表于 2012-7-24 13:13:36

preone · 发表于 2012-7-24 20:21:51

很好很强大~~

moshouhot · 发表于 2012-7-25 09:36:26

xyp1964 发表于 2012-7-24 13:13

院长的工具也挺好的，但不能完全满足我的要求，我是想让它根据一组设定值（如：3.5 4 6）来进行评议

moshouhot · 发表于 2012-7-25 09:46:52

Andyhon 发表于 2012-7-24 09:11
Sorry 3# 已订正

在这句

Andyhon大侠果然厉害，看来最佳答案非你莫属了，还有个2个小小的问题
1、如果已经提前选中线段，输入命令后，还要让我再选一次线段，能不能把之前选中的线段默认为需要偏移的线段
2、第二次偏移的时候，您的程序确实存储了第一次偏移的设定值，但显示的方法可不可以优化一下：能不能改成“Specify offset distance or<2 6 23>：”。这样就节省了一个敲No，然后输入设定值的步骤。

最后万分感谢Andyhon大侠的相助，你是最棒的。

账号		自动登录	找回密码
密码			注册

求一个根据一组设定值进行偏移的LSP程序

相关帖子

评分

本帖子中包含更多资源