如何批量偏移？这将是造福结构佬的一个大作，求大神解决~~

依然小小鸟 · 发表于 2020-2-15 16:45:20

至今没解决

Atsai · 发表于 2020-2-19 11:16:38

本帖最后由 Atsai 于 2020-2-26 09:09 编辑

下面的代码是用封闭曲线去选择其内的物件，选到了分好组再偏移就可以达到需求。

;;; SelByObj -Gilles Chanteau- 06/10/06
;;; Cree un jeu de selection avec tous les objets contenus ou
;;; captures, dans la vue courante, par l'objet selectionne
;;; (cercle, ellipse, polyligne fermee).
;;; Arguments :
;;; - un nom d'entite (ename)
;;; - un mode de selection (Cp ou Wp)
;;; - un filtre de selection ou nil
;;;
;;; modifie le 19/07/07 : fonctionne avec les objets hors fenetre
;;; Creates a selection set by crossing or window polygon
;;; using a curve entity (circle, ellipse or closed polyline)
;;; Arguments :
;;; - ename of the entity use for selection
;;; - selection mode (CP or WP)
;;; - a selection filter or nil
(defun SelByObj (ent opt fltr / obj dist n lst prec dist p_lst ss)
(vl-load-com)
(if (= (type ent) 'ENAME)
(setq obj (vlax-ename->vla-object ent))
(setq obj ent
ent (vlax-vla-object->ename ent)
)
)
(cond
((member (vla-get-ObjectName obj)
'("AcDbCircle" "AcDbEllipse")
)
(setq dist (/ (vlax-curve-getDistAtParam
obj
(vlax-curve-getEndParam obj)
)
50
)
n 0
)
(repeat 50
(setq
lst
(cons
(trans
(vlax-curve-getPointAtDist obj (* dist (setq n (1+ n))))
0
1
)
lst
)
)
)
)
((and (= (vla-get-ObjectName obj) "AcDbPolyline")
(= (vla-get-Closed obj) :vlax-true)
)
(setq p_lst (vl-remove-if-not
'(lambda (x)
(or (= (car x) 10)
(= (car x) 42)
)
)
(entget ent)
)
)
(while p_lst
(setq
lst
(cons
(trans (append (cdr (assoc 10 p_lst))
(list (cdr (assoc 38 (entget ent))))
)
ent
1
)
lst
)
)
(if (/= 0 (cdadr p_lst))
(progn
(setq prec (1+ (fix (* 25 (sqrt (abs (cdadr p_lst))))))
dist (/ (- (if (cdaddr p_lst)
(vlax-curve-getDistAtPoint
obj
(trans (cdaddr p_lst) ent 0)
)
(vlax-curve-getDistAtParam
obj
(vlax-curve-getEndParam obj)
)
)
(vlax-curve-getDistAtPoint
obj
(trans (cdar p_lst) ent 0)
)
)
prec
)
n 0
)
(repeat (1- prec)
(setq
lst (cons
(trans
(vlax-curve-getPointAtDist
obj
(+ (vlax-curve-getDistAtPoint
obj
(trans (cdar p_lst) ent 0)
)
(* dist (setq n (1+ n)))
)
)
0
1
)
lst
)
)
)
)
)
(setq p_lst (cddr p_lst))
)
)
)
(cond
(lst
(vla-ZoomExtents (vlax-get-acad-object))
(setq ss (ssget (strcat "_" opt) lst fltr))
(vla-ZoomPrevious (vlax-get-acad-object))
ss
)
)
)

;;; SelByObj -Gilles Chanteau- 06/10/06 
;;; Cree un jeu de selection avec tous les objets contenus ou 
;;; captures, dans la vue courante, par l'objet selectionne 
;;; (cercle, ellipse, polyligne fermee). 
;;; Arguments : 
;;; - un nom d'entite (ename) 
;;; - un mode de selection (Cp ou Wp) 
;;; - un filtre de selection ou nil 
;;; 
;;; modifie le 19/07/07 : fonctionne avec les objets hors fenetre 
 
