[求助]如何提取曲线中的断点的座标数据后再生成一个文本文件

yshf

;请用以下程序

;提取曲线等分段点坐标并存盘
;等分数可突破“Measure“及“Divide”命令最大数32767的限制
;在盘结果为：点编号   X   Y，在盘后立即用记事本后打开该文件
(defun c:qxcl()
    (vl-load-com)
    (setq cm (getvar "cmdecho") om (getvar "osmode"))
    (setvar "cmdecho" 0) (setvar "osmode" 0)
    (setq ff (open (setq wjm (getfiled "请选择等分点数据存盘文件" "" "txt" 1)) "w")
          en (car (entsel "\n请选择要等分段的曲线:"))
          n  (getint "\n请输入等分数<100>:")
          nx (getint "\n请输入要保留的小数位数<3>:")
    )
    (if (= n nil) (setq n 100))
    (if (= nx nil) (setq nx 3))
    (command "lengthen" en "")
    (setq vob (vlax-ename->vla-object en)
   l   (getvar "perimeter")
   dis (/ l n)       i   0
    )
    (repeat (1+ n)
       (setq pt  (vlax-curve-getpointatdist vob (* i dis)) i (1+ i))
       (princ
          (strcat (itoa i) "  " (rtos (car pt) 2 nx) "  " (rtos (cadr pt) 2 nx) "\n") ff
       )
    )
    (close ff)
    (startapp "notepad" wjm)
    (setvar "cmdecho" cm) (setvar "osmode" om) (princ)
)

xqgong

不好意思，我的结果怎么还是错误呢？如下：

命令: qxcl
请选择要等分段的曲线:
请输入等分数<100>:20
请输入要保留的小数位数<3>:4
当前长度: 716.7118，包含角: 91; 错误: Automation 错误。 无数据库

yshf

请问你用的是2000以上的版本吗？