[求助]谁能帮我做个缩放对象但其中的标注文字与箭头不变

wowan1314

10楼上传的程序出现新问题无法加载字体！

8楼的CAOYIN大侠。我操作的过程是这样的！ 对一个标注SC两倍，结果：如期结果！数字不变！

对SC后的标注再SC两倍，结果：数字也变大两倍。

你编的LSP就是我想要的效果！^_^ 所以请你再改进一下下！让它怎么SC都不变化！  

caoyin

(defun c:test (/ ss pt ss2 flag alst)
  (defun lt:ss->list (ss / en)
    (vl-remove nil (mapcar '(lambda (x)
                             (if (= (type (setq en (cadr x))) 'ename) en)
                            )
                           (ssnamex ss)
                   )
    )
  )
  (if (and (setq ss (ssget))
           (setq pt (getpoint "\n指定缩放的基点: "))
      )
    (progn
      (if (setq ss2 (ssget "_p" '((0 . "DIMENSION"))))
        (progn
          (setq alst (mapcar '(lambda (d)
                               (setq d (vlax-ename->vla-object d))
                               (list d (vla-get-Measurement d))
                              )
                             (lt:ss->list ss2)
                     )
                flag T
          )
        )
      )
      (princ "\n指定缩放的比例因子: ")
      (command "_.scale" ss "" pt "\\")
      (if flag
        (mapcar '(lambda (x / d)
                  (setq d (car x))
                  (vla-put-LinearScaleFactor d (* (/ (cadr x) (vla-get-Measurement d))
                                                  (vla-get-LinearScaleFactor d)
                                               )
                  )
                 )
                alst
        )
      )
    )
  )
  (princ)
)

wowan1314

感谢楼上的CAOYIN大侠！

指定缩放的基点: ; 错误: 参数类型错误: lselsetp nil

程序不能使用！参数类型错误

caoyin

12楼已经修改

wowan1314

晕！ 我重新复制下来还是一样的问题！ 怎么回事！

wowan1314

新的已经下载，并通过测试！完全正常！ 十分满意！严重感谢！

wowan1314

强烈感谢CAOYIN大侠的帮助！以后再不怕画大样图了！

CAOYIN同志热情洋溢，乐于助人，古道侠肠。道德高尚,品质优良。

貌似CAOYIN同志长期活动在明经通道，为大家排忧解难！ 以前就曾发帖感谢！ 今忍不住再次感谢！

明经通道的好同志呀！ 

caoyin

别这么夸张

wowan1314

不是夸张! 可能词用的大了点！但事却是真事！

还真符合你的等级：职业侠客  ，   无门无派，  那就是职业游侠嘛！  ^_^

ahill

其实这种工具严格说来。。应该是不会需要的。。因为他这个说白了。。就是个如何在一张图框上放多个不同比例详图的问题。。而他这种通过放大缩小的方式来实现是一种相对较差的画法。。建议楼主去研究一下图纸空间。。如果实在是习惯用模型空间的话。。提供一种简单的不容易出错的笨办法：首先要明白比例概念，比如计划在一个1:30的图框内放一个1:5的详图，画图用1:1，对详图先按1:5标注，然后Ctrl+X　所画的详图（含标注），然后　Ctrl+Shift+V ，生成一个无名块，对这个无名块　Scale　6倍，就可以确保打印出来合乎制图规范的图了。如果要修改，双击块，可修改。

当然，从CAD制图的规范性来讲，还是建议用图纸空间布图的方式来实现。方便，又好控制。