[求助]文字表格居中

caoyin

我测试仍然没问题，你可以测试一下 (command "_.boundary" "")在 acad2002上运行的情况，我用2009

xd-xdcad

可惜我的2002版本总是出现问题,应该能更改吧?

xd-xdcad

输入命令_.boundary,显示如图

caoyin

(defun c:JZ (/ err)
  (defun algion (msg    /      ss     lst    i      vlalst boxlst
                 x      cor1   cor2   findboxpt     newboxpt
                 en1    en     enlst  y      y2
                )
    (princ msg)
    (setq ss (ssget '((0 . "text"))))
    (if (not ss) (exit))
    (setq lst nil)
    (setq i 0)
    (repeat (sslength ss)
      (setq lst (cons (ssname ss i) lst))
      (setq i (1+ i))
    )
    (setq vlalst (mapcar 'vlax-ename->vla-object lst))
    (setq boxlst (mapcar '(lambda (x / cor1 cor2)
                            (vla-GetBoundingBox x 'cor1 'cor2)
                            (list (vlax-safearray->list cor1)
                                  (vlax-safearray->list cor2)
                            )
                          )
                         vlalst
                 )
    )
    (setq
      findboxpt (mapcar '(lambda (x)
                           (polar (car x)
                                  (angle (car x) (cadr x))
                                  (/ (DISTANCE (car x) (cadr x)) 2.0)
                           )
                         )
                        boxlst
                )
    )
    (setq newboxpt (mapcar '(lambda (x)
                              (setq en1 (entlast))
                              (vl-cmdf "_boundary" x "")
                              (setq en (entlast))
                              (if (not (equal en1 en))
                                (progn
                                  (setq enlst (entget en))
                                  (setq lst (vl-remove-if-not
                                              '(lambda (y) (= (car y) 10))
                                              enlst
                                            )
                                  )
                                  (setq cor1 (vl-remove 10 (car lst))
                                        cor2 (vl-remove 10 (nth 2 lst))
                                  )
                                  (while (setq en1 (entnext en1))
                                    (entdel en1)
                                  )
                                  (polar cor1
                                         (angle cor1 cor2)
                                         (/ (DISTANCE cor1 cor2) 2.0)
                                  )
                                )
                              )
                            )
                           findboxpt
                   )
    )
    (mapcar '(lambda (x y y2)
               (vla-move x (vlax-3d-point y) (vlax-3d-point y2))
             )
            vlalst
            findboxpt
            newboxpt
    )
  )
  (setq err (VL-CATCH-ALL-APPLY 'algion (list "\n师兄 选择单行文字: ")))
  (princ)
)

xd-xdcad

非常抱歉，问题依旧

sailorcwx

将1楼的程序中(setq    newboxpt (mapcar '(lambda (x)

改成(setq    newboxpt (mapcar '(lambda (x / en1 en)

就可以了

sailorcwx

或者把(entdel en1)改成(vl-cmdf "erase" en1 "")应该都可以

xd-xdcad

sailorcwx发表于2008-5-21 14:06:00或者把(entdel en1)改成(vl-cmdf \"erase\" en1 \"\")应该都可以

这个方法可行，问题解决了,但出现了另外一个问题，执行命令后,按CTRL+Z,在恢复到原先的状态的同时，还会出现一个边框，

sailorcwx

那你用一个command把你的程序包起来嘛

sailorcwx

我推荐的是这种改法

将1楼的程序中(setq    newboxpt (mapcar '(lambda (x)

改成(setq    newboxpt (mapcar '(lambda (x / en1 en)