;;; Creates a selection set by crossing or window polygon 
;;; using a curve entity (circle, ellipse or closed polyline) 
;;; Arguments : 
;;; - ename of the entity use for selection 
;;; - selection mode (CP or WP) 
;;; - a selection filter or nil 
  (defun SelByObj (ent opt fltr / obj dist n lst prec dist p_lst ss) 
    (vl-load-com) 
    (if        (= (type ent) 'ENAME) 
      (setq obj (vlax-ename->vla-object ent)) 
      (setq obj        ent 
            ent        (vlax-vla-object->ename ent) 
      ) 
    ) 
    (cond 
      ((member (vla-get-ObjectName obj) 
               '("AcDbCircle" "AcDbEllipse") 
       ) 
       (setq dist (/ (vlax-curve-getDistAtParam 
                       obj 
                       (vlax-curve-getEndParam obj) 
                     ) 
                     50 
                  ) 
             n          0 
       ) 
       (repeat 50 
         (setq 
           lst 
            (cons 
              (trans 
                (vlax-curve-getPointAtDist obj (* dist (setq n (1+ n)))) 
                0 
                1 
              ) 
              lst 
            ) 
         ) 
       ) 
      ) 
      ((and (= (vla-get-ObjectName obj) "AcDbPolyline") 
            (= (vla-get-Closed obj) :vlax-true) 
       ) 
       (setq p_lst (vl-remove-if-not 
                     '(lambda (x) 
                        (or (= (car x) 10) 
                            (= (car x) 42) 
                        ) 
                      ) 
                     (entget ent) 
                   ) 
       ) 
       (while p_lst 
         (setq 
           lst 
            (cons 
              (trans (append (cdr (assoc 10 p_lst)) 
                             (list (cdr (assoc 38 (entget ent)))) 
                     ) 
                     ent 
                     1 
              ) 
              lst 
            ) 
         ) 
         (if (/= 0 (cdadr p_lst)) 
           (progn 
             (setq prec        (1+ (fix (* 25 (sqrt (abs (cdadr p_lst)))))) 
                   dist        (/ (- (if (cdaddr p_lst) 
                                (vlax-curve-getDistAtPoint 
                                  obj 
                                  (trans (cdaddr p_lst) ent 0) 
                                ) 
                                (vlax-curve-getDistAtParam 
                                  obj 
                                  (vlax-curve-getEndParam obj) 
                                ) 
                              ) 
                              (vlax-curve-getDistAtPoint 
                                obj 
                                (trans (cdar p_lst) ent 0) 
                              ) 
                           ) 
                           prec 
                        ) 
                   n        0 
             ) 
             (repeat (1- prec) 
               (setq 
                 lst (cons 
                       (trans 
                         (vlax-curve-getPointAtDist 
                           obj 
                           (+ (vlax-curve-getDistAtPoint 
                                obj 
                                (trans (cdar p_lst) ent 0) 
                              ) 
                              (* dist (setq n (1+ n))) 
                           ) 
                         ) 
                         0 
                         1 
                       ) 
                       lst 
                     ) 
               ) 
             ) 
           ) 
         ) 
         (setq p_lst (cddr p_lst)) 
       ) 
      ) 
    ) 
    (cond 
      (lst 
       (vla-ZoomExtents (vlax-get-acad-object)) 
       (setq ss (ssget (strcat "_" opt) lst fltr)) 
       (vla-ZoomPrevious (vlax-get-acad-object)) 
       ss 
      ) 
    ) 
  )

wudechao · 发表于 2020-2-19 13:23:08

本帖最后由 wudechao 于 2020-2-19 13:24 编辑

20060510412 发表于 2019-1-8 08:53
E派工具箱，功能强大，程序数量也多，但是太臃肿了，为了一两个功能，需要加载那么多不需要的功能，所以 ...

我也如此，附加功能没有源代码的不用。cad是因为无法剥离无用功能，所以只能装完整版。

caoyin · 发表于 2021-3-4 12:35:17

新开一贴，看看是否符号要求：http://bbs.mjtd.com/thread-183094-1-1.html

lee50310 · 发表于 2021-4-14 20:00:58

本帖最后由 lee50310 于 2021-4-15 08:36 编辑

請問你程式的需求是希望達到如 2樓動態圖所演示的那樣嗎?
還是照你原本半成品程式的詢問方式
如:
1."請輸入偏移方式[正向(Z)/反向(F)/雙向(S)/通過(T)]<"
2.請輸入偏移距離
3.請選擇基點

依然小小鸟 · 发表于 2021-4-15 10:53:57

lee50310 发表于 2021-4-14 20:00
請問你程式的需求是希望達到如 2樓動態圖所演示的那樣嗎?
還是照你原本半成品程式的詢問方式
如:

我希望的结果是动态图里面的效果我帖子里面的CAD测试图也有一部分展示

lee50310 · 发表于 2021-4-18 15:17:32

本帖最后由 lee50310 于 2021-4-20 13:50 编辑

我希望的结果是动态图里面的效果

依你的需求,程式已寫好並在cad2018測試 ok
我稍微整理一下再發表,請耐心等待

依然小小鸟 · 发表于 2021-4-19 11:05:34

lee50310 发表于 2021-4-18 15:17
依你的需求,程式已寫好並在cad2018測試 ok
我稍微整理一下再發表,請耐心等待

期待

lee50310 · 发表于 2021-4-20 13:53:10

本帖最后由 lee50310 于 2024-7-3 12:59 编辑

讓你久等了!
請到此處下載
http://bbs.mjtd.com/thread-183326-1-1.html

litianwu8900 · 发表于 2022-10-13 16:17:14

很有用，能自动换了颜色，向内向外都行，太给力了。

账号		自动登录	找回密码
密码			注册

[提问] 如何批量偏移？这将是造福结构佬的一个大作，求大神解决~~

本帖子中包含更多资源

本帖子中包含更多资源