hubeiwdlue 发表于 2023-11-13 14:38:49

动态字宽

本帖最后由 hubeiwdlue 于 2023-11-14 13:13 编辑

   最近需要一个动态字宽的插件，在论坛中找了几个，感觉都不是自己想要了，就自己写了一个简单的单行文本动态字宽的代码。
-----2023.11.14
    修复了一个bug，原先子函数wdl_wzboxdown算法有问题，现已更新。已经下载的朋友，可以直接将子函数替换一下就可以了。(defun wdl_wzboxdown(en / END PTS ANG ZG PT LENTXT PTE)
    (setq end (entget en))
    (setq pts (cdr (assoc 10 end)))
    (setq ang (cdr (assoc 50 end)))
    (setq zg (cdr (assoc 40 end)))
    (setq pt (textbox end))
    (setq lentxt (caadr pt))
    (setq pte (polar pts ang lentxt))
    (list pts pte)
)





183017064 发表于 2025-3-18 13:41:52

潘成祥2015 发表于 2023-11-13 17:30
如果也能输入值就好了
加了输入值

(defun c:zkk(/ EN ENTDATA ANG PTS PTE DIS1 GR P1 PT_FZ P2 DIS2 FLAG ZK ZK_FLAG wdl_wzboxdown new_zk)
;; 提取包容盒底部2点坐标
(defun wdl_wzboxdown(en / END PTS ANG ZG PT LENTXT PTE)
    (setq end (entget en))
    (setq pts (cdr (assoc 10 end)))
    (setq ang (cdr (assoc 50 end)))
    (setq zg (cdr (assoc 40 end)))
    (setq pt (textbox end))   
    (setq lentxt (caadr pt))
    (setq pte (polar pts ang lentxt))
    (list pts pte)
)

;; main
(setq en (car(entsel)))
(setq entdata (entget en))
(if (wcmatch (cdr(assoc 0 entdata)) "TEXT")
    (progn
      (setq ang (cdr (assoc 50 entdata))) ; 文字转角
      (setq pts (car (wdl_wzboxdown en))) ; 文字起点
      (setq pte (cadr (wdl_wzboxdown en))) ; 文字终点
      (setq dis1 (distance pts pte)) ; 文字宽度
      (setq zk (cdr (assoc 41 entdata))) ; 原宽度因子
      
      (princ "\n拖动鼠标调整或按输入数值: ")
      (while (setq gr (grread t 12 0)) ; 允许混合输入模式
      (cond
          ;; 鼠标拖动模式
          ((= (car gr) 5)
            (setq p1 (cadr gr))
            (setq pt_fz (polar p1 (+ ang (/ pi 2)) 1))
            (setq p2 (inters p1 pt_fz pts pte nil))
            (setq dis2 (distance pts p2))
            (redraw) ; 清空临时图形
            (grdraw p1 p2 3 1) ; 绘制动态引导线
            (setq flag (/ dis2 dis1))
            (setq zk_flag (* zk flag))
            (princ (strcat "\r当前宽度因子: " (rtos zk_flag 2 2))) ; 动态显示数值
            (entmod (subst (cons 41 zk_flag) (assoc 41 entdata) entdata)) ; 实时更新
          )
         
          ;; 键盘输入模式
          ((= (car gr) 2)
            (if (= (cadr gr) 13) ; 检测回车键
            (progn
                (initget 1) ; 禁止空输入
                (setq new_zk (getreal (strcat "\n输入新宽度因子 <" (rtos zk_flag 2 2) ">: "))) ; 带默认值的输入提示
                (if new_zk
                  (progn
                  (entmod (subst (cons 41 new_zk) (assoc 41 entdata) entdata)) ; 应用输入值
                  (setq zk_flag new_zk) ; 更新当前值
                  )
                )
                (exit) ; 退出循环
            )
            )
          )
         
          ;; 退出条件（左键/右键点击）
          ((or (= (car gr) 3) (= (car gr) 25)) (exit))
      )
      )
    )
    (princ "\n错误：请选择文字对象！")
)
(princ)
)

d1742647821 发表于 2023-11-15 16:54:20

hubeiwdlue 发表于 2023-11-15 11:43
字宽啊。我一般是调整图纸名称的时候用这个，有的图纸编号太长了，图名框放不下，动态的调起来方便一些。

多行的时候，字宽变窄了，就有可能3行变2行，实际宽度并没有发生改变

hubeiwdlue 发表于 2023-11-15 19:05:16

d1742647821 发表于 2023-11-15 16:54
多行的时候，字宽变窄了，就有可能3行变2行，实际宽度并没有发生改变

哦，是的。我就是想学习下，大神们都是怎么操作多行文字的字宽的，能发一段代码给我学习下吗？

戏男 发表于 2023-11-13 16:55:17

这样调节字的宽度就方便多了，很历害的功能

wangsr 发表于 2023-11-13 17:03:23

我试用了好用，如能再支持多行文字就更好了。

潘成祥2015 发表于 2023-11-13 17:30:39

如果也能输入值就好了

hubeiwdlue 发表于 2023-11-13 17:46:22

wangsr 发表于 2023-11-13 17:03
我试用了好用，如能再支持多行文字就更好了。

我不知道多行文字的宽度因子怎么调用，组码、属性里面好像都没有。

wangsr 发表于 2023-11-14 07:33:58

hubeiwdlue 发表于 2023-11-13 17:46
我不知道多行文字的宽度因子怎么调用，组码、属性里面好像都没有。

我们群内的高手有时间完善一下谢谢。

paulpipi 发表于 2023-11-14 08:36:31

感谢分享，简单实用

菜鸟初来乍到 发表于 2023-11-14 10:39:01

感谢楼主分享

tiancao100 发表于 2023-11-14 16:18:31

怎么会有这种需求

szhorse 发表于 2023-11-14 22:34:31

看着不错的功能，明早试试
页: [1] 2 3
查看完整版本: 动态字宽