如何获取块内某点的全局坐标

kozmosovia

光算基点没有用，块的比例，旋转和镜像都有影响。所以需要用正经的块转换矩阵进行transform

飞雪神光

xunifengshen 发表于 2025-9-1 09:02
我就是没法获取全局坐标啊 块基点和块内坐标岂不是一样的道理 获取的块基点都是0  没什么用

发图看看   

xunifengshen

飞雪神光 发表于 2025-9-1 09:55
发图看看

不好意思  现在网站不能上传文件和图片了 我大约描述下吧 当我选择两个相同的块时 这两个块都有一个相同的圆 我把这两个圆心坐标找出来 后续操作 比如 连线

xunifengshen

kozmosovia 发表于 2025-9-1 09:13
光算基点没有用，块的比例，旋转和镜像都有影响。所以需要用正经的块转换矩阵进行transform

这个矩阵确实是很好 但是这个方法有点技术含量  有点吃不透了 我就想着通过一个方法获取两个相同块内的相同元素 比如一个圆的圆心 找出这两个坐标 然后连线

caoyin

;;p1是块定义内的点，P2是块参照所在空间的点

(setq en  (car (entsel "\n选择块参照: "))
      mat (RefGeom en)
      p2  (mapcar '+ (mxv (car mat) p1) (cadr mat))
)


;; RefGeom (gile)
;; returns a list which first item is a 3x3 transformation matrix (rotation,
;; scales, normal) and second item the object insertion point in its parent
;; (xref, bloc or space)
;;
;; Argument : an ename
(defun RefGeom (ename / elst ang norm)
  (setq elst (entget ename)
        ang  (cdr (assoc 50 elst))        
        norm (cdr (assoc 210 elst))
  )
  (list
    (mxm
      (mapcar (function (lambda (v) (trans v 0 norm T)))
          '((1.0 0.0 0.0) (0.0 1.0 0.0) (0.0 0.0 1.0))
      )
      (mxm
        (list (list (cos ang) (- (sin ang)) 0.0)
              (list (sin ang) (cos ang) 0.0)
              '(0.0 0.0 1.0)
        )
        (list (list (cdr (assoc 41 elst)) 0.0 0.0)
              (list 0.0 (cdr (assoc 42 elst)) 0.0)
              (list 0.0 0.0 (cdr (assoc 43 elst)))
        )
      )
    )
    (trans (cdr (assoc 10 elst)) norm 0)
  )
)

;;; VXV Returns the dot product of 2 vectors
(defun vxv (v1 v2)
  (apply '+ (mapcar '* v1 v2))
)
;; TRP Transpose a matrix -Doug Wilson-
(defun trp (m)
  (apply 'mapcar (cons 'list m))
)
;; MXV Apply a transformation matrix to a vector -Vladimir Nesterovsky-
(defun mxv (m v)
  (mapcar '(lambda (r) (vxv r v)) m)
)
;; MXM Multiply two matrices -Vladimir Nesterovsky-
(defun mxm (m q)
  (mapcar '(lambda (r) (mxv (trp q) r)) m)
)

kozmosovia

xunifengshen 发表于 2025-9-1 10:49
这个矩阵确实是很好 但是这个方法有点技术含量  有点吃不透了 我就想着通过一个方法获取两个相同块内的相 ...

简易方式：在圆心放置一个非常小的属性，然后直接从块参照提取块内属性，通过取属性的定位点获取实际的圆心WCS的坐标。这样就完全不用考虑矩阵。

caoyin

kozmosovia 发表于 2025-9-1 11:19
简易方式：在圆心放置一个非常小的属性，然后直接从块参照提取块内属性，通过取属性的定位点获取实际的圆 ...

不推荐这样
1.结果错误：属性和属性定义可以不在一个位置的
2.方法不好

xunifengshen

caoyin 发表于 2025-9-1 11:12
;;p1是块内点，P2是当前空间的点

(setq en  (car (entsel "\n选择块参照: "))

选择块参照: ; 错误: no function definition: REFGEOM

caoyin

xunifengshen 发表于 2025-9-1 11:32
选择块参照: ; 错误: no function definition: REFGEOM

后面的引用程序没看到吗？

kozmosovia

caoyin 发表于 2025-9-1 11:32
不推荐这样
1.结果错误：属性和属性定义可以不在一个位置的
2.方法不好

属性是可以lockpoisiton的