如何新建pgp文件,定义简化命令

caoyin

;; 我没有理解错你的意思,个人推荐第二种方法
;; 现在以第二种方法示例:
;; 测试：(UserPGP "ayunger.pgp")

(defun UserPGP (uPgp / apgp tmp)
  (if (and (setq uPgp (findfile uPgp))
           (setq aPgp (findfile "acad.pgp"))
      )
    (progn
      (setq tmp (vl-filename-mktemp apgp))
      (vl-file-copy apgp tmp)   ;备份 acad.pgp 文件
      (vl-file-copy uPgp apgp T)  ;注意：uPgp 用户pgp文件第一行一定要为空
      (setvar "re-init" 16)   ;重新初始化 acad.pgp 文件
      (if (vl-file-delete apgp)   ;删除 acad.pgp 文件
        (vl-file-rename tmp apgp)  ;恢复临时文件到 acad.pgp 文件
      )
    )
  )
)

无痕

比如vlx含c:atest命令

pgp就这样写（当然运行前要先加载vlx）

aaa,  *atest

sailorcwx

将你的pgp文件所在目录添加到CAD的支持路径里面，并确保它位于CAD本身的pgp文件的上方就可以了

rewq

这么多热心人,真的谢谢!

asen

vlax-add-cmd  这个函数

举例

(defun C:MYCOPY () (cmmand "COPY")) ;举例定义一个命令

(setq cmd      "N"         ;快捷命令
      cmdsys   "C:MYCOPY"  ;原命令
)

(vlax-add-cmd cmd cmdsys)

ayunger

这是本人《一个非常好用的AutoCAD工具集》中关于自动加载Ayunger.PGP文件的函数，先与大家分享！

有问题，直接: E-mail:AyungerStudio@163.com或QQ:420304230

;;********************************
;;; No.3 AY工具快捷命令初始化 函数
;;;********************************
(defun C:ayCMD(/ PGPFile fp i xString aList shortCMD GlobalCMD)
 (vl-load-com)
 (setq PGPFile "Ayunger.pgp");F:\\Ayungerstudio\\VLisp\\Ayunger.pgp
 (if (setq PGPFile (findfile PGPFile))
  (progn;then
   (setq fp (open PGPFile "r"))
   (setq i 1)
   (while (setq xString (read-line fp))
    (if (= (type xString) 'SYM) (setq xString (vl-symbol-name xString)));转换数据文件中无引号的字符串.
     (while (vl-string-search " " xstring);去掉所有的空格.
     (setq xString(vl-string-subst "" " " xstring));空格.
     (setq xString(vl-string-subst "" " " xstring));tab符.
    );end_while
    (if (and (/= (substr xString 1 1) ";") (vl-string-search "," xstring) (vl-string-search "*" xstring))
     (progn
      (setq aList (read (strcat "(" (vl-string-subst " . C:" ",*" xString) ")")))
      (setq shortCMD (vl-string-trim " " (vl-symbol-name (car aList))))
      (setq GlobalCMD (cdr aList))
      ;(vlax-remove-cmd shortCMD);删除已定义的命令.
      (vlax-add-cmd shortCMD GlobalCMD)
     );end_progn
    );end_if
    (setq i (+ i 1))
   );end_while read-line
   (close fp)
  );end_progn then
  (princ "\nAY工具简化命令定义文件 Ayunger.pgp 没找到或不存在!")
 );end_if
 (princ)
);end_defun

;;;┏━━━━━━━━━━━━━━━━━━┓
;;;┃ AY工具快捷命令自动加载(反应器调用) ┃
;;;┗━━━━━━━━━━━━━━━━━━┛
(C:ayCMD);调用AY工具快捷命令自动加载函数. 
(defun ayLoadSCMDReactor();建立AutoCAD文档级反应器.
 (vl-load-com)
 (if (not #AY_LOADSCMDREACTOR)
   (setq #AY_LOADSCMDREACTOR (vlr-docmanager-reactor nil '((:vlr-documentBecameCurrent . AI:aySCMDCallBack))))
 );end_if
 (defun AI:aySCMDCallBack (aReactor bList) (C:ayCMD));;;定义反应器的回调函数.
);end_defun
(or #AY_LOADSCMDREACTOR (ayLoadSCMDReactor));自动加载反应器.
(princ "\nAutoCAD AYunger Tools Copyright (C)2001-2008 AYunger Studio")
(prin1)

ayunger

直接到论坛下查找，我前几天发过一个本人ayunger.fas中调用PGP的完整函数！

www2002

老大真是高手！谢谢啦！！

zhuquanmao

;把别人的帖子内容改了一下，直接可以把自己定义的快捷键加到acad.pgp后了。
;XXX.PGP是自定义的快捷键文件，放在支持搜索路径中，执行repgp即可。
(defun c:repgp (/ f_txt n cctd)
(princ "\n 此命令加载自定义快捷键.")
  (setq f_txt (open (findfile "XXX.pgp") "r"))
  (setq cctd '()); 存放读取pgp文件的文本行
  (while (setq txt_row (read-line f_txt))
    (setq cctd (cons txt_row cctd))
  )
  (close f_txt)
  (setq cctd (reverse cctd)
        n 0
  )
  (setq f_txt (open (findfile "acad.pgp") "A"))
  (repeat (length cctd)
    (write-line (nth n cctd) f_txt)
    (setq n (+ 1 n))
  )
  (close f_txt)
  (setvar "RE-INIT" 16)
  (princ)
)

lxg3443

zhuquanmao 发表于 2011-5-27 00:57
;把别人的帖子内容改了一下，直接可以把自己定义的快捷键加到acad.pgp后了。
;XXX.PGP是自定义的快捷键文件 ...

这个每次都会在acad.pgp后面增加自己的命令 不管是不是和上次的一样 就会越来越多啊...
能不能修改 成为如果一样的话就不替换？