【越飞越高讲堂14】椭圆论

crtrccrt · 发表于 2012-11-17 09:18:27

一个字太牛了太牛了

海盗曹 · 发表于 2012-11-17 22:29:01

向前辈学习啦

highflybir · 发表于 2012-11-17 22:59:49

更新了一些问题的解。如：十一题最似圆椭圆问题

MENGZE · 发表于 2013-5-4 00:28:37

版主，弱弱问下在CAD模型空间中椭圆形椎体怎么展开？求回复！！！

wangdaobin · 发表于 2013-5-7 00:50:50

严重支持高师傅！！

highflybir · 发表于 2013-5-28 10:48:15

MENGZE 发表于 2013-5-4 00:28
版主，弱弱问下在CAD模型空间中椭圆形椎体怎么展开？求回复！！！

;;;=====================================================================
;;; 功能: 展开椭圆锥体。
;;; 输入: 椭圆锥底椭圆的长轴a，短轴b，椭圆锥的高h和分弧精度n
;;; 输出: 展开图的曲线的坐标点(可据此形成展开面)
;;;=====================================================================
(defun ELL:ExpandCone (a b h n / Pts Ang D Param DivAng P0 P1 R0 R1 X Y)
(setq DivAng (/ pi n 0.5)) ;等分角度
(setq Param 0) ;开始参数为0
(setq p0 (list a 0)) ;从椭圆最右边的点开始
(setq r0 (distance '(0 0 0) (list a 0 h))) ;开始的锥顶最右边点的距离
(setq Pts (list (list r0 0) '(0 0))) ;把最开始的两点加入到数据表
(setq Ang 0) ;开始角度也为0
(repeat n
(setq Param (+ Param DivAng))
(setq x (* a (cos Param))) ;椭圆上的x坐标
(setq y (* b (sin Param))) ;椭圆上的y坐标
(setq p1 (list x y)) ;点的坐标
(setq r1 (distance '(0 0 0) (list x y h))) ;展开面的锥线长度
(setq d (distance p0 p1)) ;椭圆上的上一点到这点的距离
(setq Ang (+ Ang (car (TRI:CosinesLaw d r0 r1)))) ;坐标角度
(setq Pts (cons (polar '(0 0) Ang r1) Pts)) ;得到了坐标，并把它加入到表中
(setq p0 p1) ;用新的坐标位置替换旧位置
(setq r0 r1) ;用新的锥线长度替换旧长度
)
(reverse Pts) ;逆转表，得到正序的数据
)
;;; 测试椭圆锥的展开
(defun c:ExpandCone(/ h N e d r c m a b l e o)
(initget 1)
(setq h (getdist "\n输入椭圆锥高: "))
(initget 7)
(setq N (getint "\n等分数:"))
(prompt "\n选择椭圆:")
(if (setq s (ssget ":S" '((0 . "ELLIPSE"))))
(progn
(setq e (ssname s 0))
(setq d (entget e))
(setq r (cdr (assoc 40 d)))
(setq c (cdr (assoc 10 d)))
(setq m (cdr (assoc 11 d)))
(setq a (distance '(0 0 0) m))
(setq b (* r a))
(setq l (ELL:ExpandCone a b h n))
(setq o (vlax-ename->vla-object (Ent:Make_LWPoly l T)))
(vla-move o (vlax-3d-point '(0 0 0)) (vlax-3d-point c))
(princ)
)
)
)
;;;----------------------------------------------------;
;;; 功能: 根据三边求三个角(利用余弦定理) ;
;;; 输入: 构成三角形的三边a,b,c ;
;;; 输出: 返会三条边对应的三个角 ;
;;;----------------------------------------------------;
(defun TRI:CosinesLaw (a b c / cc sc a1 a2)
(if (TRI:IsTriangle a b c)
(progn
(setq a (float a)) ;为了防止整除
(setq cc (/ (+ (* a a) (* (+ b c) (- b c))) (+ a a) b)) ;角C的余弦
(setq sc (sqrt (* (- 1 cc) (1+ cc)))) ;角C的正弦
(setq a1 (atan (* a sc) (- b (* a cc)))) ;角A
(setq a2 (atan sc cc)) ;角C
(list a1 (- pi a1 a2) a2) ;返回三个角度的列表
)
)
)
;;;----------------------------------------------------;
;;;创建一个三维多段线 ;
;;;输入: 三维的点集 ;
;;;输出: 三维多段线实体 ;
;;;----------------------------------------------------;
(defun Ent:Make_Poly (pts / e)
(setq e (Entmake (list '(0 . "POLYLINE") '(70 . 9))))
(foreach p pts
(entmake (list '(0 . "VERTEX") '(70 . 32) (cons 10 p)))
)
(entmake '((0 . "SEQEND")))
(entlast)
)

;;;===================================================================== 
;;; 功能: 展开椭圆锥体。                                    
;;; 输入: 椭圆锥底椭圆的长轴a，短轴b，椭圆锥的高h和分弧精度n             
;;; 输出: 展开图的曲线的坐标点(可据此形成展开面)                         
;;;===================================================================== 
(defun ELL:ExpandCone (a b h n / Pts Ang D Param DivAng P0 P1 R0 R1 X Y) 
  (setq DivAng (/ pi n 0.5))      ;等分角度 
  (setq Param 0)       ;开始参数为0 
  (setq p0 (list a 0))       ;从椭圆最右边的点开始 
  (setq r0 (distance '(0 0 0) (list a 0 h)))    ;开始的锥顶最右边点的距离 
  (setq Pts (list (list r0 0) '(0 0)))     ;把最开始的两点加入到数据表 
  (setq Ang 0)        ;开始角度也为0 
  (repeat n 
    (setq Param  (+ Param DivAng)) 
    (setq x   (* a (cos Param)))     ;椭圆上的x坐标 
    (setq y   (* b (sin Param)))     ;椭圆上的y坐标 
    (setq p1  (list x y))      ;点的坐标 
    (setq r1  (distance '(0 0 0) (list x y h)))    ;展开面的锥线长度 
    (setq d   (distance p0 p1))      ;椭圆上的上一点到这点的距离 
    (setq Ang (+ Ang (car (TRI:CosinesLaw d r0 r1))))   ;坐标角度 
    (setq Pts (cons (polar '(0 0) Ang r1) Pts))    ;得到了坐标，并把它加入到表中 
    (setq p0 p1)       ;用新的坐标位置替换旧位置 
    (setq r0 r1)       ;用新的锥线长度替换旧长度 
  ) 
  (reverse Pts)        ;逆转表，得到正序的数据 
) 
;;; 测试椭圆锥的展开 
(defun c:ExpandCone(/ h N e d r c m a b l e o) 
  (initget 1) 
  (setq h (getdist "\n输入椭圆锥高: ")) 
  (initget 7) 
  (setq N (getint "\n等分数:")) 
  (prompt "\n选择椭圆:") 
  (if (setq s (ssget ":S" '((0 . "ELLIPSE")))) 
    (progn 
      (setq e (ssname s 0)) 
      (setq d (entget e)) 
      (setq r (cdr (assoc 40 d))) 
      (setq c (cdr (assoc 10 d))) 
      (setq m (cdr (assoc 11 d))) 
      (setq a (distance '(0 0 0) m)) 
      (setq b (* r a)) 
      (setq l (ELL:ExpandCone a b h n)) 
      (setq o (vlax-ename->vla-object (Ent:Make_LWPoly l T))) 
      (vla-move o (vlax-3d-point '(0 0 0)) (vlax-3d-point c)) 
      (princ) 
    ) 
  ) 
) 
;;;----------------------------------------------------; 
;;; 功能: 根据三边求三个角(利用余弦定理)               ; 
;;; 输入: 构成三角形的三边a,b,c                        ; 
;;; 输出: 返会三条边对应的三个角                       ; 
;;;----------------------------------------------------; 
(defun TRI:CosinesLaw (a b c / cc sc a1 a2) 
  (if (TRI:IsTriangle a b c) 
    (progn 
      (setq a  (float a))     ;为了防止整除 
      (setq cc (/ (+ (* a a) (* (+ b c) (- b c))) (+ a a) b)) ;角C的余弦 
      (setq sc (sqrt (* (- 1 cc) (1+ cc))))    ;角C的正弦 
      (setq a1 (atan (* a sc) (- b (* a cc))))    ;角A 
      (setq a2 (atan sc cc))     ;角C 
      (list a1 (- pi a1 a2) a2)     ;返回三个角度的列表 
    ) 
  ) 
) 
;;;----------------------------------------------------; 
;;;创建一个三维多段线                                  ; 
;;;输入: 三维的点集                                    ; 
;;;输出: 三维多段线实体                                ; 
;;;----------------------------------------------------; 
(defun Ent:Make_Poly (pts / e) 
  (setq e (Entmake (list '(0 . "POLYLINE") '(70 . 9)))) 
  (foreach p pts 
    (entmake (list '(0 . "VERTEX") '(70 . 32) (cons 10 p))) 
  ) 
  (entmake '((0 . "SEQEND"))) 
  (entlast) 
)

MENGZE · 发表于 2013-5-29 21:18:31

谢谢老师！！！

MENGZE · 发表于 2013-5-29 21:19:11

受教了！！！

自贡黄明儒 · 发表于 2013-9-24 13:02:02

C:test4中(setq ptb (vlax-curve-getPointAtParam ent (* pi 0.5)))与成了(setq ptb (vlax-curve-getPointAtParam en (* pi 0.5)))

NJZX05 · 发表于 2013-11-22 17:05:47

鸟哥的东西，不赞都不行啊！！！！！要是我早看到，要少走多少弯路啊！！！

账号		自动登录	找回密码
密码			注册