[求助]：[1227]请问logand与logior两命令的涵义与用法?

sfzyr · 发表于 2012-5-21 21:12:12

本帖最后由 sfzyr 于 2012-5-21 21:31 编辑

与c 语言中的位逻辑与& ，位逻辑或 | 是一样的，如下：
(logand 7 15 3)：
7=111；15=1111 ； 3=11
故计算如下：
   0  1  1  1
   1  1  1  1
& 0  0  1  1
--------------------
= 0 0  1  1
= 3

http://bbs.mjtd.com/thread-2747-2-1.html

smartstar · 发表于 2012-5-22 18:12:14

谢谢，终于明白了。

自贡黄明儒 · 发表于 2012-5-23 12:39:30

学习了！！！！

crazylsp · 发表于 2013-5-11 22:19:21

端点1 中点2
(logand 0 3)  0 3=0+3 0 但  (logand >3的 3) ?? 可能有3啊 ?
(logand 1 3) 1 3=1+2 1 端点
(logand 2 3) 2  3=1+2  2 中点
(logand 3 3) 3  3 3 端点中点

洪少(刀模) · 发表于 2018-11-6 14:26:02

略明白，但基础不硬，用在vlisp还有待练习，谢谢

yjtdkj · 发表于 2021-6-24 16:17:52

; a way to find a closed polyline by point inside
;Lee Mac
(defun polyfrominsidepoint (p / e i r s)
(if
(setq i -1
s
(ssget "_X"
(list '(0 . "LWPOLYLINE")
'(-4 . "&=")
'(70 . 1)
(if (= 1 (getvar 'cvport))
(cons 410 (getvar 'ctab))
'(410 . "Model")
)
)
)
)
(while (and (null r) (setq e (ssname s (setq i (1+ i)))))
(if (raycast p
(mapcar 'cdr
(vl-remove-if-not '(lambda (x) (= 10 (car x)))
(entget e)
)
)
)
(setq r e)
)
)
)
r
)
(defun raycast (p l)
(= 1
(logand 1
(length
(vl-remove 'nil
(mapcar
'(lambda (a b)
(inters p (mapcar '+ p '(1e8 0.0)) a b)
)
(cons (last l) l)
l
)
)
)
)
)
)
(defun c:SelPolylinebyPoint (/ e p)
(if (setq p (getpoint "\nSpecify point: "))
(if (setq e (polyfrominsidepoint p))
(sssetfirst nil (ssadd e))
(princ "\nNo polyline found.")
)
)
(princ)
)

; a way to find a closed polyline by point inside 
 ;Lee Mac 
(defun polyfrominsidepoint (p / e i r s) 
  (if 
    (setq i -1 
          s 
            (ssget "_X" 
                   (list '(0 . "LWPOLYLINE") 
                         '(-4 . "&=") 
                         '(70 . 1) 
                         (if (= 1 (getvar 'cvport)) 
                           (cons 410 (getvar 'ctab)) 
                           '(410 . "Model") 
                         ) 
                   ) 
            ) 
    ) 
     (while (and (null r) (setq e (ssname s (setq i (1+ i))))) 
       (if (raycast p 
                    (mapcar 'cdr 
                            (vl-remove-if-not '(lambda (x) (= 10 (car x))) 
                                              (entget e) 
                            ) 
                    ) 
           ) 
         (setq r e) 
       ) 
     ) 
  ) 
  r 
) 
(defun raycast (p l) 
  (= 1 
     (logand 1 
             (length 
               (vl-remove 'nil 
                          (mapcar 
                            '(lambda (a b) 
                               (inters p (mapcar '+ p '(1e8 0.0)) a b) 
                             ) 
                            (cons (last l) l) 
                            l 
                          ) 
               ) 
             ) 
     ) 
  ) 
) 
(defun c:SelPolylinebyPoint (/ e p) 
  (if (setq p (getpoint "\nSpecify point: ")) 
    (if        (setq e (polyfrominsidepoint p)) 
      (sssetfirst nil (ssadd e)) 
      (princ "\nNo polyline found.") 
    ) 
  ) 
  (princ) 
)

大家看看，李麦克的用法，是什么讲究？

账号		自动登录	找回密码
密码			注册

[求助]：[1227]请问logand与logior两命令的涵义与用法?

浏览过的版块