自动标注问题？

chui

我是个新手。
我在这个网站看了关于面积标注的lisp程序，原先是要指定标注位置的，现在我想通过选择对象后，自动求出该面域的中心位置，将文字标注在重心位置上，我对它进行了修改，但是行不通，请教各位了！

龙龙仔

(defun C:MJBZ (/        TXTSIZE         HEADTXT  PRECISION            OLDCMD
               SEL        ENT         ENTLIST  ENTNAME  VLAENT   AREA
               PT        REGENT
              )
  (setq TXTSIZE (getvar "dimtxt"))
  (setq HEADTXT "地块总面积为: ")
  (setq PRECISION 3)
  (setq OLDCMD (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq SEL t)
  (vl-load-com)
  (while SEL
    (setq ENT (entsel "\n选取封闭多义线/面域: "))
    (if        ENT
      (progn
        (setq ENTLIST (entget (car ENT)))
        (setq ENTNAME (strcase (cdr (assoc 0 ENTLIST))))
        (cond
          ((and        (wcmatch ENTNAME "*POLYLINE")
                (setq VLAENT (vlax-ename->vla-object (car ENT)))
                (= :vlax-true (vla-get-closed VLAENT))
           )
           (setq AREA
                  (strcat HEADTXT
                          (rtos (vlax-curve-getarea VLAENT) 2 PRECISION)
                  )
           )
           (command "_.copy" (car ENT) "" "0,0" "0,0")
           (command "region" (car ENT) "")
           (setq REGENT (entlast))
           (setq PT (vlax-get (vlax-ename->vla-object REGENT)
                              "centroid"
                    )
           )
           (entdel (entlast))
           (command "text" "j" "c" PT TXTSIZE "" AREA)
          )
          ((= ENTNAME "REGION")
           (command "area" "o" (car ENT))
           (setq
             AREA (strcat HEADTXT (rtos (getvar "area") 2 PRECISION))
           )
           (setq REGENT (car ENT))
           (setq PT
                  (vlax-get (vlax-ename->vla-object REGENT) "centroid")
           )
           (command "text" "j" "c" PT TXTSIZE "" AREA)
          )
          (t
           (princ "\n所选对像非封闭多义线/面域")
          )
        )
      )
      (setq SEL NIL)
    )
  )
  (setvar "cmdecho" OLDCMD)
  (princ)
)

chui

我回加倍努力的！