关于连续打印的问题，请教！！

霹雳啪啦啦

XUXT:
这个东东写过几年了，偶尔上来看看又被翻出来了。当年怎么写的忘记了，反正都是在MODELSPACE里操作的，没有布局的问题。
贴出当年写的东东的核心子程序，供有兴趣的人参考。2006里调试正常。

Sub Plot_Frame(PlotZone() As Double)

Dim M, N As Integer
Dim ExtLowLeft As Variant
Dim ExtUpRight As Variant
Dim PlotLowLeft(0 To 1) As Double, PlotUpRight(0 To 1) As Double
               
    If PlotRagType = acWindow Then
        PlotLowLeft(0) = PlotZone(1)
        PlotLowLeft(1) = PlotZone(2)
        PlotUpRight(0) = PlotZone(3)
        PlotUpRight(1) = PlotZone(4)
       
        ' 设置打印范围和打印区域的比例
        ThisDrawing.ModelSpace.Layout.SetWindowToPlot PlotLowLeft, PlotUpRight
        ElseIf PlotRagType = acExtents Then
       
            ExtLowLeft = ThisDrawing.GetVariable("extmin")
            ExtUpRight = ThisDrawing.GetVariable("extmax")
            PlotLowLeft(0) = ExtLowLeft(0)
            PlotLowLeft(1) = ExtLowLeft(1)
            PlotUpRight(0) = ExtUpRight(0)
            PlotUpRight(1) = ExtUpRight(1)
       
    End If
    ThisDrawing.ModelSpace.Layout.PlotType = PlotRagType
   
    ThisDrawing.ModelSpace.Layout.StandardScale = acScaleToFit
    ThisDrawing.ModelSpace.Layout.CenterPlot = True
    ThisDrawing.ModelSpace.Layout.StyleSheet = "monochrome.ctb"
   
    '选择打印机
    ThisDrawing.ModelSpace.Layout.ConfigName = ComboBox1.Value
   
    '选择纸张
    If OptionButton1.Value = True Then
        ThisDrawing.ModelSpace.Layout.CanonicalMediaName = "A4"
        ElseIf OptionButton2.Value = True Then
            ThisDrawing.ModelSpace.Layout.CanonicalMediaName = "A3"
    End If
   
    ' 设置打印份数为1
    ThisDrawing.Plot.NumberOfCopies = 1
   
    ' 开始打印
    ThisDrawing.Plot.QuietErrorMode = True
   
    '旋转设置
    If PlotUpRight(0) - PlotLowLeft(0) > PlotUpRight(1) - PlotLowLeft(1) Then
        ThisDrawing.ModelSpace.Layout.PlotRotation = ac90degrees
        Else
            ThisDrawing.ModelSpace.Layout.PlotRotation = ac0degrees
    End If
   
    ThisDrawing.Plot.PlotToDevice
    DoEvents
   
End Sub

PlotZone是传递给子程序的打印区域，4元素数组，代表左上角和右下角的坐标。
PlotRagType是全局变量，AcPlotType类型，代表是窗口还是范围等打印方式。
ComboBox1中是打印机列表，可通过以下代码在父程序初始化时取得：
plotDevices = ThisDrawing.ModelSpace.Layout.GetPlotDeviceNames()
For I = LBound(plotDevices) To UBound(plotDevices)
    ComboBox1.AddItem plotDevices(I)
Next
OptionButton1和2用来选择a4还是a3纸。
你需要添加父程序，取得打印范围的左上交和右下角，然后一次次调用这个子程序，就可以批量打印了