字符串UTF-8编码互转
本帖最后由 tryhi 于 2024-10-29 17:13 编辑用的不多，但是有这方面需求的人其实也不少，但是论坛也基本没这方面的代码，类似于vl-string->list和vl-list->string，只不过用的是UTF-8
;;将任意字符串转换为UTF-8编码，返回十进制数据表__作者：tryhi-大海
;;(try-str2UTF-8 "编码") ;-->(231 188 150 231 160 129)
(defun try-str2UTF-8 (str / file_list fileget stream)
(if (setq stream (vlax-create-object "Adodb.Stream"))
(progn
(vlax-put-property stream 'Type 2) ; 1二进制读取 2文本模式读取
(vlax-put-property stream 'Mode 3) ; 1-读,2-写,3-读写
(vlax-put-property stream 'Charset "utf-8") ; 设置编码为UTF-8
(vlax-invoke stream 'Open)
(vlax-invoke stream 'WriteText str)
(vlax-put-property stream 'Position 0) ; 将位置重置为起始位置
(vlax-put-property stream 'Type 1) ; 1二进制读取 2文本模式读取
(setq FileGet(Vlax-Invoke-Method stream 'Read nil))
(setq File_list (vlax-safearray->list (vlax-variant-value FileGet)))
(vlax-release-object stream)
(cdddr File_list);去除BOM
)
(princ"\n无法创建'Adodb.Stream'对象")
)
)
;;将UTF-8编码的十进制数据表转换为字符串__作者：tryhi-大海
;;(try-UTF-8toStr '(231 188 150 231 160 129)) ;-->"编码"
(defun try-UTF-8toStr (decList / stream result saFileGet)
(if (setq stream (vlax-create-object "Adodb.Stream"))
(progn
(vlax-put-property stream 'Type 1) ; 1二进制读取 2文本模式读取
(vlax-invoke stream 'Open);; 打开流
(setq saFileGet (vlax-make-safearray 17 (cons 0 (1- (length decList)))));; 创建SafeArray
(vlax-safearray-fill saFileGet decList);; 填充SafeArray
(Vlax-Invoke-Method stream 'Write saFileGet);; 写入二进制数据
(vlax-put-property stream 'Position 0);; 将位置重置为起始位置
(vlax-put-property stream 'Type 2); 2文本模式读取
(vlax-put-property stream 'Charset "utf-8")
(setq result (Vlax-Invoke-Method stream 'ReadText nil));; 读取文本数据
(vlax-release-object stream);; 释放对象
result
)
(princ"\n无法创建'Adodb.Stream'对象")
)
)
将字符串转换为UTF-8编码，返回十进制数据表
(try-str2UTF-8 "编码")
返回：(231 188 150 231 160 129)
将UTF-8编码的十进制数据表转换为字符串
(try-UTF-8toStr '(231 188 150 231 160 129))
返回："编码"
tryhi 发表于 2024-7-9 17:43
同样的办法就可以,charset参数可以用unicode;utf-8;ascii;gb2312;big5;gbk
(defun try-str2gbk (str / file_list fileget stream)
(if (setq stream (vlax-create-object "Adodb.Stream"))
(progn
(vlax-put-property stream 'Type 2) ; 1二进制读取 2文本模式读取
(vlax-put-property stream 'Mode 3) ; 1-读,2-写,3-读写
(vlax-put-property stream 'Charset "GBK") ; 设置编码为GBK
(vlax-invoke stream 'Open)
(vlax-invoke stream 'WriteText str)
(vlax-put-property stream 'Position 0) ; 将位置重置为起始位置
(vlax-put-property stream 'Type 1) ; 1二进制读取 2文本模式读取
(setq FileGet(Vlax-Invoke-Method stream 'Read nil))
(setq File_list (vlax-safearray->list (vlax-variant-value FileGet)))
(vlax-release-object stream)
(cdddr File_list);去除BOM
)
(princ"\n无法创建'Adodb.Stream'对象")
)
)
测试：(try-str2gbk "编码") ;-->(235) 不对的，知道哪里没有改对呢？ 本帖最后由 tryhi 于 2024-10-29 18:23 编辑
尘缘一生 发表于 2024-10-29 17:21
(try-UTF-8toStr (try-str2UTF-8 "\n 无法创建'Adodb.Stream'对象")))
这样是不是，简体，繁体，都支持 ...
我实在不知道怎么回答你这个问题，因为你完全误解了这两个函数的功能，换个问题，vl-string->list和vl-list->string你用过吗？
如果用过，可能就能理解，如果没用过，建议先查一下这两个系统函数的功能以及作用
这两个函数作用是用来在必须使用utf-8时可以正常转换，比如9楼调用sqlite，或者某些网页交互，或者SHP文件构建，又或者遇到某些系统必须使用UTF-8的文本等等……跟你说的什么princ没有任何关系
本帖最后由 tryhi 于 2024-7-11 09:51 编辑
flowerson 发表于 2024-7-10 11:01
感谢，海大师。我一行行试，能理解你说的了。“GBK没有BOM这3个字节” 但是这些知识是怎样积累到的 ...
其实是因为我在写UTF-8的时候发现总是多出来3个字节，那么百度UTF-8后发现那叫BOM，那去掉3个字节就解决，那其他编码不存在这个问题，就不需要去了
那么你在改GBK的时候同样道理，你直接套用我的函数就会发现总是少了3个字节，代码总共才十来行，那大概看一下就会发现最后一句cdddr，你删了去掉不就解决了，这是逻辑思考问题，不是知识积累
海哥出品必属精品，感谢海哥分享~:lol 海哥出品必属精品 感谢作者的分享！
海哥出品必属精品 不错，来学习学习 大海哥又又又玩啥呢 海哥正给力 非常不错，我之前研究sqlite的exe的时候，lisp调用官方的exe，返回来的是UTF-8字串，我一直没搞定，看了你这个帖子，瞬间明白了，接下来我将sqlite官方的数据库exe分享出来，结合大海这个帖子，希望同仁们少走弯路 本帖最后由 你有种再说一遍 于 2024-7-6 17:51 编辑
dcl12142024-7-6 15:57
非常不错，我之前研究sqlite的exe的时候，lisp调用官方的exe，返回来的是UTF-8字串，我一直没搞定，看了你这个帖子，瞬间明白了，接下来我将sqlite官方的数据库exe分享出来，结合大海这个帖子，希望同仁们少走弯路
lisp终点是ActiveX(com),至于有没有函数提示,那就全凭vb功力了...