LISP计算时间差

yeshuaxing · 发表于 2012-7-1 15:24:17

各位好，请问LISP如何计算时间差，我的日期为字符串，计算两日期间的天数要如何写LISP代码？

Andyhon · 发表于 2012-7-1 15:56:51

Command: (- (distof "20120702") (distof "20120701"))
1.0

Command: (- (atoi "20120702") (atoi "20120701"))
1

nzl1116 · 发表于 2012-7-1 16:17:13

;;;返回指定年份的总天数
(defun dt-dates (oneyear)
(if (numberp oneyear)
(if (= 0 (rem oneyear 4))
(if (= 0 (rem oneyear 100))
(if (= 0 (rem oneyear 400))
366
365
)
366
)
365
)
)
)
;;;返回指定年份每个月和对应的天数的关联表
(defun dt-everyMonth-list (spacYear)
(list
(cons 1 31)
(cons 2
(if (= 0 (rem spacYear 4))
(if (= 0 (rem spacYear 100))
(if (= 0 (rem spacYear 400))
29
28
)
29
)
28
)
)
(cons 3 31)
(cons 4 30)
(cons 5 31)
(cons 6 30)
(cons 7 31)
(cons 8 31)
(cons 9 30)
(cons 10 31)
(cons 11 30)
(cons 12 31)
)
)
;;;返回指定日期是当年的第几天
;;;spyear 指定年份
;;;spmonth 指定月份
;;;spdate 指定日期
(defun dt-nthdate (spyear spmonth spdate / ddList somemon sumdates)
(if (and (numberp spyear) (numberp spmonth) (numberp spdate))
(progn
(setq ddList (dt-everyMonth-list spyear)
somemon 1
sumdates 0
)
(while (< somemon spmonth)
(setq sumdates (+ (cdr (assoc somemon ddList)) sumdates)
somemon (1+ somemon)
)
)
(+ sumdates spdate)
)
)
)
;;;两个日期之间的天数
(defun dt-dist (mList nList / maxyear minyear maxList minList someyear
sumdate)
(if (and (numberp (caddr mList)) (numberp (caddr nList)))
(if (/= (car mList) (car nList))
(progn
(setq maxyear (max (car mList) (car nList))
minyear (min (car mList) (car nList))
maxList (assoc maxyear (list mList nList))
minList (assoc minyear (list mList nList))
)
(setq someyear (+ minyear 1)
sumdate 0
)
(while (< someyear maxyear)
(setq sumdate (+ (dt-dates someyear) sumdate)
someyear (1+ someyear)
)
)
(+ (- (dt-dates minyear)
(dt-nthdate minyear (cadr minList) (caddr minList))
)
sumdate
(dt-nthdate maxyear (cadr maxList) (caddr maxList))
)
)
(abs (- (dt-nthdate (car mList) (cadr mList) (caddr mList))
(dt-nthdate (car nList) (cadr nList) (caddr nList))
)
)
)
)
)

;;;返回指定年份的总天数 
(defun dt-dates        (oneyear) 
  (if (numberp oneyear) 
    (if        (= 0 (rem oneyear 4)) 
      (if (= 0 (rem oneyear 100)) 
        (if (= 0 (rem oneyear 400)) 
          366 
          365 
        ) 
        366 
      ) 
      365 
    ) 
  ) 
) 
;;;返回指定年份每个月和对应的天数的关联表 
(defun dt-everyMonth-list (spacYear) 
  (list 
    (cons 1 31) 
    (cons 2 
          (if (= 0 (rem spacYear 4)) 
            (if        (= 0 (rem spacYear 100)) 
              (if (= 0 (rem spacYear 400)) 
                29 
                28 
              ) 
              29 
            ) 
            28 
          ) 
    ) 
    (cons 3 31) 
    (cons 4 30) 
    (cons 5 31) 
    (cons 6 30) 
    (cons 7 31) 
    (cons 8 31) 
    (cons 9 30) 
    (cons 10 31) 
    (cons 11 30) 
    (cons 12 31) 
  ) 
) 
;;;返回指定日期是当年的第几天 
;;;spyear  指定年份 
;;;spmonth 指定月份 
;;;spdate  指定日期 
(defun dt-nthdate (spyear spmonth spdate / ddList somemon sumdates) 
  (if (and (numberp spyear) (numberp spmonth) (numberp spdate)) 
    (progn 
      (setq ddList   (dt-everyMonth-list spyear) 
            somemon  1 
            sumdates 0 
      ) 
      (while (< somemon spmonth) 
        (setq sumdates (+ (cdr (assoc somemon ddList)) sumdates) 
              somemon  (1+ somemon) 
        ) 
      ) 
      (+ sumdates spdate) 
    ) 
  ) 
) 
;;;两个日期之间的天数 
(defun dt-dist (mList nList / maxyear minyear maxList minList someyear 
                sumdate) 
  (if (and (numberp (caddr mList)) (numberp (caddr nList))) 
    (if        (/= (car mList) (car nList)) 
      (progn 
        (setq maxyear (max (car mList) (car nList)) 
              minyear (min (car mList) (car nList)) 
              maxList (assoc maxyear (list mList nList)) 
              minList (assoc minyear (list mList nList)) 
        ) 
        (setq someyear (+ minyear 1) 
              sumdate  0 
        ) 
        (while (< someyear maxyear) 
          (setq        sumdate         (+ (dt-dates someyear) sumdate) 
                someyear (1+ someyear) 
          ) 
        ) 
        (+ (- (dt-dates minyear) 
              (dt-nthdate minyear (cadr minList) (caddr minList)) 
           ) 
           sumdate 
           (dt-nthdate maxyear (cadr maxList) (caddr maxList)) 
        ) 
      ) 
      (abs (- (dt-nthdate (car mList) (cadr mList) (caddr mList)) 
              (dt-nthdate (car nList) (cadr nList) (caddr nList)) 
           ) 
      ) 
    ) 
  ) 
)

