[求助]求助一个x,y不同比例时候，cad计算路基横断面lsp

znchssy · 发表于 2009-6-5 12:26:00

上传我的效果图。

znchssy · 发表于 2009-6-7 16:16:00

下面程序还是有点问题，就是想把开始比例x/y用常量1000赋值，不知道怎样改。

(DEFUN C:QA4(/ OLDOS PT STA QAREA)
(setq olderr *error*)
(setq *error* myerr)
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(SETVAR "OSMODE" 0)
(prompt "点已知x y 比例的多边形: ")
(setq en (car (entsel)))
(setq x(,1000))
(setq y(,1000))
(SETQ QAREA (GETVAR "AREA"))
(setq yuanmj (/ qarea x y))
(prompt "点另一已知x y 比例的多边形: ")
(setq x1 (getreal "输入x向的比例: ") y1 (getreal "输入y向的比例: "))
(setq pt1 (getpoint "文字的位置: "))
(setq qarea1 (* yuanmj x1 y1) qarea1 (rtos qarea1 2 3))
(COMMAND "TEXT" PT1 h "0" QAREA1)
(SETVAR "OSMODE" OLDOS)
(SETVAR "CMDECHO" 1)
(setq *error* olderr)
(PRINC)
)

zml84 · 发表于 2009-6-8 08:36:00

