请教一下关于文件选取的问题。

alwaysbin · 发表于 2004-8-6 01:16:00

请教一下关于文件选取的问题。

比如我有2组文字，第一组为“2C14+2C20;2C25”，第二组为“;4C25”，我分别点取这两组文字，C为符号，在第一组中，我如何分别得到分号前面的数字的和？

比如，a1＝2×14+2×20 a2＝2×25，就是说按分号断，前面和后面的数字分别求和。

谢谢各位大侠！

meflying · 发表于 2004-8-6 09:15:00

(setq a (vl-string-subst " " ";" "2C14+2C20;2C25"))
(setq a (strcat "(" a ")"))
(read a)

alwaysbin · 发表于 2004-8-6 12:25:00

我是在R14里面用，用vl好像不行。

这样做只是得到了字符串，但是还是无法计算出结果啊，a1＝2×14+2×20＝68，怎样得到这个68的计算结果啊？？

meflying · 发表于 2004-8-6 13:43:00

到底是乘还是C？你是问如何分割还是问如何计算，还是要把你写一个完整的程序？如果是后者，你提供的信息还不够详细，还有，是否一定要在R14下使用？ (setq a (vl-string-subst " " ";" "2*14+2*20;2*25"))
(setq a (strcat "(" a ")"))
(setq a (mapcar 'vl-symbol-name (read a)))
(mapcar 'cal a)

alwaysbin · 发表于 2004-8-6 20:06:00

是符号，如果是乘号就好办了。我的是一个字符串“%%131”，是结构里的钢筋符号，2%%13116就表示2根16的钢筋，比如我有一串文字，"2%%13116;3%%13125"，怎样才能计算出分号前后的钢筋的面积啊？？或者是把根数和直径直接分离出来也可以。

可以不用14，只要2002能用就行。

如下图，黄色的为第一组数据，就是2%%13116;3%%13125，表示上部2根16，下部3根25，请问我如何能分别得到面积？？

alwaysbin · 发表于 2004-8-6 20:09:00

顺便把图也弄上来，我要得到的最终结果是判断白色的钢筋的面积是否小于分号后面的钢筋面积的1/4。

alin · 发表于 2004-8-7 00:56:00

本帖最后由作者于 2004-8-7 16:23:01 编辑

(defun C:tt(/ str1 str2 tmp1 tmp2 area1 area2)
(setq str1 (cdr (assoc 1 (entget (car (entsel "\n选择第一个text: ")))))
str2 (cdr (assoc 1 (entget (car (entsel "\n选择第二个text: ")))))
)
(setq tmp1 (Parse_It (vl-string-subst "x" "%%131" (last (Parse_It str1 ";"))) "x")
tmp2 (Parse_It (vl-string-subst "x" "%%131" (last (Parse_It str2 ";"))) "x")
)
(setq area1 (* (read (car tmp1)) (CirArea (read (cadr tmp1))))
area2 (* (read (car tmp2)) (CirArea (read (cadr tmp2))))
)
(if (> area2 (/ area1 4))
(princ "\n腰筋面积>1/4底筋面积.")
(princ "\n腰筋面积<=1/4底筋面积.")
)
(princ)
)
;计算园面积
(defun CirArea (dia)
(* pi dia dia 0.25)
)
; 字符串分拆作者: Bill Kramer
(defun Parse_It (inStr ;Input string to parse
Delim ;Delimeter character (or ascii code)
/
Res ;Result list buffer
Inx ;Character location of delim in string
InxP ;Previous character location
)
;
; Verify DELIM is of the proper type
;
(setq Delim (if (= (type Delim) 'STR)
(ASCII Delim) ;Convert character to integer
(if (/= (type Delim) 'INT) ;is it integer?
32 ;then use space
(if (> 0 Delim 256) Delim 32)))
;
; Set up parameters for string search loop
;
Inx (VL-String-Position Delim inStr 0)
InxP -1
)
;
(while (and Inx (< Inx (strlen inStr)))
(setq Res
(cons (substr inStr (+ 2 InxP) (- Inx InxP 1))
Res)
InxP Inx
Inx (VL-String-Position Delim inStr (1+ InxP))
)
)
(setq Res (cons (substr inStr (+ 2 InxP)) Res))
(reverse Res)
)
;

(defun C:tt(/ str1 str2 tmp1 tmp2 area1 area2)
   (setq str1 (cdr (assoc 1 (entget (car (entsel "\n选择第一个text: ")))))
  str2 (cdr (assoc 1 (entget (car (entsel "\n选择第二个text: ")))))
   )
   (setq tmp1 (Parse_It (vl-string-subst "x" "%%131" (last (Parse_It str1 ";"))) "x")
  tmp2 (Parse_It (vl-string-subst "x" "%%131" (last (Parse_It str2 ";"))) "x")
   )
   (setq area1 (* (read (car tmp1)) (CirArea (read (cadr tmp1))))
  area2 (* (read (car tmp2)) (CirArea (read (cadr tmp2))))
   )
   (if (> area2 (/ area1 4))
       (princ "\n腰筋面积>1/4底筋面积.")
       (princ "\n腰筋面积<=1/4底筋面积.")
   )
   (princ)
)
;计算园面积
(defun CirArea (dia)
   (* pi dia dia 0.25)
)
; 字符串分拆 作者: Bill Kramer
(defun Parse_It (inStr   ;Input string to parse
     Delim   ;Delimeter character (or ascii code)
     /
     Res     ;Result list buffer
     Inx     ;Character location of delim in string
     InxP   ;Previous character location
     )
   ;
   ; Verify DELIM is of the proper type
   ;
   (setq Delim (if (= (type Delim) 'STR)
    (ASCII Delim) ;Convert character to integer
    (if (/= (type Delim) 'INT) ;is it integer?
       32 ;then use space
       (if (> 0 Delim 256) Delim 32)))
  ;
  ; Set up parameters for string search loop
  ;
  Inx (VL-String-Position Delim inStr 0)
  InxP -1
  )
   ;
   (while (and Inx (< Inx (strlen inStr)))
       (setq Res
       (cons (substr inStr (+ 2 InxP) (- Inx InxP 1))
     Res)
     InxP Inx
     Inx (VL-String-Position Delim inStr (1+ InxP))
     )
   )
   (setq Res (cons (substr inStr (+ 2 InxP)) Res))
   (reverse Res)
   )
;

alwaysbin · 发表于 2004-8-7 14:22:00

本帖最后由作者于 2004-8-7 14:54:25 编辑

谢谢alin，先送你一朵鲜花，你真是太厉害了。不过我还有几个问题，我不懂vl，你能不能帮我完善一下。 1.如果是两种钢筋的组合，比如1%%13116+1%%13118，能不能将这将这两种钢筋加起来，求出面积？ 2.如果我在选第二组文字的时候，不选直接回车，那么area2就读分号前面的数字。可以实现吗？ 3.如果area2<area1/4，就加大直径，直到大于为止，直接在改文字。

alin · 发表于 2004-8-7 17:43:00

(defun C:TEST (/ ss1 ss2 str1 str2 tmp1 tmp2 area1 area2 ent1 ent2 newbarDia)
(princ "\n选择第一个text: ")
(setq ss1 (ssget ":s" '((0 . "TEXT"))))
(princ "\n选择第二个text: ")
(setq ss2 (ssget ":s" '((0 . "TEXT"))))
(if ss1
(progn
(setq str1 (cdr (assoc 1 (setq ent1 (entget (ssname ss1 0))))))
(if ss2
(progn
(setq str2
(cdr (assoc 1 (setq ent2 (entget (ssname ss2 0))))))
(setq tmp1 (Parse_It (vl-string-subst
"x"
"%%131"
(last (Parse_It str1 ";")))
"x")
tmp2 (Parse_It (vl-string-subst
"x"
"%%131"
(last (Parse_It str2 ";")))
"x")
)
) ;progn
(progn
(setq tmp1 (Parse_It (vl-string-subst
"x"
"%%131"
(last (Parse_It str1 ";")))
"x")
tmp2 (Parse_It (vl-string-subst
"x"
"%%131"
(car (Parse_It str1 ";")))
"x")
) ;setq
) ;progn
) ;if ss2
(setq area1 (* (read (car tmp1))
(CirArea (read (cadr tmp1))))
area2 (* (read (car tmp2))
(CirArea (read (cadr tmp2))))
)
(if (> area2 (/ area1 4))
(cond (ss2
(princ "\n腰筋面积>1/4底筋面积。通过。"))
(t
(princ "\n面筋面积>1/4底筋面积。通过。"))
)
(cond
(ss2
(princ "\n腰筋面积<=1/4底筋面积.")
(if (setq newbarDia (PickABar (/ area1 8)))
(progn
(entmod (setq ent2
(subst
(cons
1
(strcat "2%%131" (itoa newbarDia)))
(assoc 1 ent2)
ent2)))
(princ (strcat "\n腰筋已改为"
(vl-string-subst
"-"
"%%131"
(cdr (assoc 1 ent2)))))
)
(princ "\n*****超出选筋范围。可能要设两排腰筋。*****")
)
)
(t
(princ "\n面筋面积<=1/4底筋面积.")
(if (setq newbarDia (PickABar (/ area1 8)))
(progn
(entmod (setq ent1
(subst
(cons
1
(strcat "2%%131"
(itoa newbarDia)
";"
(last (Parse_It str1 ";"))))
(cons 1 str1)
ent1)))
(princ
(strcat
"\n面筋已改为"
(vl-string-subst
"-"
"%%131"
(car (Parse_It (cdr (assoc 1 ent1)) ";")))))
)
(princ
"\n*****超出选筋范围。可能要设两条以上面筋。*****")
)
)
)
) ;if
) ;progn
(princ "\n没有选择处理文字。")
) ;if ss1
(princ)
)
;计算园面积
(defun CirArea (dia)
(* pi dia dia 0.25)
)
;选筋
(defun PickABar (a)
(setq barlst '(12 14 16 18 20 22 25 28 30 32))
(setq newdia (1+ (fix (sqrt (/ (* 4 a) pi)))))
(if (member newdia barlst)
newdia
(nth (vl-position newdia (vl-sort (cons newdia barlst) '<))
barlst)
)
)
; 作者: Bill Kramer
;
(defun Parse_It (inStr ;Input string to parse
Delim ;Delimeter character (or ascii code)
/ Res ;Result list buffer
Inx ;Character location of delim in string
InxP ;Previous character location
)
;
; Verify DELIM is of the proper type
;
(setq Delim (if (= (type Delim) 'STR)
(ASCII Delim) ;Convert character to integer
(if (/= (type Delim) 'INT) ;is it integer?
32 ;then use space
(if (> 0 Delim 256)
Delim
32)))
;
; Set up parameters for string search loop
;
Inx (VL-String-Position Delim inStr 0)
InxP -1
)
;
(while (and Inx (< Inx (strlen inStr)))
(setq Res
(cons (substr inStr (+ 2 InxP) (- Inx InxP 1))
Res)
InxP Inx
Inx (VL-String-Position Delim inStr (1+ InxP))
)
)
(setq Res (cons (substr inStr (+ 2 InxP)) Res))
(reverse Res)
)
;

(defun C:TEST   (/ ss1 ss2 str1 str2 tmp1 tmp2 area1 area2 ent1 ent2 newbarDia)
   (princ "\n选择第一个text: ")
   (setq ss1 (ssget ":s" '((0 . "TEXT"))))
   (princ "\n选择第二个text: ")
   (setq ss2 (ssget ":s" '((0 . "TEXT"))))
   (if ss1
       (progn
           (setq str1 (cdr (assoc 1 (setq ent1 (entget (ssname ss1 0))))))
           (if ss2
  (progn
     (setq  str2
     (cdr (assoc 1 (setq ent2 (entget (ssname ss2 0))))))
     (setq  tmp1 (Parse_It (vl-string-subst
         "x"
         "%%131"
         (last (Parse_It str1 ";")))
                   "x")
    tmp2 (Parse_It (vl-string-subst
         "x"
         "%%131"
         (last (Parse_It str2 ";")))
                   "x")
    )
     ) ;progn
  (progn
     (setq  tmp1 (Parse_It (vl-string-subst
         "x"
         "%%131"
         (last (Parse_It str1 ";")))
                   "x")
    tmp2 (Parse_It (vl-string-subst
         "x"
         "%%131"
         (car (Parse_It str1 ";")))
                   "x")
    ) ;setq
     ) ;progn
  ) ;if ss2
           (setq area1 (* (read (car tmp1))
             (CirArea (read (cadr tmp1))))
         area2 (* (read (car tmp2))
             (CirArea (read (cadr tmp2))))
         )
           (if (> area2 (/ area1 4))
  (cond (ss2
               (princ "\n腰筋面积>1/4底筋面积。通过。"))
             (t
               (princ "\n面筋面积>1/4底筋面积。通过。"))
             )
  (cond
     (ss2
       (princ "\n腰筋面积<=1/4底筋面积.")
       (if (setq newbarDia (PickABar (/ area1 8)))
           (progn
               (entmod (setq ent2
                 (subst
        (cons
           1
           (strcat "2%%131" (itoa newbarDia)))
        (assoc 1 ent2)
        ent2)))
               (princ (strcat "\n腰筋已改为"
                 (vl-string-subst
        "-"
        "%%131"
        (cdr (assoc 1 ent2)))))
               )
           (princ "\n*****超出选筋范围。可能要设两排腰筋。*****")
           )
       )
     (t
       (princ "\n面筋面积<=1/4底筋面积.")
       (if (setq newbarDia (PickABar (/ area1 8)))
           (progn
               (entmod (setq ent1
                 (subst
        (cons
           1
           (strcat "2%%131"
             (itoa newbarDia)
             ";"
             (last (Parse_It str1 ";"))))
           (cons 1 str1)
           ent1)))
               (princ
     (strcat
         "\n面筋已改为"
         (vl-string-subst
             "-"
             "%%131"
             (car (Parse_It (cdr (assoc 1 ent1)) ";")))))
               )
           (princ
               "\n*****超出选筋范围。可能要设两条以上面筋。*****")
           )
       )
     )
  ) ;if
           ) ;progn
       (princ "\n没有选择处理文字。")
       ) ;if ss1
   (princ)
   )
  ;计算园面积
(defun CirArea  (dia)
   (* pi dia dia 0.25)
   )
  ;选筋
(defun PickABar   (a)
   (setq barlst '(12 14 16 18 20 22 25 28 30 32))
   (setq newdia (1+ (fix (sqrt (/ (* 4 a) pi)))))
   (if (member newdia barlst)
       newdia
       (nth (vl-position newdia (vl-sort (cons newdia barlst) '<))
   barlst)
       )
   )
  ; 作者: Bill Kramer
  ;
(defun Parse_It   (inStr ;Input string to parse
       Delim ;Delimeter character (or ascii code)
       / Res ;Result list buffer
       Inx ;Character location of delim in string
       InxP ;Previous character location
)
  ;
  ; Verify DELIM is of the proper type
  ;
   (setq  Delim (if (= (type Delim) 'STR)
    (ASCII Delim) ;Convert character to integer
    (if (/= (type Delim) 'INT) ;is it integer?
       32 ;then use space
       (if (> 0 Delim 256)
           Delim
           32)))
  ;
  ; Set up parameters for string search loop
  ;
  Inx     (VL-String-Position Delim inStr 0)
  InxP   -1
  )
  ;
   (while (and Inx (< Inx (strlen inStr)))
       (setq Res
               (cons (substr inStr (+ 2 InxP) (- Inx InxP 1))
             Res)
     InxP Inx
     Inx   (VL-String-Position Delim inStr (1+ InxP))
     )
       )
   (setq Res (cons (substr inStr (+ 2 InxP)) Res))
   (reverse Res)
   )
  ;

alwaysbin · 发表于 2004-8-7 18:26:00

谢谢，现在的程序已经基本可以满足我的需要了。

还有两个小问题就是上部筋和下部筋都可能出现组合的情况，如何像上面的一样让他们相加？

还有就是有时钢筋后面可能有表示排二排的数字，比如2/3等，如何不受这些文字的干扰？我列了4种可能出现的情况，如果这4种情况都能够实现，那就大功告成了。

账号		自动登录	找回密码
密码			注册

请教一下关于文件选取的问题。

本帖子中包含更多资源

本帖子中包含更多资源

本帖子中包含更多资源