怎么实现点击封闭图形内部，自动形成开洞线

a405692168 · 发表于 2023-10-22 23:12

tt; 错误: no function definition: XYP-MKLACO

我怎么用不了......

qazxswk · 发表于 2023-10-22 23:16

a405692168 发表于 2023-10-22 23:12
tt; 错误: no function definition: XYP-MKLACO

要配合e派工具箱使用。

qazxswk · 发表于 2023-10-22 23:36

我的不需要配合任何工具箱的。可以试试
(defun c:11(/  ent  pt p1 p2 p3 p0 len len1 minpoint maxpoint)
(while
(setq pt (getpoint "\n在闭合区域拾取一点<退出>:"))
(vl-cmdf "-boundary" pt "")
(setq ent (entlast))
(vla-getboundingbox (vlax-ename->vla-object ent) 'minpoint 'maxpoint) ;获得包围盒
(setq p1(vlax-safearray->list minpoint) p3(vlax-safearray->list maxpoint)) ;盒最小与最大点
(entdel ent)
(setq p2 (list (car p1)(cadr p3)))
(setq len (distance p1 p2))
(setq len1 (distance p3 p2))
(if (< len len1)
(setq p0 (polar p1 (/ pi 3)  (* len 0.8)))
(setq p0 (polar p1 (/ pi 2.2)  (* len 0.8)))
)
(entmake (list'(0 . "LWPOLYLINE")'(100 . "AcDbEntity")'(100 . "AcDbPolyline")(cons 62 8)
(cons 90 3) (cons 10 p1) (cons 10 p0) (cons 10 p3) ))
)
(princ))

wlpkok · 发表于 2023-10-25 15:20

qazxswk 发表于 2023-10-22 23:36
我的不需要配合任何工具箱的。可以试试
(defun c:11(/ ent pt p1 p2 p3 p0 len len1 minpoint maxpoint) ...

还是大哥你这个好用

a405692168 · 发表于 2023-10-26 20:53

qazxswk 发表于 2023-10-22 23:36
我的不需要配合任何工具箱的。可以试试
(defun c:11(/ ent pt p1 p2 p3 p0 len len1 minpoint maxpoint) ...

谢谢，大神这个好用，有空的时候，能增加个功能：自动把开洞线固定到"开洞线"图层上吗？

qazxswk · 发表于 2023-10-27 13:23

本帖最后由 qazxswk 于 2023-10-30 00:09 编辑

a405692168 发表于 2023-10-26 20:53
谢谢，大神这个好用，有空的时候，能增加个功能：自动把开洞线固定到"开洞线"图层上吗？

(defun c:11(/  ent  pt p1 p2 p3 p0 len len1 minpoint maxpoint)
(if (= (tblobjname "layer" "开洞线") nil)
(entmake (list'(0 . "layer")'(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLayerTableRecord")
(cons 2 "开洞线") '(70 . 0) '(62 . 8)
)))
(while
(setq pt (getpoint "\n在闭合区域拾取一点<退出>:"))
(vl-cmdf "-boundary" pt "")
(setq ent (entlast))
(vla-getboundingbox (vlax-ename->vla-object ent) 'minpoint 'maxpoint) ;获得包围盒
(setq p1(vlax-safearray->list minpoint) p3(vlax-safearray->list maxpoint)) ;盒最小与最大点
(entdel ent)
(setq p2 (list (car p1)(cadr p3)))
(setq len (distance p1 p2))
(setq len1 (distance p3 p2))
(if (< len len1)
(setq p0 (polar p1 (/ pi 3)  (* len 0.8)))
(setq p0 (polar p1 (/ pi 2.2)  (* len 0.8)))
)
(entmake (list'(0 . "LWPOLYLINE")'(100 . "AcDbEntity")'(100 . "AcDbPolyline")(cons 8 "开洞线")
(cons 90 3) (cons 10 p1) (cons 10 p0) (cons 10 p3) ))
)
(princ))

hd654 · 发表于 2023-10-27 18:59

这个功能不错，我用画门板的开启线，马克了

账号		自动登录	找回密码
密码			注册

[提问] 怎么实现点击封闭图形内部，自动形成开洞线