如何获取用 List 命令输出的数据？

guosheyang

三维实体的范围可以试下李迈克的函数 (LM:ssboundingbox(ssget))

mokson

guosheyang 发表于 2022-3-2 20:51
三维实体的范围可以试下李迈克的函数 (LM:ssboundingbox(ssget))

请问要下载安装什么插件吗？

guosheyang

;; Selection Set Bounding Box  -  Lee Mac
;; Returns a list of the lower-left and upper-right WCS coordinates of a
;; rectangular frame bounding all objects in a supplied selection set.
;; s - [sel] Selection set for which to return bounding box
;(LM:ssboundingbox(ssget))
(defun LM:ssboundingbox( s / a b i m n o )
    (repeat (setq i (sslength s))
        (if
            (and
                (setq o (vlax-ename->vla-object (ssname s (setq i (1- i)))))
                (vlax-method-applicable-p o 'getboundingbox)
                (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list o 'a 'b))))
            )
            (setq m (cons (vlax-safearray->list a) m)
                  n (cons (vlax-safearray->list b) n)
            )
        )
    )
    (if (and m n)
        (mapcar '(lambda ( a b ) (apply 'mapcar (cons a b))) '(min max) (list m n))
    )
)