[求助]vlisp/lisp能否判断图层使用了"真彩色"?

jaminth · 发表于 2010-2-1 22:30:00

请教大家:

vlisp/lisp能否判断图层使用了"真彩色"?

狂刀无痕 · 发表于 2010-2-1 23:00:00

vla-get-truecolor + vla-get-red / green / blue

caoyin · 发表于 2010-2-2 00:23:00

本帖最后由作者于 2010-2-2 14:02:04 编辑

或

(assoc 420 (entget(tblobjname "layer" layerName)))

返回nil说明没使用真彩色，反之则是

jaminth · 发表于 2010-2-2 07:50:00

请教caoyin:

比如assoc 420 (entget(tblobjname "layer" "col-p1")))

返回420 . 16571297), 如何把16571297算成原来的真彩色数值:252,219,161

caoyin · 发表于 2010-2-2 14:01:00

(defun TrueColor2RGB (col /)
(strcat (itoa (lsh (fix col) -16))
          ","
          (itoa (lsh (lsh (fix col) 16) -24))
          ","
          (itoa (lsh (lsh (fix col) 24) -24))
)
)

jaminth · 发表于 2010-2-2 22:09:00

谢谢caoyin

jaminth · 发表于 2010-2-2 22:20:00

下面这一行能够成功执行:

(vla-put-Color (vla-add (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))) "col-p4") 4)

可换成这样就不行了,请求帮助:

(vla-put-Color (vla-add (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))) "col-p4") "252,219,161")

caoyin · 发表于 2010-2-2 23:25:00

(setq ACAD   (vlax-get-acad-object)
      ColObj (vla-getinterfaceobject
               ACAD
               (strcat "AutoCAD.AcCmColor." (substr (getvar "AcadVer") 1 2))
             )
      LayObj (vla-add (vla-get-Layers (vla-get-ActiveDocument ACAD)) "col-p4")
)
(vla-SetRGB colObj 252 219 161)
(vla-put-TrueColor LayObj colObj)

jaminth · 发表于 2010-2-2 23:43:00

谢谢caoyin,上楼的代码能否简单解释一下?!万分感谢!

caoyin · 发表于 2010-2-2 23:58:00

要怎么解释？

(vla-getinterfaceobject ACAD (strcat "AutoCAD.AcCmColor." (substr (getvar "AcadVer") 1 2)));;加载真彩色对象

(vla-SetRGB colObj 252 219 161);;设置真彩色对象的Red Green Blue各自的值

(vla-put-TrueColor LayObj colObj);;将真彩赋与图层对象

账号		自动登录	找回密码
密码			注册

[基础] [求助]vlisp/lisp能否判断图层使用了"真彩色"?