舍去和修改尺寸标注小数点后数值

sz721 · 发表于 2012-9-21 22:23:39

本帖最后由 sz721 于 2012-9-21 22:24 编辑

选择需要修改的标注，使其尺寸数值取整或保留小数点一位（都为 .5）。如果小数点后数值为 0.1~0.4 则舍去小数取整。如果小数点后数值为 0.5~0.9 则保留小数并一律改为 0.5 。整数不做改变。效果如下：

cable2004 · 发表于 2012-9-21 22:23:40

本帖最后由 cable2004 于 2012-9-25 02:09 编辑

(defun c:tt( / e en rd rd1 sd1 ti%)
  (princ "\n选择要修改的尺寸：")
  (setq sd1 (ssget '((0 . "DIMENSION"))))
  (setq ti% 0)
  (repeat  (sslength sd1)
   (setq en (ssname sd1 ti%))
   (setq e (entget en))
   (setq rd (cdr (assoc 42 e)))
   (if (equal (fix rd) (fix (+ 0.5 rd)) 0)
      (setq rd1 (rtos (fix rd) 2 0))
      (setq rd1 (rtos (+ (fix rd) 0.5) 2 1))
)
  (entmod (subst (cons 1  rd1) (assoc 1 e) e))
(setq ti%(+ 1 ti%))
)
)

xshrimp · 发表于 2012-9-21 22:41:47

设置标注样式可以满足要求

nigma · 发表于 2012-9-21 22:44:49

本帖最后由 nigma 于 2012-9-21 22:45 编辑

这个在autocad里面有控制的吧
例如DIMRND=0.5就可以了。

sz721 · 发表于 2012-9-21 22:55:07

本帖最后由 sz721 于 2012-9-21 22:58 编辑

nigma 发表于 2012-9-21 22:44
这个在autocad里面有控制的吧
例如DIMRND=0.5就可以了。

主要是我要修改别人的图纸，况且设置0.5的话，数值碰到0.8或0.9就会进1。

陨落 · 发表于 2012-9-23 11:26:36

这个好说，

lyqiezi · 发表于 2012-9-24 23:09:52

本帖最后由 lyqiezi 于 2012-9-24 23:10 编辑

(defun c:cc5()
  (princ "\n选择要修改的尺寸：")
  (setq sd1 (ssget '((0 . "DIMENSION"))))
  (setq ti% 0)
  (if (/= sd1 nil)
   (while
      (<= ti%
      (- (sslength sd1) 1)
      )
   (setq en (ssname sd1 ti%))
   (setq e (entget en))
   (setq od (assoc 1 e))
   (setq rd (cdr (assoc 42 e)))
   (setq dt1 (cdr od))
   (if (= dt1 "")
      (setq dt1 (rtos rd 2 2))
   )
   (setq xsd (vl-string-search "." dt1))
   (if (/= xsd nil)
      (progn
      (setq ndt1 (substr dt1 1 xsd))
      (setq ndt2 (atof (substr dt1 (+ xsd 2) 1)))
      (if (<= ndt2 4)
            (setq ndt2 "")
            (setq ndt2 ".5")
      )
      (setq ndt (strcat ndt1 ndt2))
      (setq nd (cons 1 ndt))
      (setq e (subst nd od e))
      (entmod e)
   )
   )
   (setq ti%(+ 1 ti%))
   )
)
(prin1)
)

lyqiezi · 发表于 2012-9-24 23:13:23

搞了半天，终于搞出来了
尺寸标注的42跟1是不同的格式，看着算出来的数都对，结果一开始只对修改过的尺寸有效，害我找了老半天的问题，好不容易才发现一个是字符，一个是数值

sscylh · 发表于 2012-9-24 23:42:47

如果用vba做的话,很简单,一个for循环就可以了,建议楼主发一个dwg格式的上来,方便调试代码

xyp1964 · 发表于 2012-9-25 07:36:20

本帖最后由 xyp1964 于 2012-9-25 07:36 编辑

需要考虑伪尺寸的情况

;; 伪源码需要e派工具箱的支持
(defun c:tt ()
(setq i -1)
(princ "\n选择要修改的尺寸: ")
(if (setq ss (ssget '((0 . "DIMENSION"))))
(while (setq s1 (ssname ss (setq i (1+ i))))
(setq tx (xyp-dxf 1 s1)
rd (if (= tx "")
(xyp-dxf 42 s1)
(distof tx)
)
r0 (fix rd)
r1 (if (equal r0 (fix (+ 0.5 rd)) 0)
(rtos r0 2 0)
(rtos (+ r0 0.5) 2 1)
)
)
(xyp-SubUpd s1 1 r1)
)
)
(princ)
)

账号		自动登录	找回密码
密码			注册

舍去和修改尺寸标注小数点后数值

最佳答案

点评

相关帖子

本帖子中包含更多资源

点评

浏览过的版块