yeshuaxing · 发表于 2012-7-1 16:20:35

谢谢楼上的兄弟姐妹，太让我感动了

yeshuaxing · 发表于 2012-7-1 16:24:00

Andyhon 发表于 2012-7-1 15:56
Command: (- (distof "20120702") (distof "20120701"))
1.0

老大，这法子好象只适用于当月的情况，不过还是谢谢

Andyhon · 发表于 2012-7-1 16:40:51

...我的日期为字符串...

可否先来个示例?

Command: (Rtos (getVar "Cdate") 2 16)
"20120701.16370862"

Command: (Rtos (getVar "date") 2 16)
"2456110.692659502"

yeshuaxing · 发表于 2012-7-1 18:32:38

Andyhon 发表于 2012-7-1 16:40
...我的日期为字符串...

可否先来个示例?

;;;将字符串转为列表，str字符串,del字符串的分隔符
(DEFUN stringtolist (str del / pos lst)
(WHILE (SETQ pos (VL-STRING-SEARCH del str))
(SETQ lst (CONS (SUBSTR str 1 pos) lst)
str (SUBSTR str (+ pos 1 (STRLEN del)))
)
)
(REVERSE (CONS str lst))
)

yeshuaxing · 发表于 2012-7-1 18:37:53

本帖最后由 yeshuaxing 于 2012-7-1 18:39 编辑

Andyhon 发表于 2012-7-1 16:40
...我的日期为字符串...

可否先来个示例?

修改原代码
;;;两个日期之间的天数
(DEFUN dt-dist (mlist nlist / maxyear minyear maxlist minlist someyear
            sumdate
            );;;
;;;
;;; (setq mlist "2003/11/1" nlist "2003/1/1")
(SETQ mlist       (stringtolist mlist "/")
      nlist       (stringtolist nlist "/")
)
(SETQ mlist       (LIST (ATOI (CAR mlist))
                  (ATOI (CADR mlist))
                  (ATOI (CADDR mlist))
            )
)
(SETQ nlist       (LIST (ATOI (CAR nlist))
                  (ATOI (CADR nlist))
                  (ATOI (CADDR nlist))
            )
);;;上为增加的代码
;;;;
(IF (AND (NUMBERP (CADDR mlist)) (NUMBERP (CADDR nlist)))
(IF (/= (CAR mlist) (CAR nlist))
      (PROGN
(SETQ maxyear (MAX (CAR mlist) (CAR nlist))
      minyear (MIN (CAR mlist) (CAR nlist))
      maxlist (ASSOC maxyear (LIST mlist nlist))
      minlist (ASSOC minyear (LIST mlist nlist))
)
(SETQ someyear (+ minyear 1)
      sumdate  0
)
...............................................................

;;;将日期如：“2012/07/01”转为列表，str字符串,del字符串的分隔符
(DEFUN stringtolist (str del / pos lst)
(WHILE (SETQ pos (VL-STRING-SEARCH del str))
      (SETQ lst (CONS (SUBSTR str 1 pos) lst)
            str (SUBSTR str (+ pos 1 (STRLEN del)))
      )
)
(REVERSE (CONS str lst))
)

.................................

  应用举例： (dt-dist “2012/07/01”  “2011/1/1”)

Andyhon · 发表于 2012-7-1 20:44:43

这儿有个 Julian date 的示例可一并参考
http://forums.autodesk.com/t5/Vi ... d-Time/td-p/2400622

yeshuaxing · 发表于 2012-7-1 23:09:41

Andyhon 发表于 2012-7-1 20:44
这儿有个 Julian date 的示例可一并参考
http://forums.autodesk.com/t5/Visual-LISP-AutoLISP-and-Genera ...

谢谢Andyhon长老，你提供的代码可以解决问题了，再谢.....

账号		自动登录	找回密码
密码			注册

LISP计算时间差

相关帖子