[求助]如何替外部参考档增加图层?

vken7az2p

<br/>请问在A图档,<br/>XREF参考进来 B图档,<br/>该如何去替换其物件的图层?<br/>且若该图档没有此图层,<br/>可以写入此档案中,<br/>这样的过程<br/>该怎样编写程式完成呢?<br/>烦请各位高手可以解答一下<br/>谢谢~<br/>

龙龙仔

這要用到objectdbx暗地裡打開B圖檔並修改你說的,再更新B檔案

vken7az2p

那请教该怎样使用呢?

是否可以说明一下

谢谢

龙龙仔

不要只問,要寫點東西出來,是那裡不會寫,我在Objectdbx上不是有例子了嗎?

龙龙仔

;;Test R2005
;;要先加載Thumbnailer.arx
;;改XREF--->圖層名稱 & 增加"LUCAS"圖層 & 改所有空間物件為紅色
(defun C:TT (/ APP BNAME DBXDOC DOC DWGNAME LAYERS)
  (vl-load-com)

  (defun SAVEASEX (DBXDOC DWGNAME)
    (vlax-invoke-method
      (vla-getinterfaceobject
 (vlax-get-acad-object)
 "Thumbnailer.Application"
      )
      'PRESERVETHUMBNAIL
      (vlax-get-property DBXDOC 'DATABASE)
    )
    (vlax-invoke-method DBXDOC 'SAVEAS DWGNAME)
  )

  (if (vlax-property-available-p
 (setq DWGNAME (vlax-ename->vla-object
   (car (entsel "\nSelect Xref: "))
        )
 )
 'PATH
      )
    (progn
      (setq APP (vlax-get-acad-object))
      (setq DOC (vla-get-activedocument APP))
      (setq DBXDOC (vla-getinterfaceobject
       APP
       (strcat "ObjectDBX.AxDbDocument."
        (substr (getvar "ACADVER") 1 2)
       )
     )
      )
      (setq
 BNAME (vla-item (vla-get-blocks DOC) (vla-get-name DWGNAME))
      )
      (setq DWGNAME (vla-get-path DWGNAME))
      (vla-open DBXDOC DWGNAME)
      (vlax-for BLK (vla-get-blocks DBXDOC)
 (if (= :vlax-true (vla-get-islayout BLK))
   (vlax-for OBJ BLK
     (vla-put-color OBJ 1)
   )
 )
      )
      (vlax-for LAY (setq LAYERS (vla-get-layers DBXDOC))
 (if (/= "0" (vla-get-name LAY))
   (vla-put-name LAY (strcat (vla-get-name LAY) "-lai"))
 )
      )
      (vla-add LAYERS "LUCAS")
      (if (> (atoi (getvar "AcadVer")) 15)
 (SAVEASEX DBXDOC DWGNAME)
 (vla-saveas DBXDOC DWGNAME)
      )
      (vla-reload BNAME)
      (mapcar 'vlax-release-object (list APP DOC DBXDOC LAYERS))
    )
  )
  (princ)
)

龙龙仔

;;很多人不會註冊ObjectDbx(繁體系統測試通過,簡體系統未測試),支持R2000以上
;;加載DbxDoc.vlx
;;(load "dbxdoc.vlx" nil)
;;(setq DBXDOC (DBXDOC))
;;即註冊ObjectDbx完成