面积查询单位是平方米？

lzu1797

呵呵

那就真的只能用lisp了

sailorcwx

你用scale把图缩小1000倍不就可以了

aozero

我缩小了一下，结果图在哪儿我都不知道了，还是谢谢楼上的朋友们，大家想了很多方法。

谢谢！！！

我想在命令栏显示面积、长度用平方米、米为单位，是不是真的很难呀，呵呵。

aozero

期待中。。。。。。

aozero

在2楼的中间去掉那些标注的语句，加上一句：(princ "Area: " A1) 可以吗？

谢谢！

zara

>>  我缩小了一下，结果图在哪儿我都不知道了
  Zoom.E 命令可以将图形中的内容最大可能地显示到屏幕上来

>>  在2楼的中间去掉那些标注的语句，加上一句：(princ "Area: " A1) 可以吗
  可以的. 从 (setq txthgt ...  到 (command ...  几行的内容都不需要了, 替换为 (princ (strcat "Area: " A1 "\n")) 即可将标注改为显示

aozero

谢谢指点！！！

perniu1234

到底怎么用？能否明示!

aozero

代码参考我在晓东版块上问的，“ZM184”大侠回复的：

http://www.xdcad.net/forum/showthread.php?s=&postid=3154154#post3154154

;;;===========================================================
;;;  查询单个图元长度、面积信息                               
;;;                                                           
;;;　日　期：zml84 于2007-02-05                              
;;;===========================================================
(defun c:t (/ bl el ent 类型 pt0 pt1 r jd0 jd1 jd l a)
    (princ "\n★★查询长度、面积\n★★默认CAD单位为毫米")
    ;;设置比例
    (setq bl 1000)
    (while
    (= (setq el (entsel "\n请点选实体：")) nil)
    )
    (setq ent  (entget (car el) '("*"))
      类型 (cdr (assoc '0 ent))
    )
    (princ "\n \n★对象类型：")
    (princ 类型)

    (cond
    ((= 类型 "LINE")
     (progn
         (setq pt0 (cdr (assoc '10 ent))
           pt1 (cdr (assoc '11 ent))
           l   (distance pt0 pt1)
         )
         (princ "，长度：")
         (princ (/ l bl))
         (princ " 米")
     )
    )

    ((= 类型 "CIRCLE")
     (progn
         (setq r (cdr (assoc '40 ent))
           l (* 2.0 pi r)
           a (* pi r r)
         )
         (princ "，周长：")
         (princ (/ l bl))
         (princ " 米")
         (princ "，面积：")
         (princ (/ a bl bl))
         (princ " 平方米")
     )
    )

    ((= 类型 "ARC")
     (progn
         (setq r   (cdr (assoc '40 ent))
           jd0 (cdr (assoc '50 ent))
           jd1 (cdr (assoc '51 ent))
         )
         (if (< jd1 jd0)
         (setq jd (- (+ jd1 pi pi) jd0))
         (setq jd (- jd1 jd0))
         )
         (setq l (* r jd))
         (princ "，长度：")
         (princ (/ l bl))
         (princ " 米")
     )
    )

    ((or
         (= 类型 "LWPOLYLINE")
         (= 类型 "SPLINE")
         (= 类型 "ELLIPSE")
         (= 类型 "REGION")
     )
     (progn
         (setvar "CMDECHO" 0)
         (command "_AREA" "O" el)
         (setq l (getvar "PERIMETER")
           a (getvar "AREA")
         )
         (princ "，长度：")
         (princ (/ l bl))
         (princ " 米")
         (princ "，面积：")
         (princ (/ a bl bl))
         (princ " 平方米")
     )
    )

    ( (= 类型 "HATCH")
     (progn
         (setvar "CMDECHO" 0)
         (command "_list" el "")
         (graphscr)
         (setq a (getvar "AREA"))
         (princ "\n \n★对象类型：")
         (princ 类型)
         (princ "，面积：")
         (princ (/ a bl bl))
         (princ " 平方米")
     )
    )

    (t
     (princ "，不能识别！！")
    )
    )
    (princ)
)
;;;===========================================================
(princ "\n\n★★查询长度、面积\n★★键入命令\"T\"开始执行。")
(princ)
;;;===========================================================

具体作法是：你先打开一个CAD文件，打开菜单“工具”-》AUTOLISP-》VISUL AUTOLISP编辑器，复制此代码，保存为一个LSP文件。

然后在VISUL AUTOLISP介面下，打开菜单“文件”-》生成应用程序-》新建应用向导-》简单-》下一步-》应用程序位置（你可以选择），应用程序名称（你可以自己定义）-》下一步-》生成VLX程序，你要加载它（在工具菜单中）。你必须修改一下“ZM184”的第一行“(defun c:t (/ bl el ent 类型 pt0 pt1 r jd0 jd1 jd l a)”，你把“t”修改为你喜欢的命令，别和CAD中命令重复了，比如你改为“XSMC”，你在命令行打入“XSMC”就OK了，不知道你明白没有，谢谢晓东的“ZM184”大侠及明经的各位朋友。

石井鱼

命令: ; 错误: 读入的 (八进制) 字符不正确: 0