(defun c:addatts

前生

(defun c:addatts (/ oecho blkName tagName ss totVal index en val txtPt)
   ;;
   ;;subroutine to extract attribute value from a block
   ;;
     (defun attval (ins att / attnam val)
        (while (and
                 (/= attnam att)
                 (/= (cdr (assoc 0 (entget ins))) "SEQEND")
               )
               (setq attnam (cdr (assoc 2 (entget ins))))
               (if (= attnam att)
                   (setq val (cdr (assoc 1 (entget ins))))
               )
               (setq ins (entnext ins))
        )
        (eval val)
     );end attval
   ;;
   ;;start of main 'addatts' function
   ;;
     (setq
       oecho (getvar "cmdecho")
       blkName (strcase (getstring "\nBlock name: "))
       tagName (strcase (getstring "\nTag name to total: "))
       ss (ssget "x" (list '(0 . "insert")(cons 2 blkName)))
       totVal 0
       index 0
     )
     (setvar "cmdecho" 0)
     (cond
       ((not ss)
        (princ "\nInvalid block name.")
       )
       ((not (attval (ssname ss index) tagName))
        (princ "\nInvalid attribute tag.")
       )
       (T
        (repeat (sslength ss)
          (setq
            en (ssname ss index)
            val (distof (attval en tagName))
            index (1+ index)
          )
          (if val (setq totVal (+ totVal val)))
        );end repeat
        (setq
          totVal (rtos totVal)
          txtPt (getpoint "\nInsertion point for total value: ")
        )
        (command
          "._text"
          "middle"
           txtpt
        )
        (if (= 0.0 (cdr (assoc 40 (tblsearch "style" (getvar "textstyle")))))
           (command "" "" totVal)
           (command "" totVal)
        )
       )
     );end cond
     (setvar "cmdecho" oecho)
     (princ)
   );end addatts

HQ_2003

此程序有何功能，能解释一下吗？