求一个快速填充的程序

edata

新建文件试试，应该原来的函数没有覆盖掉，我这没问题

enn09

非常好用，感谢edata大神~~~~~~

fire9527

edata 发表于 2014-6-17 10:30
新建文件试试，应该原来的函数没有覆盖掉，我这没问题

可以了，很顺手、很方便的程序，非常感谢！

enn09

@edata,用完会改变以后所有的默认图层的颜色，跟线型，有没有办法改？

hooboxu

请问怎么删除填充边界啊???可以吗.大大们在吗?

迹扬

hooboxu 发表于 2014-11-23 01:04
请问怎么删除填充边界啊???可以吗.大大们在吗?

2楼和10楼的都是好程序，10楼的本身就是可以删除边界的啊？

迹扬

2#的加一句话就可以删除边界了。加完是这样子的：

迹扬

迹扬 发表于 2014-12-21 22:21
2#的加一句话就可以删除边界了。加完是这样子的：

;;快速填充command版本

;;code by edata@mjtd

;;2014-6-16

;;变函数参数

;;(sk_hatch_cmd sk_ha_name sk_ha_scale sk_ha_ang)

;;sk_ha_name 填充名字符串

;;sk_ha_scale 填充比例 数字或数字字符串

;;sk_ha_ang 填充角度 0-360度数字或数字字符串

;;例子(sk_hatch_cmd "earth" 100 0.0)

(defun sk_hatch_cmd( sk_ha_name sk_ha_scale sk_ha_ang / bak_clay bak_col bak_cmd en0 en1 en2 p1 p3)

  (or sk_ha_name (setq sk_ha_name "earth"))

  (or sk_ha_scale (setq sk_ha_scale 100))

  (or sk_ha_ang (setq sk_ha_ang 0.0))

  (setq bak_clay(getvar 'clayer)

        bak_col(getvar 'cecolor)

        bak_cmd(getvar 'cmdecho)

        )  

  (if(not(tblobjname "layer" "00-填充"))

    (entmake (list '(0 . "LAYER")

                   '(100 . "AcDbSymbolTableRecord")

                   '(100 . "AcDbLayerTableRecord")

                   '(70 . 0)

                   '(6 . "Continuous")

                   (cons 2 "00-填充")

                   (cons 62 5)

             )

    )

    )

  (setvar 'clayer "00-填充")

  (setvar 'cecolor "8")

  (setvar 'cmdecho 0)

  (while (and(setq p1(getpoint "\n指定第一点:"))

                 (setq p3(getcorner p1 "\n指定对角点:"))

                 )

    (progn

      (if(> (getvar 'cmdactive) 0)(command))

      (setq en0(entlast))

      (command "_.RECTANG" "_non" p1 "_non" p3)

      (setq en1(entlast))

      (command "-bhatch" "p" sk_ha_name sk_ha_scale sk_ha_ang "s" en1 "" "")
      
      (entdel en1)  ;这条是我加的，删除边界

      (if(> (getvar 'cmdactive) 0)(command))

      (setq en2(entlast))

      (if(sk_h5_eq en1 en2)

        (progn

        (alert "创建填充失败.")

        (if (not(sk_h5_eq en1 en0)) (entdel en1))

        )

        )

      )

    )  

  (and bak_clay(setvar 'clayer bak_clay))

  (and bak_col(setvar 'cecolor bak_col))

  (and bak_cmd(setvar 'cmdecho bak_cmd))  

  (princ)

  )

(defun sk_dxf(ent code)(cdr(assoc code (entget ent))))

(defun sk_h5_eq(ent1 ent2)

  (= (sk_dxf ent1 5)(sk_dxf ent2 5))

  )

(defun c:tt()

  (sk_hatch_cmd "earth" 100 0.0)

  (princ)

  )

(defun c:tt2()

  (sk_hatch_cmd "angle" 100 0.0)

  (princ)

  )

wangxf888

方便的填充程序  不错哦

放羊去的

收藏备用，好东西啊