(setvar "CMDECHO" 0)
(vl-load-com)
;;;=================================================================*
;;;功能：测量封闭区域的面积（可分别设置XY比例） *
;;;日期：zml84 于 2009-06-07 *
(defun C:TT (/ X Y SIZE SS AREA STR TMP)
;; 0 初始化
(or *TEST_TMP*
(setq *TEST_TMP* '(1000 100 2.5))
)
(setq X (nth 0 *TEST_TMP*)
Y (nth 1 *TEST_TMP*)
SIZE (nth 2 *TEST_TMP*)
)
;; 1
(while
(progn
(princ
(strcat
"\n当前设置：X比例="
(rtos X)
"，X比例="
(rtos Y)
"，字高="
(rtos SIZE)
)
)
(initget "X Y Size")
(princ
"\n点取要测量面积的封闭对象，或 [X比例(X)/Y比例(Y)/字高(S)]: "
)
(setq SS (entsel ""))
)
(cond ((= SS "X")
(if (and (setq TMP (getreal "\n设置X向比例: "))
(> TMP 0)
)
(setq X TMP)
)
)
((= SS "Y")
(if (and (setq TMP (getreal "\n设置Y向比例: "))
(> TMP 0)
)
(setq Y TMP)
)
)
((= SS "Size")
(if (and (setq TMP (getreal "\n设置字体高度: "))
(> TMP 0)
)
(setq SIZE TMP)
)
)
((and (setq
AREA (vla-get-area
(vlax-ename->vla-object (car SS))
)
)
(setq AREA (/ AREA 1.0 X Y)
STR (rtos AREA 2 3)
)
(princ (strcat "\n**面积 = " STR))
(setq PT (getpoint "\n文字的位置: "))
)
(command "_.TEXT" "non" PT SIZE 0 STR)
)
)
)
;; 2
(setq *TEST_TMP* (list X Y SIZE))
(princ)
)

(setvar "CMDECHO" 0)
(vl-load-com)
;;;=================================================================*
;;;功能：测量封闭区域的面积（可分别设置XY比例）                     *
;;;日期：zml84 于 2009-06-07                                        *
(defun C:TT (/ X Y SIZE SS AREA STR TMP)
    ;; 0 初始化
    (or *TEST_TMP*
 (setq *TEST_TMP* '(1000 100 2.5))
    )
    (setq X    (nth 0 *TEST_TMP*)
   Y    (nth 1 *TEST_TMP*)
   SIZE (nth 2 *TEST_TMP*)
    )
    ;; 1 
    (while
 (progn
     (princ
  (strcat
      "\n当前设置：X比例="
      (rtos X)
      "，X比例="
      (rtos Y)
      "，字高="
      (rtos SIZE)
  )
     )
     (initget "X Y Size")
     (princ
  "\n点取要测量面积的封闭对象，或 [X比例(X)/Y比例(Y)/字高(S)]: "
     )
     (setq SS (entsel ""))
 )
    (cond ((= SS "X")
    (if (and (setq TMP (getreal "\n设置X向比例: "))
      (> TMP 0)
        )
        (setq X TMP)
    )
   )
   ((= SS "Y")
    (if (and (setq TMP (getreal "\n设置Y向比例: "))
      (> TMP 0)
        )
        (setq Y TMP)
    )
   )
   ((= SS "Size")
    (if (and (setq TMP (getreal "\n设置字体高度: "))
      (> TMP 0)
        )
        (setq SIZE TMP)
    )
   )
   ((and (setq
      AREA (vla-get-area
        (vlax-ename->vla-object (car SS))
    )
         )
         (setq AREA (/ AREA 1.0 X Y)
        STR  (rtos AREA 2 3)
         )
         (princ (strcat "\n**面积 = " STR))
         (setq PT (getpoint "\n文字的位置: "))
    )
    (command "_.TEXT" "non" PT SIZE 0 STR)
   )
    )
    )
    
    ;; 2 
    (setq *TEST_TMP* (list X Y SIZE))
    (princ)
)

zml84 · 发表于 2009-6-8 09:08:00

13楼是点取对象的方式；
14楼是点取封闭区域内一点的方式。

;;;=================================================================*
;;;功能：点取内部一点，测量封闭区域的面积（可分别设置XY比例） *
;;;日期：zml84 于 2009-06-07 *
(defun C:TT2 (/ X Y SIZE PT EN AREA STR TMP)
;; 0 初始化
(or *TEST_TMP*
(setq *TEST_TMP* '(1000 100 2.5))
)
(setq X (nth 0 *TEST_TMP*)
Y (nth 1 *TEST_TMP*)
SIZE (nth 2 *TEST_TMP*)
)
;; 1
(while
(progn
(princ
(strcat
"\n当前设置：X比例="
(rtos X)
"，X比例="
(rtos Y)
"，字高="
(rtos SIZE)
)
)
(initget "X Y Size")
(princ
"\n点取要测量的位置，或 [X比例(X)/Y比例(Y)/字高(S)]: "
)
(setq PT (getpoint ""))
)
(cond ((= PT "X")
(if (and (setq TMP (getreal "\n设置X向比例: "))
(> TMP 0)
)
(setq X TMP)
)
)
((= PT "Y")
(if (and (setq TMP (getreal "\n设置Y向比例: "))
(> TMP 0)
)
(setq Y TMP)
)
)
((= PT "Size")
(if (and (setq TMP (getreal "\n设置字体高度: "))
(> TMP 0)
)
(setq SIZE TMP)
)
)
((and
(setq EN (bpoly PT))
(setq
AREA (vla-get-area
(vlax-ename->vla-object EN)
)
)
;;(progn (command "REGEN") (redraw EN 3) t)
(entdel EN)
(setq AREA (/ AREA 1.0 X Y)
STR (rtos AREA 2 3)
)
(princ (strcat "\n**面积 = " STR))
)
(command "_.TEXT" "non" PT SIZE 0 STR)
)
)
)
;; 2
(setq *TEST_TMP* (list X Y SIZE))
(princ)
)

;;;=================================================================*
;;;功能：点取内部一点，测量封闭区域的面积（可分别设置XY比例）       *
;;;日期：zml84 于 2009-06-07                                        *
(defun C:TT2 (/ X Y SIZE PT EN AREA STR TMP)
    ;; 0 初始化
    (or *TEST_TMP*
 (setq *TEST_TMP* '(1000 100 2.5))
    )
    (setq X    (nth 0 *TEST_TMP*)
   Y    (nth 1 *TEST_TMP*)
   SIZE (nth 2 *TEST_TMP*)
    )
    ;; 1 
    (while
 (progn
     (princ
  (strcat
      "\n当前设置：X比例="
      (rtos X)
      "，X比例="
      (rtos Y)
      "，字高="
      (rtos SIZE)
  )
     )
     (initget "X Y Size")
     (princ
  "\n点取要测量的位置，或 [X比例(X)/Y比例(Y)/字高(S)]: "
     )
     (setq PT (getpoint ""))
 )
    (cond ((= PT "X")
    (if (and (setq TMP (getreal "\n设置X向比例: "))
      (> TMP 0)
        )
        (setq X TMP)
    )
   )
   ((= PT "Y")
    (if (and (setq TMP (getreal "\n设置Y向比例: "))
      (> TMP 0)
        )
        (setq Y TMP)
    )
   )
   ((= PT "Size")
    (if (and (setq TMP (getreal "\n设置字体高度: "))
      (> TMP 0)
        )
        (setq SIZE TMP)
    )
   )
   ((and
        (setq EN (bpoly PT))
        (setq
     AREA (vla-get-area
       (vlax-ename->vla-object EN)
          )
        )
        ;;(progn (command "REGEN") (redraw EN 3) t)
        (entdel EN)
        (setq AREA (/ AREA 1.0 X Y)
       STR  (rtos AREA 2 3)
        )
        (princ (strcat "\n**面积 = " STR))
    )
    (command "_.TEXT" "non" PT SIZE 0 STR)
   )
    )
    )
    ;; 2 
    (setq *TEST_TMP* (list X Y SIZE))
    (princ)
)

znchssy · 发表于 2009-6-8 09:17:00

谢谢zml84 ，真是厉害，你的程序很智能，很好用的。

zml84 · 发表于 2009-6-8 10:14:00

同行兄弟，多多交流。

znchssy · 发表于 2009-6-8 10:47:00

zml84问你一个画地面线的问题，现实工作测横断面，我们有几种方法实测，一种是直接在大致的断面线上采集点，xyz这样速度快。另外也可以对边测量模式，平距。高差。第一种方法虽然不完全在断面的法线上，但是可以模拟碎步点投影到法线上，把数据转换成平距高差形，再画地面线。我以前见过通过平距高差画地面线的lsp，但一时找不到了，不知道同行你有啥好方法能提高速度，或者好的画地面线程序。

zml84 · 发表于 2009-6-8 12:44:00

znchssy发表于2009-6-8 10:47:00zml84问你一个画地面线的问题，现实工作测横断面，我们有几种方法实测，一种是直接在大致的断面线上采集点，xyz这样速度快。另外也可以对边测量模式，平距。高差。第一种方法虽然不完全在断面的

数据格式而已，怎样都行。

给你一个参考：http://zml84.blog.sohu.com/53929625.html

zml84 · 发表于 2010-12-29 09:01:52

http://zml84.blog.sohu.com/118215464.html

gzbccy · 发表于 2011-1-6 19:10:18

呵呵，zml84真的很强大。不过14楼中第20行是不是将"，X比例="改成 "，Y比例="才对？

账号		自动登录	找回密码
密码			注册