[求助]打断的线段如何复原且为多线段

429014673 · 发表于 2010-7-23 18:00:00

;;;多段线除重点，来自晓东CAD

具体命令是什么呀？

429014673 · 发表于 2010-7-23 18:03:00

candy-jhl发表于2010-7-23 15:13:00用pedit命令，然后把线join是不是可以

是可以，打散还是出很多线的，不是三条线。

candy-jhl · 发表于 2010-7-23 21:13:00

用pedit里面有个编辑节点，可以把多余的节点转移到定点，但是那样比较麻烦，还不如重新画

yesson · 发表于 2010-7-24 00:04:00

不就是串联线吗？

楼上的那位已经回答了，用pedit命令，然后选join

我们放样套料是常用！

gufeng · 发表于 2010-7-24 11:18:00

(defun c:Test (/ ACAD_ERR ERR_INFO oldcmdecho)
(vl-load-com)
;_返回多段线坐标表
(defun Get_PL_plist (ename / ELEV EN ENTL FLAG PT VLIST)
(defun LI_item (n alist)
(cdr (assoc n alist))
)
(setq
vlist '()
entl (entget ename)
en (LI_item 0 entl)
)
(cond
((= en "LWPOLYLINE")
(setq
vlist '()
Elev (LI_item 38 entl)
)
(foreach pt entl
(if (= (car pt) 10)
(setq vlist (cons (list (cadr pt) (caddr pt) Elev) vlist))
)
)
(setq vlist (reverse vlist))
)
((= en "POLYLINE")
(setq
ename (entnext ename)
entl (entget ename)
en (LI_item 0 entl)
vlist '()
)
(while (= en "VERTEX")
(setq flag (LI_item 70 entl))
(if (and
(zerop (logand flag 1))
(zerop (logand flag 2))
(zerop (logand flag 8))
(/= flag 128)
)
(setq
pt (LI_item 10 entl)
vlist (cons pt vlist)
)
)
(setq
ename (entnext ename)
entl (entget ename)
en (LI_item 0 entl)
)
)
(setq vlist (reverse vlist))
)
)
vlist
)
;_主程序
(defun acad->app
(/ obj obj_i pl_new ANG1 ANG2 I ISCLOSE OBJ_ENAME OBJ_VLA PL X del_obj)
(setq oldcmdecho (getvar "cmdecho"))
(setvar "cmdecho" 0)
(while (not (setq obj (ssget '((0 . "*POLYLINE"))))))
(setq obj_i -1)
(initget "Y N")
(setq del_obj (getkword "是否删除原对象?[是(Y)/否(N)]]<否>:"))
(repeat (sslength obj)
(setq obj_ename (ssname obj (setq obj_i (1+ obj_i))))
(setq obj_vla (vlax-ename->vla-object obj_ename))
(setq pl (Get_PL_plist obj_ename)) ;_三维坐标表
(setq pl (mapcar '(lambda (x) (list (car x) (cadr x))) pl)) ;_二维坐标表
(setq isclose (vlax-curve-isClosed obj_vla)) ;_是否闭合
(if isclose
(setq pl (reverse (cons (cadr pl) (cons (car pl) (reverse pl)))))
)
(setq pl_new '())
(setq i 0)
(foreach x pl
(setq i (1+ i))
(if (not isclose)
(progn
(if (or (= i 1) (= i (length pl)))
(progn
(setq pl_new (cons x pl_new))
(if (= i 1)
(setq ang1 (angle x (nth i pl)))
)
)
(progn
(setq ang2 (angle x (nth i pl)))
(if ang2
(progn
(if (not (equal ang1 ang2 0.0000001))
(setq pl_new (cons x pl_new))
)
(setq ang1 ang2)
)
)
)
)
)
(progn
(if (/= i (length pl))
(progn
(setq ang2 nil)
(if (= i 1)
(setq ang1 (angle x (nth i pl)))
(setq ang2 (angle x (nth i pl)))
)
(if ang2
(progn
(if (not (equal ang1 ang2 0.0000001))
(setq pl_new (cons x pl_new))
)
(setq ang1 ang2)
)
)
)
)
)
)
)
(command "pline")
(mapcar '(lambda (x)
(command x)
)
pl_new
)
(if isclose
(command "Close")
(command "")
)
(if (= del_obj "Y")
(entdel obj_ename)
)
);_end repeat
(setvar "cmdecho" oldcmdecho)
);_end defun acad->app
;_以下为错误信息显示
(setq acad_err (vl-catch-all-apply
'(lambda ()
(acad->app)
)
)
)
(if (vl-catch-all-error-p acad_err) ;_如果返回的是错误对象
(progn
(setq err_info (vl-catch-all-error-message acad_err)) ;_截获错误信息
(setq err_info (strcat "\n错误提示:" err_info))
(setvar "cmdecho" oldcmdecho)
(vl-exit-with-error (princ err_info))
)
)
(princ)
)

(defun c:Test (/ ACAD_ERR ERR_INFO oldcmdecho)
(vl-load-com)
;_返回多段线坐标表
(defun Get_PL_plist (ename / ELEV EN ENTL FLAG PT VLIST)
  (defun LI_item (n alist)
    (cdr (assoc n alist))
  )
  (setq
    vlist '()
    entl  (entget ename)
    en   (LI_item 0 entl)
  )
  (cond
    ((= en "LWPOLYLINE")
     (setq
       vlist '()
       Elev  (LI_item 38 entl)
     )
     (foreach pt entl
       (if (= (car pt) 10)
  (setq vlist (cons (list (cadr pt) (caddr pt) Elev) vlist))
       )
     )
     (setq vlist (reverse vlist))
    )
    ((= en "POLYLINE")
     (setq
       ename (entnext ename)
       entl  (entget ename)
       en    (LI_item 0 entl)
       vlist '()
     )
     (while (= en "VERTEX")
       (setq flag (LI_item 70 entl))
       (if (and
      (zerop (logand flag 1))
      (zerop (logand flag 2))
      (zerop (logand flag 8))
      (/= flag 128)
    )
  (setq
    pt  (LI_item 10 entl)
    vlist (cons pt vlist)
  )
       )
       (setq
  ename (entnext ename)
  entl  (entget ename)
  en    (LI_item 0 entl)
       )
     )
     (setq vlist (reverse vlist))
    )
  )
  vlist
)
;_主程序
(defun acad->app
       (/ obj obj_i pl_new ANG1 ANG2 I ISCLOSE OBJ_ENAME OBJ_VLA PL X del_obj)
  (setq oldcmdecho (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (while (not (setq obj (ssget '((0 . "*POLYLINE"))))))
  (setq obj_i -1)
  (initget "Y N")
  (setq del_obj (getkword "是否删除原对象?[是(Y)/否(N)]]<否>:"))
  (repeat (sslength obj)
    (setq obj_ename (ssname obj (setq obj_i (1+ obj_i))))
    (setq obj_vla (vlax-ename->vla-object obj_ename))
    (setq pl (Get_PL_plist obj_ename)) ;_三维坐标表
    (setq pl (mapcar '(lambda (x) (list (car x) (cadr x))) pl)) ;_二维坐标表
    (setq isclose (vlax-curve-isClosed obj_vla)) ;_是否闭合
    (if isclose
      (setq pl (reverse (cons (cadr pl) (cons (car pl) (reverse pl)))))
    )
    (setq pl_new '())
    (setq i 0)
    (foreach x pl
      (setq i (1+ i))
      (if (not isclose)
 (progn
   (if (or (= i 1) (= i (length pl)))
     (progn
       (setq pl_new (cons x pl_new))
       (if (= i 1)
  (setq ang1 (angle x (nth i pl)))
       )
     )
     (progn
       (setq ang2 (angle x (nth i pl)))
       (if ang2
  (progn
    (if (not (equal ang1 ang2 0.0000001))
      (setq pl_new (cons x pl_new))
    )
    (setq ang1 ang2)
  )
       )
     )
   )
 )
 (progn
   (if (/= i (length pl))
     (progn
       (setq ang2 nil)
       (if (= i 1)
  (setq ang1 (angle x (nth i pl)))
  (setq ang2 (angle x (nth i pl)))
       )
       (if ang2
  (progn
    (if (not (equal ang1 ang2 0.0000001))
      (setq pl_new (cons x pl_new))
    )
    (setq ang1 ang2)
  )
       )
     )
   )
 )
      )
    )
    (command "pline")
    (mapcar '(lambda (x)
        (command x)
      )
     pl_new
    )
    (if isclose
      (command "Close")
      (command "")
    )
    (if (= del_obj "Y")
      (entdel obj_ename)
      )
  );_end repeat
  (setvar "cmdecho" oldcmdecho)
);_end defun acad->app
  
;_以下为错误信息显示
(setq acad_err (vl-catch-all-apply
   '(lambda ()
      (acad->app)
    )
        )
)
(if (vl-catch-all-error-p acad_err) ;_如果返回的是错误对象
  (progn
    (setq err_info (vl-catch-all-error-message acad_err)) ;_截获错误信息
    (setq err_info (strcat "\n错误提示:" err_info))
    (setvar "cmdecho" oldcmdecho)
    (vl-exit-with-error (princ err_info))
  )
)
(princ)
)

429014673 · 发表于 2010-7-25 14:13:00

gufeng发表于2010-7-24 11:18:00以下内容为程序代码: (defun c:Test (/ ACAD_ERR ERR_INFO oldcmdecho) (vl-load-com) ;_返回多段线坐标表 (defun Get_PL_plist (ename / ELEV EN ENTL FLAG PT VLIST)

429014673 · 发表于 2010-7-25 14:14:00

原来的线还在，最好可以删除。

gufeng · 发表于 2010-7-26 16:54:00

是否删除原对象?[是(Y)/否(N)]]<否>:"

提示是输入Y不就可以删除了？

tc405003 · 发表于 2011-12-23 14:48:02

9楼的源程序好像少了一个子程序 POLYDUMPPOINT 9楼的楼主能否补上，多谢了

cxjzxh · 发表于 2012-3-16 15:21:53

确实少了，麻烦补上来，多谢！

账号		自动登录	找回密码
密码			注册

[基础] [求助]打断的线段如何复原且为多线段