明经CAD社区

 找回密码
 注册

QQ登录

只需一步,快速开始

搜索
查看: 1808|回复: 3

起重机箱型梁绘制和强度、刚度验算源程序

[复制链接]
发表于 2012-12-23 11:26 | 显示全部楼层 |阅读模式
(defun c:xjie (/ jie1 jie2 jie3 jie4 jie5 jie6 jie7 ji8 ji9 en1 en2 en3
        en4)   ;(ppg1是全局变量,后面要用)工字钢绘制,gzgcan内部含:平均腿厚t、r、r1、Ix参数
  (setq jiemga (getint "截面高:"))
  (setq jiekua (getint "截面宽:"))
  (setq gaibho (getreal "盖板厚:"))
  (setq fubanh (getreal "腹板厚:"))
  (setq neisho (getreal "腹板内缩:"))
  (setvar "cmdecho" 0)   ;禁止    命令 回显
  (SETVAR "OSMODE" 0)   ;禁止    对象 捕捉
  (command "LAYER"   "m"       "中心线"  "ON"    "中心线"  "c"
    1      "中心线"  "l"  "CENTERX2"      "中心线"
    "LW"      0.13      "中心线"  ""
   )
  (setq jie11 (/ jiemga 2)
jie12 (/ jiekua 2)
  )     ;高度/厚
  (command "line"
    (list 0 (+ jie11 20))
    (list 0 (* (+ jie11 20) -1))
    ""
  )
  (command "LAYER"   "m"       "粗实线"  "ON"    "粗实线"  "c"
    7      "粗实线"  "l"  "continuous"      "粗实线"
    "LW"      0.35      "粗实线"  ""
   )
  (setq jie1 (list (* jie12 -1) jie11))
  (setq jie2 (list jie12 (- jie11 gaibho)))
  (setq jie3 (list (* jie12 -1) (* (- jie11 gaibho) -1)))
  (setq jie4 (list jie12 (* jie11 -1)))
  (setq jie5 (list (* (- jie12 neisho) -1) (- jie11 gaibho)))
  (setq jie7 (list (* (- jie12 neisho fubanh) -1)
     (* (- jie11 gaibho) -1)
      )
  )
  (setq jie6 (list (- jie12 neisho) (- jie11 gaibho)))
  (setq jie8 (list (- jie12 neisho fubanh) (* (- jie11 gaibho) -1)))
  (setq zongmianji
  (+ (* jiekua gaibho 0.02)
     (* (- jiemga gaibho gaibho) fubanh 0.02)
  )
  )     ;总面积 平方厘米
  (command "rectang" jie1 jie2 "")
  (setq en1 (entlast))
  (command "rectang" jie3 jie4 "")
  (setq en2 (entlast))
  (command "rectang" jie5 jie7 "")
  (setq en3 (entlast))
  (command "rectang" jie6 jie8 "")
  (setq en4 (entlast))
  (command "LAYER"   "m"       "剖面线"  "ON"    "剖面线"  "C"
    5      "剖面线"  "l"  "continuous"      "剖面线"
    "LW"      0.13      "剖面线"  ""
   )
  (command "hatch" "ANSI31" 2 0 en1 "") ;填充,参数:图案名称、图案比例、剖面线与45°的夹角、"L"表示对最近生成的图元进行充填)"JIS_LC_20A"
  (command "hatch" "ANSI31" 2 0 en2 "")
  (command "hatch" "ANSI31" 2 90 en3 "")
  (command "hatch" "ANSI31" 2 90 en4 "")
  (setvar "clayer" "粗实线")
  (setq jiemga (/ jiemga 10.000)) ;转换成厘米CM
  (setq jiekua (/ jiekua 10.000))
  (setq gaibho (/ gaibho 10.000))
  (setq fubanh (/ fubanh 10.000))
  (setq neisho (/ neisho 10.000))
  (setq guanxingjux
  (/ (- (* jiekua (expt jiemga 3))
        (* (- jiekua (* fubanh 2))
    (expt (- jiemga (* gaibho 2)) 3)
        )
     )
     12
  )
  )     ;惯性矩Ix公式,公式来源:参见,袖珍机械设计师手册P48
  (command "text"
    "ML"
    '(1000 0)
    38
    0
    (strcat "Ix=" (rtos guanxingjux 2 3))
    ""
  )
  (command "text" "ML" '(1369 0) 38 0 "/cm" "")
  (command "text" "ML" '(1448 20) 18 0 "4" "")
  (setq guanxingjuy
  (+ (/ (* gaibho (expt jiekua 3) 2) 12.0)
     (* (/ (- jiemga (* gaibho 2)) 12.0)
        (- (expt (- jiekua (* neisho 2)) 3)
    (expt (- jiekua (* neisho 2) (* fubanh 2)) 3)
        )
     )
  )
  )     ;惯性矩Iy公式,相当于Ix旋转90度
  (command "text"
    "ML"
    '(1000 -80)
    38
    0
    (strcat "Iy=" (rtos guanxingjuy 2 3))
    ""
  )
  (command "text" "ML" '(1369 -80) 38 0 "/cm" "")
  (command "text" "ML" '(1448 -60) 18 0 "4" "")
  (setq jimianxishu
  (/ (- (* jiekua (expt jiemga 3))
        (* (- jiekua (* fubanh 2))
    (expt (- jiemga (* gaibho 2)) 3)
        )
     )
     6
     jiemga
  )
  )     ;抗弯截面系数Wz,公式来源:参见,袖珍机械设计师手册P48
  (command "text"
    "ML"
    '(1000 -160)
    38
    0
    (strcat "Wx=" (rtos jimianxishu 2 2))
    ""
  )
  (command "text" "ML" '(1369 -160) 38 0 "/cm" "")
  (command "text" "ML" '(1448 -140) 18 0 "3" "")
  (command "text"
    "ML"
    '(1000 -240)
    38
    0
    (strcat "截面总面积=" (rtos zongmianji 2 3))
    ""
  )
  (command "text" "ML" '(1469 -240) 38 0 "/cm" "")
  (command "text" "ML" '(1548 -220) 18 0 "2" "")
  (command "text"
    "ML"
    '(1000 -320)
    38
    0
    (strcat "理论重量=" (rtos (* zongmianji 0.783) 2 3))
    ""
  )
  (command "text" "ML" '(1469 -320) 38 0 "Kg/m" "")
  (SETVAR "OSMODE" 1)   ;允许 对象捕捉
  (command "zoom" "e")   ;图纸居中
  (qdys)    ;强度验算,子程序
)     ;绘制主梁的箱型截面,然后验算强度和刚度
(defun qdys ()    ;《强度验算》
  (setq zzaihe (getreal "主梁总载荷(含小车和自重)t:"))
  (setq zkuadu (getreal "跨度m:"))
     ;假定主梁材料用Q235,(setq xuyongyingli (*(/ jiemmj 2.00 100)330.000) zuidawanju(* zzaihe 9.8 zkuadu 0.25) )
     ;本设计(只和材料与受拉断面的面积有关)的最大许用应力xuyongyingli,其单位为MPa;(力×力臂)最大弯矩zuidawanju的单位为kN·m
;;;(setq zuidayingli (/ (* zaidawanju (expt 10 6)) (* jiemxs(expt 10 3)) ) ) ;(最大弯矩/截面系数)=梁断面承受的最大应力zuidayingli
;;;  ;最大许用应力xuyongyingli和  梁断面承受的最大应力zuidayingli做比较
;;;(command "text"  "ML"  '(1000 0) 180 0 (strcat "经校验,梁是" (if (>= xuyongyingli zuidayingli) "安全的( √ )。" "不安全的( × )。")""));惯性矩Ix公式
  (setq qdyaoqiu (+ (/ (* zzaihe 9.8 (expt (* zkuadu 100) 3))
         (* 48 206 100)
         guanxingjux
      )
      (/ (* 5.00
     (* zongmianji 0.00000783 9.8)
     (expt (* zkuadu 100) 4)
         )
         (* 384 206 100)
         guanxingjux
      )
   )
  )     ;强度要求
     ;冲击载荷静挠度+梁自重形成的均布载荷引起的静挠度,
     ;计算单位的换算:1MPa=1N/mm^2=100N/平方厘米=0.1kN/平方厘米,面积长度均用厘米,206GPa=(206*1000MPa)*0.1=206*100(kN/平方厘米),计算单位均为厘米
  (if (<= (/ (* zzaihe 9.8 zkuadu 0.25 1000) jimianxishu) 117.5)
     ;(总载荷×总跨度×0.25×1000)÷抗弯截面系数
    (command
      "text"
      "ML"
      '(1000 -510)
      48
      0
      (strcat "抗拉强度需:"
       (rtos (/ (* zzaihe 9.8 zkuadu 0.25 1000) jimianxishu) 2 1)
       "MPa, 通过强度校验( √ )。"
      )
    )
    (command
      "text"
      "ML"
      '(1000 -510)
      48
      0
      (strcat "抗拉强度需:"
       (rtos (/ (* zzaihe 9.8 zkuadu 0.25 1000) jimianxishu) 2 1)
       "MPa, 无法通过强度校验( × )。"
      )
    )
  )
  (command "text"
    "ML"
    '(1000 -410)
    48
    0
    (strcat "如果将本截面做成载荷(起重量加葫芦):"
     (rtos zzaihe 2 1)
     " t,跨度:"
     (rtos zkuadu 2 2)
     " m的单梁起重机,"
    )
  )
  (if (<= qdyaoqiu (/ zkuadu 7.5)) ;计算依据:GB/T1306-2008 建议垂直静挠度f≦S/750,此处跨度的计算单位从M转换成CM,即qdyaoqiu和(/ zkuadu 7.5)的单位均是厘米.
    (command "text"
      "ML"
      '(1000 -610)
      48
      0
      (strcat "垂直静挠度小于等于S/750的:"
       (rtos (/ qdyaoqiu (/ zkuadu 7.5)) 2 2)
       "倍, 静态刚性符合规定( √ )。"
      )
    )
    (command "text"
      "ML"
      '(1000 -610)
      48
      0
      (strcat "垂直静挠度达S/750的:"
       (rtos (/ qdyaoqiu (/ zkuadu 7.5)) 2 2)
       "倍, 静态刚性不符合规定( × )。"
      )
    )
  )
  (SETVAR "OSMODE" 1)   ;对象捕捉
  (command "zoom" "e")
)     ;《强度验算》   end

发表于 2016-6-14 10:49 | 显示全部楼层
这个超赞,希望成为朋友
发表于 2016-6-14 10:53 | 显示全部楼层
超赞的文件,简捷明了
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码,在未取得本站及作者授权的情况下,不得用于商业用途

GMT+8, 2024-3-29 07:22 , Processed in 0.164321 second(s), 23 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表