CAD中快速查找图元

pxt2001

选择易，了解一下

taoyi0727

刘炎华 发表于 2019-12-26 12:15
您好！如果图档太大查找会卡死，可以设条件查找对象为相同图层吗？

可以的
看你要怎么改  是同选择对象一样的图层吗?还是手动自己输入图层

刘炎华

同选择对象同图层，谢谢！

刘炎华

补充下，査找对象可以与目标对象类型相同吗，谢谢！比如，多义线只对应多义线

taoyi0727

刘炎华 发表于 2019-12-26 13:56
补充下，査找对象可以与目标对象类型相同吗，谢谢！比如，多义线只对应多义线

可以的  晚上嘛  在上班呢

刘炎华

好的，谢谢！

taoyi0727

刘炎华 发表于 2019-12-26 14:46
好的，谢谢！

(defun c:tt (/ judge l lst-name name obj ss t-get-length t-layer t-length t-type)
        (defun T-get-Length (obj / t-length)
                (cond
                        ((or
                                 (= (vla-get-ObjectName obj) "AcDbPolyline")
                                 (= (vla-get-ObjectName obj) "AcDbLine")
                         )
                                (setq T-Length (vla-get-Length obj))
                        )
                        ((= (vla-get-ObjectName obj) "AcDbArc")
                                (setq T-Length (vla-get-ArcLength obj))
                        )
                        ((= (vla-get-ObjectName obj) "AcDbCircle")
                                (setq T-Length (* pi (vla-get-Radius obj) 2))
                        )
                        ((= (vla-get-ObjectName obj) "AcDbSpline")
                                (setq endpar (vlax-curve-getEndParam obj))
                                (setq T-Length (vlax-curve-getDistAtParam obj endpar))
                        )
                )
                T-Length
        )
        (setq judge t)
        (while (and
                                         judge
                                         (setq ss (ssget ":E:S"))
                                 )
                (setq obj (vlax-ename->vla-object (setq name (ssname ss 0))))
                (setq T-type (cdr (assoc 0 (entget name))));图元类型
                (setq T-Layer (vla-get-Layer obj));图元图层
                (setq T-Length (T-get-Length obj));图元长度
                (if T-Length
                        (progn
                                (setq ss (ssget "x" (list
                                                                                                                        '(-4 . "<and")
                                                                                                                        (cons 0 T-type);图元类型
                                                                                                                        (cons 8 T-Layer);图元图层
                                                                                                                        '(-4 . "and>")
                                                                                                                )
                                                                 )
                                )
                                (while (setq name (ssname ss 0))
                                        (setq l (T-get-Length (vlax-ename->vla-object name)))
                                        (if (equal T-Length l 0.1);容差0.1,这个自己根据需要来改
                                                (setq lst-name (append lst-name (list name)))
                                        )
                                        (ssdel name ss)
                                )
                                (setq judge nil)
                        )
                )
        )
        (if lst-name
                (progn
                        (setq ss (ssadd))
                        (foreach x lst-name
                                (ssadd x ss)
                        )
                        (sssetfirst nil ss)
                        (princ (strcat "\n找到 " (itoa (sslength ss)) " 个对象\n"))
                        (princ)
                )
        )
)
看下是不是这样的

刘炎华

可以了，非常感谢！

刘炎华

taoyi0727 发表于 2019-12-26 19:13
(defun c:tt (/ judge l lst-name name obj ss t-get-length t-layer t-length t-type)
        (defun T-get-L ...

您好！可以帮我指点下这个吗？
希望复制后的对象可以成为下个命令的选择集P，就弄了下面这个：
(defun C:CX()
(command "COPY" ss "" "0,0" "0,0")
(command "move" ss "")
(princ))

但是命令中“ESC”，或命令完成后“UNDO”，会在原来的位置有多出1个图元，怎么弄啊？
不好意思啊，打扰了...
希望有空的话能指点一下，谢谢！

taoyi0727

你说的我没有看明白，水平也不高。
你就说要你完成什么功能，看我能不能写出来